質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

88.82%

Unity2D GPU Instancing に対応するシェーダ

解決済

回答 1

投稿

  • 評価
  • クリップ 0
  • VIEW 635
退会済みユーザー

退会済みユーザー

前提・実現したいこと

シェーダをGPU Instancingに対応させたい。

該当のソースコード

Shader "Unlit/World"
{
    Properties
    {
        [NoScaleOffset] _MainTex ("Texture", 2D) = "white" {}

        // 見た目調整用プロパティを変更、前回と異なり大きくするほど鋭くなる
        [PowerSlider(10)] _EdgeSharpness ("Edge Sharpness", Range(1.0, 100.0)) = 10.0

        _EdgeDist ("Edge Disturbance", Range(0.0, 1.0)) = 0.05
        _EdgeDistFreq ("Edge Disturbance Frequency", Range(0.0, 16.0)) = 4.0
    }

    SubShader
    {
        Tags { "RenderType"="Opaque" }

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #pragma multi_compile_instancing // 追加

            // 頂点アトリビュートからはUV関連を削除
            struct appdata
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
                UNITY_VERTEX_INPUT_INSTANCE_ID // 追加
            };

            // tileUvには(0, 0)、(1, 0)、(0, 1)、(1, 1)のいずれかが入る
            struct v2f
            {
                float4 vertex : SV_POSITION;
                float2 tileUv : TEXCOORD0;
                float weight : TEXCOORD1;
                float2 modelPos : TEXCOORD2;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            inline float random(float2 st) {
                return frac(sin(dot(st, float2(12.9898, 78.233))) * 43758.5453123);
            }

            float noise(float2 st)
            {
                float2 i = floor(st);
                float2 f = frac(st);
                float a = random(i);
                float b = random(i + float2(1.0, 0.0));
                float c = random(i + float2(0.0, 1.0));
                float d = random(i + float2(1.0, 1.0));
                float2 u = f * f * (3.0 - 2.0 * f);

                return dot(float2(lerp(a, b, u.x), lerp(c - a, d - b, u.x)), float2(1.0, u.y));
            }

            float fractal(float2 st)
            { 
                float4 amp = float4(1.0, 0.5, 0.25, 0.125);
                float4 v;

                v.x = noise(st);
                st = st * 2.0 + float2(14.1421356237, 17.3205080757);
                v.y = noise(st);
                st = st * 2.0 + float2(22.360679775, 26.4575131106);
                v.z = noise(st);
                st = st * 2.0 + float2(31.4159265359, 27.1828182846);
                v.w = noise(st);

                return dot(v, amp) / dot(1.0, amp);
            }

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _MainTex_TexelSize;
            float _EdgeSharpness;
            float _EdgeDist;
            float _EdgeDistFreq;

            // ユニフォーム変数を追加
            #define TYPE_COUNT_MAX 8
            int _TypeCount;
            float4 _TypeUvs[TYPE_COUNT_MAX / 2];
            float2 _TileSize;
            float _TypeLevels[TYPE_COUNT_MAX];

            v2f vert(appdata v)
            {
                v2f o;
                o.tileUv = v.color.xy;
                o.weight = v.color.a;
                o.modelPos = v.vertex.xy;
                o.vertex = UnityObjectToClipPos(v.vertex);
                UNITY_SETUP_INSTANCE_ID(v); // 追加
                UNITY_TRANSFER_INSTANCE_ID(v, o); 

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                UNITY_SETUP_INSTANCE_ID(i);
                // まずは前回同様weightを計算する
                float f = dot(float2(_EdgeDist, 1.0 - _EdgeDist), float2(fractal(i.modelPos * _EdgeDistFreq), 0.5));
                float upper = 1.0 - 2.0 * (1.0 - i.weight) * (1.0 - f);
                float lower = 2.0 * i.weight * f;
                float weight = lerp(lower, upper, step(0.5, i.weight));

                // weightを比較してどの範囲にいるか判定し、それを越えない最大のインデックスを調べる
                uint index = 0;
                [unroll(TYPE_COUNT_MAX)]
                for (int k = 0; k < _TypeCount; k++)
                {
                    if (_TypeLevels[k] < weight)
                    {
                        index = k + 1;
                        continue;
                    }
                    break;
                }
                index = min(index, _TypeCount - 1);

                // さらに、その一つ下・一つ上のインデックスを求めておく
                uint prevIndex = index > 0 ? index - 1 : 0;
                uint nextIndex = min(index + 1, _TypeCount - 1);

                // 範囲の下限・上限の高さを取得し、lowerLevelを0、upperLevelを1としたときのweightの位置を調べる
                float lowerLevel = (index == prevIndex) ? 0.0 : _TypeLevels[prevIndex];
                float upperLevel = (index == nextIndex) ? 1.0 : _TypeLevels[index];
                float weightInRange = (lowerLevel == upperLevel) ? 0.0 : (weight - lowerLevel) / (upperLevel - lowerLevel);

                // weightInRangeが0.5以上かどうかでnextIndex、prevIndexのいずれかを選択する
                uint edgeIndex = weightInRange >= 0.5 ? nextIndex : prevIndex;

                // weightInRangeが0.5の時0、そこより範囲境界に近いほど1になるような値を作る
                // このとき_EdgeSharpness乗して、カーブを適宜鋭くする
                float edgeFactor = saturate(pow(abs(weightInRange * 2.0 - 1.0), _EdgeSharpness));

                // 範囲中心および範囲境界に対応するUVを取得し、そこからそれぞれ色を取得する
                float4 edgeVector = _TypeUvs[edgeIndex / 2];
                float4 centerVector = _TypeUvs[index / 2];
                float2 edgeUv = lerp(edgeVector.xy, edgeVector.zw, edgeIndex % 2);
                float2 centerUv = lerp(centerVector.xy, centerVector.zw, index % 2);
                float2 uvOffset = i.tileUv * _TileSize;
                fixed4 edgeColor = tex2D(_MainTex, edgeUv + uvOffset);
                fixed4 centerColor = tex2D(_MainTex, centerUv + uvOffset);

                // 範囲中心でcenterColorが100%、境界部分でcenterColorとedgeColorが
                // 50%混合になるように2つの色を混ぜ合わせる
                return lerp(centerColor, edgeColor, edgeFactor * 0.5);
            }
            ENDCG
        }
    }
}

