UnityのSkyboxを自然にしたい

Question

##問題
UnityでSkyboxを使おうと思い、画像を自作してSkyboxで使うマテリアルに球状マップでインポートしました。ですが球状にしてしまった為、画像のように集中点のようなものができてしまいました。
例えば、この集中点を真上にするとか、集中点が自然になるように画像を変換するみたいなものは可能なのでしょうか？
何か皆様が工夫されていることでもいいので、教えてください！

Answer 1

簡単にポンと変換するのは難しいかもしれませんね...
直交座標と極座標の相互変換ができるような画像処理ソフトをお持ちでしたら、

のような作業を上下の極についてそれぞれ行ってやればある程度ごまかせるかもしれません。

あるいは、多少処理コストがかかってもかまわなければ、動的に星空を生成する手もあるかと思います。

Shader "Skybox/ProceduralStarfield"
{
	Properties
	{
		_Seed ("Seed", Float) = 0.0
		_NebulaColor1 ("Nebula Color 1", Color) = (0, 0, 0.25, 1)
		_NebulaColor2 ("Nebula Color 2", Color) = (0.25, 0, 0.25, 1)
		_Rotation ("Rotation Angle", Range(0.0, 360.0)) = 0.0
		_RotationAxis ("Rotation Axis", Vector) = (1.0, 0.0, 0.0, 0.0)
	}
	SubShader
	{
		Tags
		{
			"RenderType"="Background"
			"Queue"="Background"
			"PreviewType"="SkyBox"
		}

		Pass
		{
			ZWrite Off
			Cull Off

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float3 texcoord : TEXCOORD0;
			};

			struct v2f
			{
				float4 vertex : SV_POSITION;
				float3 texcoord : TEXCOORD0;
			};

			float _Rotation;
			float3 _RotationAxis;

			v2f vert(appdata v)
			{
				v2f o;
				float cosTheta;
				float sinTheta;
				sincos(_Rotation * UNITY_PI / 180.0, sinTheta, cosTheta);
				float cosThetaI = 1.0 - cosTheta;
				float3 u = normalize(_RotationAxis);
				float3 u2 = u * u;
				float3 us = u * u.yzx;
				float3x3 r = float3x3(
					       cosTheta + u2.x * cosThetaI, -u.z * sinTheta + us.x * cosThetaI,  u.y * sinTheta + us.z * cosThetaI,
					 u.z * sinTheta + us.x * cosThetaI,        cosTheta + u2.y * cosThetaI, -u.x * sinTheta + us.y * cosThetaI,
					-u.y * sinTheta + us.z * cosThetaI,  u.x * sinTheta + us.y * cosThetaI,        cosTheta + u2.z * cosThetaI
				);
				o.vertex = UnityObjectToClipPos(float4(mul(r, v.vertex.xyz), v.vertex.w));
				o.texcoord = v.texcoord;
				return o;
			}

			// Ian McEwanによるシンプレックス4Dノイズ 
			// https://gist.github.com/patriciogonzalezvivo/670c22f3966e662d2f83
			inline float4 glslMod(float4 x, float4 y) {return x - y * floor(x / y);}
			inline float glslMod(float x, float y) {return x - y * floor(x / y);}
			inline float4 permute(float4 x) {return glslMod(((x * 34.0) + 1.0) * x, 289.0);}
			inline float permute(float x) {return floor(glslMod(((x * 34.0) + 1.0) * x, 289.0));}
			inline float4 taylorInvSqrt(float4 r) {return 1.79284291400159 - 0.85373472095314 * r;}
			inline float taylorInvSqrt(float r) {return 1.79284291400159 - 0.85373472095314 * r;}
			inline float4 lessThan(float4 x, float4 y) {return saturate(sign(y - x));}

			float4 grad4(float j, float4 ip){
				const float4 ones = float4(1.0, 1.0, 1.0, -1.0);
				float4 p, s;

				p.xyz = floor(frac(j * ip.xyz) * 7.0) * ip.z - 1.0;
				p.w = 1.5 - dot(abs(p.xyz), ones.xyz);
				s = lessThan(p, 0.0);
				p.xyz = p.xyz + (s.xyz*2.0 - 1.0) * s.www; 

				return p;
			}

			float snoise(float4 v){
				const float2  C = float2( 0.138196601125010504,	 // (5 - sqrt(5))/20  G4
										  0.309016994374947451); // (sqrt(5) - 1)/4	  F4
				// First corner
				float4 i  = floor(v + dot(v, C.yyyy) );
				float4 x0 = v -	  i + dot(i, C.xxxx);

				// Other corners

				// Rank sorting originally contributed by Bill Licea-Kane, AMD (formerly ATI)
				float4 i0;

				float3 isX = step( x0.yzw, x0.xxx );
				float3 isYZ = step( x0.zww, x0.yyz );
				//	i0.x = dot(isX, 1.0);
				i0.x = isX.x + isX.y + isX.z;
				i0.yzw = 1.0 - isX;

				//	i0.y += dot(isYZ.xy, 1.0);
				i0.y += isYZ.x + isYZ.y;
				i0.zw += 1.0 - isYZ.xy;

				i0.z += isYZ.z;
				i0.w += 1.0 - isYZ.z;

				// i0 now contains the unique values 0,1,2,3 in each channel
				float4 i3 = clamp(i0, 0.0, 1.0);
				float4 i2 = clamp(i0 - 1.0, 0.0, 1.0);
				float4 i1 = clamp(i0 - 2.0, 0.0, 1.0);

				//	x0 = x0 - 0.0 + 0.0 * C 
				float4 x1 = x0 - i1 + 1.0 * C.xxxx;
				float4 x2 = x0 - i2 + 2.0 * C.xxxx;
				float4 x3 = x0 - i3 + 3.0 * C.xxxx;
				float4 x4 = x0 - 1.0 + 4.0 * C.xxxx;

				// Permutations
				i = glslMod(i, 289.0); 
				float j0 = permute(permute(permute(permute(i.w) + i.z) + i.y) + i.x);
				float4 j1 = permute(permute(permute(permute(
						i.w + float4(i1.w, i2.w, i3.w, 1.0))
						+ i.z + float4(i1.z, i2.z, i3.z, 1.0))
						+ i.y + float4(i1.y, i2.y, i3.y, 1.0))
						+ i.x + float4(i1.x, i2.x, i3.x, 1.0));
				// Gradients
				// ( 7*7*6 points uniformly over a cube, mapped onto a 4-octahedron.)
				// 7*7*6 = 294, which is close to the ring size 17*17 = 289.

				float4 ip = float4(1.0 / 294.0, 1.0 / 49.0, 1.0 / 7.0, 0.0);

				float4 p0 = grad4(j0, ip);
				float4 p1 = grad4(j1.x, ip);
				float4 p2 = grad4(j1.y, ip);
				float4 p3 = grad4(j1.z, ip);
				float4 p4 = grad4(j1.w, ip);

				// Normalise gradients
				float4 norm = taylorInvSqrt(float4(dot(p0, p0), dot(p1, p1), dot(p2, p2), dot(p3, p3)));
				p0 *= norm.x;
				p1 *= norm.y;
				p2 *= norm.z;
				p3 *= norm.w;
				p4 *= taylorInvSqrt(dot(p4, p4));

				// Mix contributions from the five corners
				float3 m0 = max(0.6 - float3(dot(x0, x0), dot(x1, x1), dot(x2, x2)), 0.0);
				float2 m1 = max(0.6 - float2(dot(x3, x3), dot(x4, x4)), 0.0);
				m0 = m0 * m0;
				m1 = m1 * m1;
				return 49.0 * (dot(m0 * m0, float3(dot(p0, x0), dot(p1, x1), dot(p2, x2)))
							+ dot(m1 * m1, float2(dot(p3, x3), dot(p4, x4))));

			}

			float _Seed;
			float4 _NebulaColor1;
			float4 _NebulaColor2;

			fixed4 frag(v2f i) : SV_Target
			{
				float4 coord = float4(i.texcoord, _Seed);
				float4 coordN1 = coord + float4(1.2, 3.4, 5.6, 7.8);
				float4 coordN2 = (coordN1 + float4(2.1, 4.3, 6.5, 8.7)) * 2.0;
				float4 coordN3 = (coordN2 + float4(5.6, 7.8, 1.2, 3.4)) * 2.0;
				float4 coordN4 = (coordN3 + float4(6.5, 8.7, 2.1, 4.3)) * 2.0;

				// 恒星...高周波ノイズを冪乗してまばらな点にする
				float star = pow(snoise(float4(coord.xyz * 32.0, coord.w)) * 0.5 + 0.5, 64.0);

				// 星雲...フラクタルノイズで密度を決め、さらにもう一つノイズを使って色ムラをつける
				float4 nebula4 = float4(snoise(coordN1), snoise(coordN2), snoise(coordN3), snoise(coordN4)) * 0.5 + 0.5;
				float nebula = pow(dot(nebula4, float4(1.0, 0.5, 0.25, 0.125)) / 1.875, 2.0);
				float3 nebulaColor = lerp(_NebulaColor1.rgb, _NebulaColor2.rgb, snoise(coord) * 0.5 + 0.5);

				return fixed4(nebulaColor * nebula + star, 1.0);
			}
			ENDCG
		}
	}
}

