メッセージボックスで数えた個数を表示したい

Question

間違えた個数をカウントして、メッセージボックスで表示したいのですが
WorksheetFunction.CountIfを使用して数えたのですが、1個としか表示されません。
初心者なので、試行錯誤しても解決できません。
どうかよろしくお願いします。

For gyou = GYOU_S To GYOU_E '開始行から終了行まで
For retsu = RETSU_S To RETSU_E '開始列から終了列まで
If s1.Cells(gyou, retsu).Value <> s2.Cells(gyou, retsu).Value Then

  errflg = True
      
  
  
  '同じ位置のセルの値が等しくなければ、そのセルを黄で塗りつぶす。
    s1.Cells(gyou, retsu).Interior.Color = rgbYellow
    
        
  End If
  
  If s1.Cells(gyou, retsu).Value = s2.Cells(gyou, retsu).Value Then
  
    s1.Cells(gyou, retsu).Interior.ColorIndex = 0
   
  
  End If
Next

Next

If errflg = True Then

cnt = WorksheetFunction.CountIf(Range("s1"), "<>s2")

  MsgBox cnt & "個未完成です"

Else

　　　　 MsgBox "完成です。"

End If

Answer 1

欲しい結果を得るためにはいろいろな方法論があるとは思いますが、
一例を示します。

Option Explicit

Sub test()
    Dim myFormula As String: myFormula = "=If(XXXX=YYYY,"""",NA())"   '仮の数式を変数に代入
    Dim rngOld As Range     '元のデータのセル範囲
    Dim rngNew As Range     '比較するデータのセル範囲
    Dim rngTemp As Range    '一時的に数式を入れるセル範囲
    Dim rngResult As Range  '検索したセル範囲
    Dim strAddress As String    'セル範囲のアドレスを示す文字列
    Dim i As Long               '見つけたセルの個数
    Dim sProm As String         'メッセージボックスに表示する文字列

    sProm = "完成"
    'セル範囲を変数に取得
    With ThisWorkbook.Worksheets
        Set rngNew = .Item("Sheet2").UsedRange
        strAddress = rngNew.Address
        Set rngOld = .Item("Sheet1").Range(strAddress)
        Set rngTemp = .Item("Sheet3").Range(strAddress)
    End With
    
    '数式内の仮のセルアドレスを実際のものに書き換え一時的な作業用シートに入力
    myFormula = Replace(myFormula, "XXXX", rngNew(1).Address(False, False, , True))
    myFormula = Replace(myFormula, "YYYY", rngOld(1).Address(False, False, , True))
    rngTemp.Formula = myFormula
    
    '検索したセルがみつからないとエラーになるので、えらーを無視する宣言
    On Error Resume Next
    '計算結果が、エラーのセルを検索
    Set rngResult = rngTemp.SpecialCells(xlCellTypeFormulas, xlErrors)
    '見つけたセルの数を数える
    i = rngResult.CountLarge
    '見つけたセルのアドレスを比較するデータのセルのアドレスに適用して黄色を塗る
    rngNew.Worksheet.Range(rngResult.Address).Interior.Color = vbYellow
    'エラーの無視を解除
    On Error GoTo 0
    
    If i > 0 Then sProm = i & 未入力
    
    '一時的に入れた数式のクリア
    rngTemp.ClearContents
    
    MsgBox sProm
End Sub

ポイント＞＞
1）操作対象は最終的にはセル範囲なのだから、変数はセル範囲を入れるものを用意
（各セル範囲はどのシートに属しているかの情報をそれぞれ持っているので、
あえて何度もシートも指定する必要はありません）
2）エクセルでは、作業用の列とか作業用のシートとかを使い、処理の途中経過を
仮に置いておくようにすると、処理の流れを考えることが容易になります。
3）折角エクセルを使っているのだから、エクセル君に出来ることはエクセル君に任せると、
コードが簡便になります。（数式や機能を大いに利用する）
4）セル範囲はRangeプロパティを使うと、文字列（セルのアドレス）でセルを指定できるので、
セル範囲のアドレスを取得して、それを流用すると上手くセル範囲が指定できると思います。

参考URL>>
プロパティ、メソッドの探り方 マクロ記録とＦ１のHelpを使う

↑を参考にコードを解読してみたり、
ステップインで1行づつ実行しながら、
シート上の様子や、ローカルウィンドウ内の変数の値の変化に注視して、
動作を確認してみてください。
あと、わからない単語・用語などが出てきたらWebで検索して、
それでも解らない場合は、再度、聞いてください。

Comments

[hiro.tatsu]

ありがとうございます。大変参考になりました。
色々な方法があることを改めて知ることができました。

Answer 2

セル一つずつ比較しているので、違った場合は、セルの色を黄色にするだけでなくて、そこでカウントしてしまえばよいのではないでしょうか？

cnt = 0       ' カウンターをリセット
For gyou = GYOU_S To GYOU_E '開始行から終了行まで
For retsu = RETSU_S To RETSU_E '開始列から終了列まで

s1.Cells(gyou, retsu).Interior.ColorIndex = 0　　　'セルの色をリセット

If s1.Cells(gyou, retsu).Value <> s2.Cells(gyou, retsu).Value Then

'同じ位置のセルの値が等しくなければ、そのセルを黄で塗りつぶす。
s1.Cells(gyou, retsu).Interior.Color = rgbYellow

cnt = cnt + 1    'カウンターに1をたす。

End If

next retsu
next gyou

If cnt > 0 Then

MsgBox cnt & "個未完成です"

Else

MsgBox "完成です。"

End If

Comments

[hiro.tatsu]

ありがとうございます。とても参考になりました。
そういう方法もあるんですね。勉強になりました。

Answer 3

CountIfに指定しているs1ってコード内のs1（シート）を指してます？
これでは単にセルS1を指しているだけなので、期待した結果は得られません。
そもそもCountIfでシートを丸ごと比較することは出来ません。

前回からの続きと思いますが、フラグではなくカウンターにすれば簡単です。
以下参考にしてください。

Dim cnt As Long
cnt = 0
For gyou = GYOU_S To GYOU_E '開始行から終了行まで
	For retsu = RETSU_S To RETSU_E '開始列から終了列まで
		If s1.Cells(gyou, retsu).Value <> s2.Cells(gyou, retsu).Value Then

			cnt = cnt + 1

			'同じ位置のセルの値が等しくなければ、そのセルを黄で塗りつぶす。
			s1.Cells(gyou, retsu).Interior.Color = rgbYellow

		End If

		If s1.Cells(gyou, retsu).Value = s2.Cells(gyou, retsu).Value Then

			s1.Cells(gyou, retsu).Interior.ColorIndex = 0

		End If
	Next
Next

If cnt > 0 Then

	MsgBox cnt & "個未完成です"

Else

	MsgBox "完成です。"

End If

Comments

[hiro.tatsu]

前回に引き続き、ありがとうございました。
やっぱり、カウンターするのが一番なんですね。