Windowsのバッチにてelse ifの後半部分が処理されません

Question

事象と確認事項

Windowsのバッチで下記の、ソースコード1の条件分岐を指定したところ、
後半４，５つ目の条件を通らなく詰まっております。
ソースコード２のようにすれば通すことができますが原因がわからず、もしわかるようでしたらお教えいただけませんでしょうか？
コードの記載方法も改善箇所のご指摘いただけますと助かります。

該当のソースコード1

@echo off
setlocal

set B1=FALSE
set B2=TRUE
set B3=TRUE

if "%B1%" == "TRUE" (
    set words="%B1% %B2% %B3% Result1"
) else if "%B1%" == "FALSE" if "%B2%" == "FALSE" if "%B3%" == "FALSE" (
    set words="%B1% %B2% %B3% Result2"
) else if "%B1%" == "FALSE" if "%B2%" == "FALSE" if "%B3%" == "TRUE" (
    set words="%B1% %B2% %B3% Result3"
) else if "%B1%" == "FALSE" if "%B2%" == "TRUE" if "%B3%" == "FALSE" (
    set words="%B1% %B2% %B3% Result4"
) else if "%B1%" == "FALSE" if "%B2%" == "TRUE" if "%B3%" == "TRUE" (
    set words="%B1% %B2% %B3% Result5"
) 

echo %words%

endlocal
exit /b 0

※バッチファイル名はiv.bat

実行結果

環境変数B1~B3を変更して各条件について網羅するようテストしました。
4つ目の条件から結果が取得できません。

C:\pg\test>iv
"TRUE TRUE TRUE Result1"

C:\pg\test>iv
"FALSE FALSE FALSE Result2"

C:\pg\test>iv
"FALSE FALSE TRUE Result3"

C:\pg\test>iv
ECHO は <OFF> です。

C:\pg\test>iv
ECHO は <OFF> です。

該当のソースコード2(解消版)

試しに下記のようにelse if を切り離すと正しい結果を取得できます。

@echo off
setlocal

set B1=FALSE
set B2=TRUE
set B3=TRUE

if "%B1%" == "TRUE" (
    set words="%B1% %B2% %B3% Result1"
) else if "%B1%" == "FALSE" if "%B2%" == "FALSE" if "%B3%" == "FALSE" (
    set words="%B1% %B2% %B3% Result2"
) else if "%B1%" == "FALSE" if "%B2%" == "FALSE" if "%B3%" == "TRUE" (
    set words="%B1% %B2% %B3% Result3"
) 
rem 切り離すとOK
if "%B1%" == "FALSE" if "%B2%" == "TRUE" if "%B3%" == "FALSE" (
    set words="%B1% %B2% %B3% Result4"
) else if "%B1%" == "FALSE" if "%B2%" == "TRUE" if "%B3%" == "TRUE" (
    set words="%B1% %B2% %B3% Result5"
) 

echo %words%

実行結果(解消版)

C:\pg\test>iv
"FALSE TRUE TRUE Result5"

補足情報（FW/ツールのバージョンなど）

OS 名: Microsoft Windows 10 Home
OS バージョン: 10.0.17763 N/A ビルド 17763

追記(回答を踏まえた修正版)

Y.H.さんに頂いた最もスッキリした形ではありませんが、
今回の反省を踏まえた修正版を追記します。

• ifを連結した時にand風の挙動をする場合もあるがかならずしもそうならない
• else if のあとで評価される条件式は一つ（ifを連結したandもどきは利用できない）
• ifの省略形を使わない(可読性以前に正しい処理が記述されない)

@echo off
setlocal

set B1=FALSE
set B2=TRUE
set B3=TRUE

if "%B1%" == "TRUE" (
	set words="%B1% %B2% %B3% Result1"
) else if "%B1%" == "FALSE" (
	if "%B2%" == "FALSE" (
		if "%B3%" == "FALSE" (
		    set words="%B1% %B2% %B3% Result2"
		) else if "%B3%" == "TRUE" (
		    set words="%B1% %B2% %B3% Result3"
		) 
	) else if "%B2%" == "TRUE" (
		if "%B3%" == "FALSE" (
		    set words="%B1% %B2% %B3% Result4"
		) else if "%B3%" == "TRUE" (
		    set words="%B1% %B2% %B3% Result5"
		) 
	)
)

echo %words%

endlocal
exit /b 0

追記2

可読性を上げたので追記します。

@echo off
setlocal

set B1=FALSE
set B2=FALSE
set B3=TRUE
set words=%B1% %B2% %B3%

if "%B1%" == "TRUE" (
    set words="%words% Result1"
) else if "%words%" == "FALSE FALSE FALSE" (
    set words="%words% Result2"
) else if "%words%" == "FALSE FALSE TRUE" (
    set words="%words% Result3"
) else if "%words%" == "FALSE TRUE FALSE" (
    set words="%words% Result4"
) else if "%words%" == "FALSE TRUE TRUE" (
    set words="%words% Result5"
) 

echo %words%

endlocal
exit /b 0

Comments

[退会済みユーザー]

ａｎｄの書き方ではないです。

[Y.H.]

@echo off
を外して実行すると全てコンソールに出力されるので何が起きているか一目瞭然で判ると思うのですが。。。

[kaxzuma]