回転させる例

using UnityEngine;

public class ProceduralStarfieldRotor : MonoBehaviour
{
	private static readonly int RotationProperty = Shader.PropertyToID("_Rotation");
	private static readonly int RotationAxisProperty = Shader.PropertyToID("_RotationAxis");

	[SerializeField] private float angularSpeed = 15.0f;
	[SerializeField] private Vector3 axis = Vector3.right;
	
	private Material skybox;
	private float angle;

	private void Start()
	{
		this.skybox = RenderSettings.skybox;
		if (this.skybox == null)
		{
			Debug.LogError("No Skybox.");
			this.enabled = false;
			return;
		}

		if (!this.skybox.HasProperty(RotationProperty))
		{
			Debug.LogError("Skybox does not have _Rotation.");
			this.enabled = false;
			return;
		}

		if (!this.skybox.HasProperty(RotationAxisProperty))
		{
			Debug.LogError("Skybox does not have _RotationAxis.");
			this.enabled = false;
			return;
		}

		this.skybox.SetVector(RotationAxisProperty, this.axis);
	}

	private void Update()
	{
		this.angle += this.angularSpeed * Time.deltaTime;
		this.skybox.SetFloat(RotationProperty, this.angle);
	}
}

Comments

[退会済みユーザー]

またまたお世話になります。極座標変換の方はあまりうまくいきませんでした... SkyboxをX軸に回転させる方法ってあるんでしょうか？

