Excel VBA（マクロ）ネット上のリンクをクリックしてから生成されるCSVファイルを取得するには？

Windows API関数を用いてファイルをダウンロードしてみました。
ご参考まで。

#If Mac Then
    'Running on MacIntosh. Do nothing.
#ElseIf VBA7 Then
    'Excel 2010 or later:
     #If Win64 Then
        '64-bit Excel, 2010 or later:
        'Use PtrSafe, LongPtr, and LongLong:
            Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" _
                                     Alias "URLDownloadToFileA" _
                                    (ByVal pCaller As LongPtr, _
                                     ByVal szURL As String, _
                                     ByVal szFileName As String, _
                                     ByVal dwReserved As LongLong, _
                                     ByVal lpfnCB As LongPtr) As LongLong
     #Else
        '32-bit Excel 2010 or later:
        'Use PtrSafe and LongPtr, but NOT LongLong:
            Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" _
                                    Alias "URLDownloadToFileA" _
                                    (ByVal pCaller As LongPtr, _
                                    ByVal szURL As String, _
                                    ByVal szFileName As String, _
                                    ByVal dwReserved As Long, _
                                    ByVal lpfnCB As LongPtr) As Long
     #End If
#Else
    'Excel 2007 or earlier:
        Private Declare Function URLDownloadToFile Lib "urlmon" Alias _
          "URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, ByVal _
            szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long
#End If

Sub Get_CSV()

    Const strURL = "https://stooq.com/q/d/l/?s=^dji&d1=20180423&d2=20190423&i=d"
    Dim strFNAME As String  'ダウンロード先（パス＋ファイル名）
    Dim ReturnValue As Variant

    'ファイル名をブックのパス＋test.csvとする
    strFNAME = ThisWorkbook.Path & "\test.csv"

    'URLDownloadToFile API をコールする
    ReturnValue = URLDownloadToFile(0, strURL, strFNAME, 0, 0)

    If ReturnValue = 0 Then 'ダウンロードに成功すると「ReturnValue =0」となる。
        Debug.Print "ダウンロード成功"
    Else
        Debug.Print "ダウンロード失敗"
    End If

    '結果の表示
    MsgBox strFNAME & "を保存しました。"

End Sub