CAN BUS シールドを使った通信が出来ない

Question

車両のCAN信号を読む為にArduinoで使えるCAN BUS シールドを購入しました。

SFE-DEV-13262
https://www.switch-science.com/catalog/2493/

構成図はこんな感じです。

ソフトはArduionoが無償で提供してくれているAPI使いました。
https://github.com/Seeed-Studio/CAN_BUS_Shield

しかし

ID: 0 Data: 
ID: 0 Data: 
ID: 0 Data: 
ID: 0 Data: 
ID: 0 Data: 

と表示されたままCANが表示されません。
ソースは以下の通りです。

// ライブラリヘッダのインクルード
#include <mcp_can.h>
#include <SPI.h>
 
//設定値
#define CS_PIN  (10) // CSを10ピンとする（変更可能）
#define INT_PIN (9)  // INTを9ピンとする（変更可能）
 
long unsigned int rxId;
unsigned char len = 0;
unsigned char rxBuf[8];

MCP_CAN CAN0(CS_PIN);      
 
void setup() {
    Serial.begin(115200);
    CAN0.begin(CAN_STDID, CAN_500KBPS, MCP_8MHZ); // CANの通信速度を500kbpsにする 
    pinMode(INT_PIN, INPUT); // 割り込みのためのピンを設定
    CAN0.setMode(MCP_NORMAL);
    Serial.println("MCP2515 Library Receive Example...");
}

byte data[8] = {0x00, 0x01, 0x02, 0x03, 0x04, 0x05, 0x06, 0x07};

void loop(){
    //受信
    if(!digitalRead(INT_PIN)) {  // 受信割り込みが発生したら、CANデータをReadする
        CAN0.readMsgBuf(&rxId, &len, rxBuf);
        Serial.print("ID: ");
        Serial.print(rxId, HEX);
        Serial.print("  Data: ");
        for(int i = 0; i<len; i++) {
            if(rxBuf[i] < 0x10) {
                Serial.print("0");
            }
            Serial.print(rxBuf[i], HEX);
            Serial.print(" ");
        }
        Serial.println();
    }
}

回路図は以下のようになっております。

D-SUB9のピン配列はこちらを参考にしました。

D-SUB9のピンの配列はこのようにしました

ご存知の方がおりましたら是非ご回答をお願いいたします。

Answer 1

終端処理が正しく出来てなかったのが原因だったようです。

https://monoist.atmarkit.co.jp/mn/articles/2006/15/news014.html
https://e2e.ti.com/blogs_/japan/b/analog/posts/can-1-can

MCP2515 CAN バス モジュール TJA1050を2台接続で通信出来てたのは、
１：１だったから終端処理が無くても動作していただけの事だったようです。

Comments

[SHOMI]

他の回答にベストアンサーがついていますが、こちらが原因だったということであればベストアンサーを変更してください。

Answer 2

私の使っているCANモジュールをは、ほぼ同じ見た目のものですが、以下で使えています。
if (CAN0.begin(MCP_ANY, CAN_1000KBPS, MCP_16MHZ) == CAN_OK)
CAN_500KBPSやMCP_8MHZにすると正しくデータが受信できなくなったりします。
こちらも色々試してみてください。

Answer 3

MCP2515 CAN バス モジュール TJA1050を2台、Arudinoを2台購入してやってみたら問題なく通信できました。

SFE-DEV-13262を使えなかったのは、pin配が間違っていたりするのかな？

Answer 4

D-SUB9のピン配列はこちらを参考にしました。
D-SUB9のピンの配列はこのようにしました

車両との配線は自作でしょうか。
表に書かれているOBD-IIは車両側OBD-IIコネクタの端子番号ではなく、市販されているOBD-II<->D-SUB9ケーブルのD-SUB9側ピン配置です。
車両側OBD-IIコネクタとの接続は以下のとおりですが正しいピンに接続されていますか。

端子	OBD-IIピン	D-SUB9ピン
GND	5	2
CAN-H	6	3
CAN-L	14	5

OBD-IIコネクタピン配置

ソフトはArduionoが無償で提供してくれているAPI使いました。
https://github.com/Seeed-Studio/CAN_BUS_Shield

これとは別のMCP_CAN_libを使用したコードに見えますが…
CAN0.begin()の第1引数にCAN_STDIDを指定していますが、MCP_ANYかMCP_STDEXTです。
MCP_STDEXTと値がたまたま一致していますが…
第3引数にMCP_8MHZを指定されていますが、回路図によると16MHzなのでMCP_16MHZとしてください。
StandardID(11bit)決めうちですがこれで良いのでしょうか。
ネットで拾ったコードを試す前にライブラリに付属のサンプルスケッチで試してみては？

// CAN Receive Example
//

#include <mcp_can.h>
#include <SPI.h>

long unsigned int rxId;
unsigned char len = 0;
unsigned char rxBuf[8];
char msgString[128];                        // Array to store serial string

#define CAN0_INT 2                              // Set INT to pin 2
MCP_CAN CAN0(10);                               // Set CS to pin 10


void setup()
{
  Serial.begin(115200);
  
  // Initialize MCP2515 running at 16MHz with a baudrate of 500kb/s and the masks and filters disabled.
  if(CAN0.begin(MCP_ANY, CAN_500KBPS, MCP_16MHZ) == CAN_OK)
    Serial.println("MCP2515 Initialized Successfully!");
  else
    Serial.println("Error Initializing MCP2515...");
  
  CAN0.setMode(MCP_NORMAL);                     // Set operation mode to normal so the MCP2515 sends acks to received data.

  pinMode(CAN0_INT, INPUT);                            // Configuring pin for /INT input
  
  Serial.println("MCP2515 Library Receive Example...");
}

void loop()
{
  if(!digitalRead(CAN0_INT))                         // If CAN0_INT pin is low, read receive buffer
  {
    CAN0.readMsgBuf(&rxId, &len, rxBuf);      // Read data: len = data length, buf = data byte(s)
    
    if((rxId & 0x80000000) == 0x80000000)     // Determine if ID is standard (11 bits) or extended (29 bits)
      sprintf(msgString, "Extended ID: 0x%.8lX  DLC: %1d  Data:", (rxId & 0x1FFFFFFF), len);
    else
      sprintf(msgString, "Standard ID: 0x%.3lX       DLC: %1d  Data:", rxId, len);
  
    Serial.print(msgString);
  
    if((rxId & 0x40000000) == 0x40000000){    // Determine if message is a remote request frame.
      sprintf(msgString, " REMOTE REQUEST FRAME");
      Serial.print(msgString);
    } else {
      for(byte i = 0; i<len; i++){
        sprintf(msgString, " 0x%.2X", rxBuf[i]);
        Serial.print(msgString);
      }
    }
        
    Serial.println();
  }
}

Comments

[izuki_y]

ご連絡が遅くなって大変申し訳ございません。
ご丁寧にありがとうございます。

>車両との配線は自作でしょうか。
自作です。D-sub9のメスーメスでつなげています。
ピンの配列は異なってます。
自分はPIN5, 3, 2 のストレートでつないだケーブルを使っております。

ソース使わせていただきます。
結果は報告させていただきます。

ご回答ありがとうございました。