ファイル検索結果に応じてメッセージ出力

Question

前提・実現したいこと

ファイル検索結果に応じてメッセージ出力させたい
3番目のファイルは存在しないです。

発生している問題

3番目が存在しないファイルで見つかりませんでしたの旨のメッセージを出力させたいのですが
下記の実行結果となります

【実行結果】
□C:\Users\AAAA\BBBB.xls
■C:\Users\CCCC\DDDD.xls
■C:\Users\AAAA\BBBB.xls
□C:\Users\CCCC\DDDD.xls
■C:\Users\AAAA\BBBB.xls
■C:\Users\CCCC\DDDD.xls

【コード】
Sub Sample()
Call FileSearch("C:\Users\AAAA", "BBBB.xls")
Call FileSearch("C:\Users\CCCC", "DDDD.xls")
Call FileSearch("C:\Users\EEEE", "FFFF.xls")
End Sub

Sub FileSearch(Path As String, Target As String)
Dim FSO As Object, Folder As Variant, File As Variant
Set FSO = CreateObject("Scripting.FileSystemObject")
For Each Folder In FSO.GetFolder(Path).SubFolders
Call FileSearch(Folder.Path, Target)
Next Folder
For Each File In FSO.GetFolder(Path).Files
If (File.Name = Target) Then
msg = "□" & File.Path & "が見つかりました"""
MsgBox msg
Else
msg = "■" & File.Path & "が見つかりました"""
MsgBox msg
End If
Next File
End Sub

Answer 1

For Each File In FSO.GetFolder(Path).Filesですべてのファイルをスキャンしてますが、
同じファイル名が見つかったらmsg変数に見つかったと代入してループを抜ける。
msg変数が""のままならファイルは存在しなかった。
というロジックにするといいでしょう。

コードの修正例

Sub FileSearch(Path As String, Target As String)
    Dim FSO As Object, Folder As Variant, File As Variant
    Dim msg As String
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    For Each Folder In FSO.GetFolder(Path).SubFolders
        Call FileSearch(Folder.Path, Target)
    Next Folder
    
    For Each File In FSO.GetFolder(Path).Files
        If (File.Name = Target) Then
            msg = "□" & File.Path & "が見つかりました"
            Exit For
        End If
    Next File
    If msg = "" Then msg = "■" & Path & "内に" & Target & "は見つかりませんでした"
    MsgBox msg
End Sub

別解

ファイルが存在するかどうかは、FileSystemObject.FileExistsメソッドを使うとシンプルです。

Sub FileSearch(Path As String, Target As String)
    Dim FSO As Object, Folder As Variant, File As Variant
    Dim msg As String

    Set FSO = CreateObject("Scripting.FileSystemObject")
    For Each Folder In FSO.GetFolder(Path).SubFolders
        Call FileSearch(Folder.Path, Target)
    Next Folder

    If FSO.FileExists(Path & "\" & Target) Then
        msg = "□" & Path & "\" & Target & "が見つかりました"
    Else
        msg = "■" & Path & "内に" & Target & "は見つかりませんでした"
    End If
    Debug.Print msg
End Sub

Answer 2

提示のコードではフォルダ内のファイルをリストアップして出力してるという動作なので、
存在しないファイルというのは出しようがないと思いますが。