試したこと

(http://tips.hecomi.com/entry/2018/09/24/232125)

↑のHPを参考に、マテリアルの設定から「enable gpu instancing」が表示出来るようにはしたのですが、実際にプレイしてみると、描画されていませんでした。シェーダのことをよく分からないため、どう直せばいいのかが分かりません。GPU Instancing に対応させる方法を教えていただけるとありがたいです。

回答お願いします。

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 過去に投稿した質問と同じ内容の質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 1

checkベストアンサー

0

ご提示いただいたUnity の GPU Instancing に対応するシェーダのコードを調べてみた - 凹みTips記事中の「頂点シェーダ」の節をご覧いただきたいのですが、UNITY_SETUP_INSTANCE_ID(v)vertの頭の方に配置されています。
記事によれば、インスタンシング版のコードではUnityObjectToClipPosの内部でunity_InstanceIDを使用するとのことですので、それを設定するためのUNITY_SETUP_INSTANCE_IDマクロはそこよりも手前の位置に移動するべきかと思います。

            // 省略

            v2f vert(appdata v)
            {
                v2f o;
                UNITY_SETUP_INSTANCE_ID(v); // IDセットアップをUnityObjectToClipPos使用部分よりも手前に移動
                o.tileUv = v.color.xy;
                o.weight = v.color.a;
                o.modelPos = v.vertex.xy;
                o.vertex = UnityObjectToClipPos(v.vertex);
                UNITY_TRANSFER_INSTANCE_ID(v, o); 

                return o;
            }

            // 省略

投稿

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2019/04/27 20:42

    回答ありがとうございました。

    キャンセル

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 88.82%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

関連した質問

同じタグがついた質問を見る