区切り対象文字を含むデータを区切り対象から外す方法

Question

Access2010のVBAでSplit関数を使ってタブ区切りデータを分割しようとしました。
ただ、元データの作りとして、1要素内に入ってほしいデータにも区切り文字と同様のタブ文字が入っており、
結局。

サンプル文字列（タブは\tで記載）

"\"AAA\tBBB\tCCC\"\tDDD"

上記は「"AAA\tBBB\tCCC"」と「DDD」の2分割になってほしかったのですが、結局各4分割になってしまいます。
こういったデータはコマンドプロンプトのパスのように、""で囲んでおけば通るだろうかと試してみてましたが、
望ましい結果にはなってくれませんでした。
こういったデータを期待値となる2分割にする方法は何かないでしょうか。

Answer 1

正規表現を使うと一発でできると思いますが、私は苦手なので、
Split と Join で書いてみました。

'文字列をタブで分割したバリアント配列に変換
'ただし " で囲まれた部分は分割しない
Public Function SplitTSV(s As String) As Variant
    Dim cols
    cols = Split(s, """")
    
    Dim i As Long
    For i = LBound(cols) To UBound(cols) Step 2
         cols(i) = Replace(cols(i), vbTab, vbCrLf)
    Next

    SplitTSV = Split(Join(cols, ""), vbCrLf)
    'SplitTSV = Split(Join(cols, """"), vbCrLf) '"を残したい場合はこちらで
End Function

'動作確認
Public Sub TestSplitTSV()
    Dim s As String
    s = """AAA\tBBB\tCCC""\tDDD"
    s = Replace(s, "\t", vbTab)
    
    Dim v As Variant
    v = SplitTSV(s)
    Debug.Print Join(v, "／")
End Sub

ロジック
0. 引用符 " で分割する(Split)と、配列の奇数番目(1,3,5...)の要素が " で囲まれた部分になる。
0. 偶数番目(0,2,4...)の要素のタブを別の区切り文字(改行)に置換する。
0. 配列をJoinで結合する。
0. 結合した文字列を区切り文字(改行)で分割する。

Comments

[JanTh1989]

回答ありがとうございます。
処理が簡略化されており、わかりやすいです。
サンプルデータ前後に別データがあっても、配列の奇数偶数の位置も変わらいみたいなので、偶数の改行化固定でやれそうです。
"文字は残しておきたいので、2の次に奇数へ"文字を先頭と最後に付与する処理を足せば、万事解決しそうなので、そのあたりを検討に入れつつ作業にあたります。

ありがとうございました。

[ttyp03]

”でSplitしたあとの法則に気づいたのはさすがです。

Answer 2

なんか関数一発でできるといいんですが、知識がなかったのでゴリゴリ書いてみました。
とりあえずDebug.Printで出力しているので、必要であれば配列に入れたりなんかしてください。
あとExcelのVBAでテストしたので、AccessのVBAで不都合があるところは適宜修正してください。

    s = """AAA\tBBB\tCCC""\tDDD"
    s = Replace(s, "\t", vbTab)
    
    cols = Split(s, """")
    For Each col In cols
        If Trim(col) <> "" Then
            If Left(col, 1) = vbTab Then
                col = Mid(col, 2)
                If Right(col, 1) = vbTab Then
                    col = Mid(col, 1, Len(col) - 1)
                End If
                cols2 = Split(col, vbTab)
                For Each col2 In cols2
                    Debug.Print col2
                Next
            Else
                Debug.Print col
            End If
        End If
    Next

結果
AAA BBB CCC
DDD

別データでテスト。

    s = """AAAA\tBBBB\tCCCC""\tDDD\tEEEE\t""FFFF\tGGGG"""

結果
AAAA    BBBB    CCCC
DDD
EEEE
FFFF    GGGG

指摘があったので修正しました。
結局まじめにパースしてます。

    col = ""
    For i = 1 To Len(s)
        c = Mid(s, i, 1)
        Select Case c
            Case """"
                If qs = False Then
                    qs = True
                Else
                    Debug.Print col
                    col = ""
                    qs = False
                End If
            Case vbTab
                If qs = False Then
                    If col <> "" Then
                        Debug.Print col
                    End If
                    col = ""
                Else
                    col = col & c
                End If
            Case Else
                col = col & c
        End Select
    Next
    If col <> "" Then
        Debug.Print col
    End If

Comments

[torisan]

条件が合っているかわかりませんが、最初の項目が単体だと纏められてしまう気がします。

s = "AAA\tBBB"
AAA BBB

[ttyp03]

あー、確かにそうですね。
考えます。

[ttyp03]

修正版を追記しました。
なんかイマイチ洗練されてませんが。。。

[torisan]

横槍すみませんでした。
自分も少し考えましたが意外とややこしいですね、これ。
対応ありがとうございます。

[ttyp03]

いえ、指摘していただいて助かりました。
CSV,TSVのパースは面倒ですね。

[JanTh1989]

返答が遅くなり申し訳ありません。
回答ありがとうございます。
Splitに変わる良い感じの関数はやはりありませんか・・・。

頂いたコードはタブと""""の2段分割と結合で対応ですね。
Accessに入れてみたところ、動きとしては大丈夫そうでした。
分割⇒連結のような動きが、妥当な気がしてきました。

ひとまずこの方向で進めてみます。

[ttyp03]

hatena19氏の回答の方がスッキリ出来上がっているので、そちらのほうがいいかもしれません。
いずれにしても両方とも良く動作確認をして最適なものをお選びください。