ご回答いただき有り難うございます。
> asahina1979
> ａｎｄの書き方ではないです。
回答いただいた手前恐縮ですが、andの条件を表現する記法にしており、差し支えなければandの書き方になっていない部分についてご指摘いただくことはできますでしょうか。

> Y.H.
> @echo off
> を外して実行すると全てコンソールに出力されるので何が起きているか一目瞭然で判ると思うのですが。。。
実行した結果につきまして、
５番目が正となり結果を取得できる用に見受けられます。ソースコード２の解消版では取得できるのですが取得できない理由までたどり着くことができずご助言いただくことはできますでしょうか？
> else if "FALSE" == "FALSE" if "TRUE" == "TRUE" if "TRUE" == "TRUE" (set words="FALSE TRUE TRUE Result5" )

## echo off外し実行結果抜粋
```
if "FALSE" == "TRUE" (set words="FALSE TRUE TRUE Result1" )
else if "FALSE" == "FALSE" if "TRUE" == "FALSE" if "TRUE" == "FALSE" (set words="FALSE TRUE TRUE Result2" )
else if "FALSE" == "FALSE" if "TRUE" == "FALSE" if "TRUE" == "TRUE" (set words="FALSE TRUE TRUE Result3" )
else if "FALSE" == "FALSE" if "TRUE" == "TRUE" if "TRUE" == "FALSE" (set words="FALSE TRUE TRUE Result4" )
else if "FALSE" == "FALSE" if "TRUE" == "TRUE" if "TRUE" == "TRUE" (set words="FALSE TRUE TRUE Result5" )

C:\pg\test>echo
ECHO は <ON> です。

```

Answer 1

当初記載した「以下を省略した記述」に誤りがあった為、質問記載のコードと私の回答記載のコードで結果に相違があります。
質問記載のif(else if)の条件を省略せず展開した物を正しい物に書き換えました。

---

質問記載のif 文は都合よく記述されてますが以下を省略した記述になります。B1=FALSE、B2=TRUEの場合wordsに値は入りません。

if "%B1%" == "TRUE" (
    set words="%B1% %B2% %B3% Result1"
) else if "%B1%" == "FALSE" (
    if "%B2%" == "FALSE" (
        if "%B3%" == "FALSE" (
            set words="%B1% %B2% %B3% Result2"
        ) else if "%B1%" == "FALSE" (
            if "%B2%" == "FALSE" (
                if "%B3%" == "TRUE" (
                    set words="%B1% %B2% %B3% Result3"
                ) else if "%B1%" == "FALSE" (
                    if "%B2%" == "TRUE" (
                        if "%B3%" == "FALSE" (
                            set words="%B1% %B2% %B3% Result4"
                        ) else if "%B1%" == "FALSE" (
                            if "%B2%" == "TRUE" (
                                if "%B3%" == "TRUE" (
                                    set words="%B1% %B2% %B3% Result5"
                                )
                            )
                        )
                    )
                )
            )
        )
    )
)

複数の変数に対して組み合わせをif文で記述する場合は以下のようにすると簡潔に書けます

if "%B1%" == "TRUE" (
    set words="%B1% %B2% %B3% Result1"
) else if "%B1% %B2% %B3%" == "FALSE FALSE FALSE" (
    set words="%B1% %B2% %B3% Result2"
) else if "%B1% %B2% %B3%" == "FALSE FALSE TRUE" (
    set words="%B1% %B2% %B3% Result3"
) else if "%B1% %B2% %B3%" == "FALSE TRUE FALSE" (
    set words="%B1% %B2% %B3% Result4"
) else if "%B1% %B2% %B3%" == "FALSE TRUE TRUE" (
    set words="%B1% %B2% %B3% Result5"
)

Comments

[kaxzuma]

明快なご回答をありがとうございます。

else ifの中をすべて評価している前提で考えておりましたが、そこが違ったという点気がつくことができておりませんでした。andの記載になってない点もよくわかりました。

> 変数B1がFALSEの場合はすべて、REM (1)のところに入ります。
について引っかかりが残ります。質問に記載した実行結果より
"FALSE FALSE TRUE Result3"の結果になるケースもありました。
こちらも検証内容の誤りなどあると思われますので、改めて上記知見を踏まえ確認してみます。

[Y.H.]

FALSE FALSE TRUE の場合、kaxzumaさんの仰るとおり結果に差異がありますね。

[Y.H.]

回答を修正しました。これで何が起こっているのか判ると思います。
※正に、KojiDoiさん回答のURLの記事に記載の罠にはまって回答してた。。。

[kaxzuma]

私の一番最初に書いた条件式を素直にイフイフするとたしかにこうなりますね、、
"%B2%" == "TRUE"　の条件が完全に埋もれてしまいました。
大変良くわかりました。

スッキリとした形式で書くつもりが、
elseifの完全にだめな例となっていたようです。
多くのことを学ばさせていただきありがとうございます。
今回の反省と、修正版について質問に追記しました。

今度ともどうぞよろしくお願いいたします。

Answer 2

http://u64178.blogspot.com/2014/08/if-and-or.html
この辺を見れば原因と対策が理解できるのではないでしょうか。

Comments

[kaxzuma]

情報のご提供ありがとうございます。頂いたページもすでに参考にしていました。
しかしながら、多重条件についての理解がなかったためにコピペで利用し引っかかりました。
今回皆様にご回答いただきました内容踏まえて改めて参考にしたいと思います。