[Bongo]

スカイボックスを回転できるかどうかは、スカイボックスのマテリアルが回転に対応しているかによるようですね。マテリアルが回転プロパティを持っていれば、RenderSettings.skyboxでマテリアルを取得してプロパティの値を書き換えることで回せるかと思います。
回答に提示しましたProceduralStarfieldを回転できるよう変更し、スクリプトから回転させる例を追加しました。ご参考になりますでしょうか?

[退会済みユーザー]

なるほど...とても参考になりました！ちなみにこのShaderは全て手書きで作ったのですか？

[Bongo]

一見長くてややこしいように見えますが、コードの大部分を占めているのは4次元ベクトルからノイズ値を得る関数でして、これはコメントにあるように [GLSL Noise Algorithms · GitHub](https://gist.github.com/patriciogonzalezvivo/670c22f3966e662d2f83 )で紹介されていたGLSL用コードをShaderLab向けに改造したものです。今回使ったシンプレックスノイズの他にも便利そうなものがいろいろ載っていてお役に立つかと思います。
他には、軸と角度から回転行列を算出する部分は[ロドリゲスの回転公式 - Wikipedia](https://ja.wikipedia.org/wiki/%E3%83%AD%E3%83%89%E3%83%AA%E3%82%B2%E3%82%B9%E3%81%AE%E5%9B%9E%E8%BB%A2%E5%85%AC%E5%BC%8F )を採用しました。
それ以外の、frag関数で行っているノイズを加工して星空っぽい見た目にする部分は一応オリジナルではありますが、やっていることはわりとありふれているように思います。独自性を主張できるようなレベルではないんじゃないですかね...?
ノイズ関数を除けば大して複雑なものではありませんので、いろいろいじってしまってください。恒星ノイズの周波数を上げ下げすると恒星の細かさが変わりますし、冪乗する指数を上げて星雲のムラを強調することができるでしょう。
他にも、Seedはノイズ計算の第4次元に使われており、ゆっくり変化させると空模様が変わります。今回は星空なのでころころ変化させるものではないでしょうが、星雲でなく空の雲を表現するときには雲に動きがついて面白そうですね。

[退会済みユーザー]

な、なるほど...本当に尊敬します...これから色々見てみます。ありがとうございました！