Excel VBA で、検索結果の上位10件のサイトをIEのタブで表示させたい。

Question

Excel VBA で、検索結果の上位10件のサイトをIEのタブで表示させたい。

Excel VBA 初心者です。
例えば、セル【B4~B13】に検索ワードがあり、VBAで、それぞれの検索ワードでIEを立ち上げ
グーグルで、検索を掛けます。
↑
ここまではできました。
その後、検索結果として表示された上位10件(上から10番目)までを、上記でたちあげた、
それぞれのIE上で、タブで分けて表示させたいです。

色々と、ググってはみましたが、自分が望むものはHitしませんでした。
（理解できていないだけかもしれません。。。）
本来、自分のVBAレベルではIE制御はまだまだ先なのですが、業務上どうしても必要で
他に分かる社内の人間もおりません。ご教示いただけると幸いです。

下記に記載した内容が、現段階のものです。
─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─
Sub 検索()

n = Cells(Rows.Count, "A").End(xlUp).Row
For iii = 4 To n
Range("B" & iii).Select
Dim ie As Object

Set ie = CreateObject("InternetExplorer.Application")
ie.Visible = True

'▼　""で囲まれたURLの画面へ移動　▼
ie.Navigate "http://www.google.co.jp/search?q=" & ActiveCell

waitNavigation ie

Next
End Sub
─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─ ─
'▼　URL画面の読み込み待ち　▼
Sub waitNavigation(ie As Object)

Do While ie.Busy Or ie.ReadyState < 4
DoEvents
Loop
End Sub

Comments

[stdio]

HTMLが取得できるなら直接書き換えれば済む話ですが...
それば出来ないのでしょうか？

[max222]

ご質問ありがとうございます。。。ありがとうございます…なんですが、自分の知識が着いていけておらず、そのご質問の意味さえ分かっておりません。orz
質問の意味としては、
A:Firefoxでhtmlの要素を確認し、googleの検索結果画面のhtml要素を確認し、上位10件を取得する。的なことでしょうか？
　↑そうであったり、仮に近しいやり方だった場合、その対応方法がわかりません。。。

B：webクエリで、一度Excelで読み込んで、その該当URLをIEタブで開くという事でしょうか？

[stdio]

URLをIEタブで開かなくてもHTMLの文字列さえ取得できれば、後はSplit関数を使いまくって文字区切れば？
そうしたら上位１０位はすぐ取得できますが...
しかし、基本的にランキングの様なシステムはPHPやjavascriptを使用している事が多いためもしかしたら、取得できないかも。
下記等を参考にしてみてはいかがでしょうか？
https://tonari-it.com/vba-ie-get-table/
https://www.fastclassinfo.com/entry/vba_ie_control

Answer 1

回答ではなくてヒント？ですみません。
また、「上位10件」ではなく、「検索結果の最初のページにヒットしたものだけ」の処理です。
「動画」とか「画像」みたいなのが一番上に表示されてしまっている場合はその部分は無視しています。

私もよくわかってないのですみませんが、当方でも色々試してみましたら、以降のコードで、一応、検索結果のタイトルとURLが取得できました。Excelのアクティブシートに書き出しています。

条件分岐の中で、「anc_anchor01.Click」みたいな感じで「Clickメソッド」を使うと、そのページへ飛ぶこともできます。ただ、別のタブに表示する方法がわかりませんでした。
「InternetExplorer getelementsbytagname 使い方」みたいな感じでWeb検索したら、もしかしたら、何か出てくるかもしれません。
あと、「<h3」という<h3>タグの一部があったら、タイトルを取得しているようにしていますが、これはHTMLソースを見たら、たまたまGoogleがh3を使っていたようなのでそうしました。なのでほかのタグが使われているページでは正常動作しないと思います。つまり、「<h3」だけでなく「<h2」なども分岐に加えたほうがいいかもしれません。（私もHTMLタグは詳しくないのでよくわかっていません！すみません！）

実行するには、VBEの画面にて、「Microsoft Internet Controls」と、「Microsoft HTML Object Library」を参照設定してからにします。
また、参照設定（事前バインディング）をしたので、IEのインスタンスの生成は、CreateObjectではなく、Newに変えました。
（参照設定して、CreateObjectしてしまうと2重になってしまうかもしれないので。また、インテリセンスが使いたかったので。）

もちろん、参照設定しないなら、Newではなく、CreateObject に戻してください。
「Microsoft HTML Object Library」がらみのものについても、CreateObject のようなことが必要だと思います。

ちゃんと動かなかったらごめんなさい。

Sub test01()

    Dim ie                  As InternetExplorer
    Dim hd_htdoc            As HTMLDocument
    Dim anc_anchor01        As HTMLAnchorElement
    Dim i                   As Integer
    Dim s_HTML              As String
    Dim s_txt               As String
    
    Set ie = New InternetExplorer
    ie.Visible = True
    
    ie.Navigate "http://www.google.co.jp/search?q=" & "steve gadd"
    waitNavigation ie
    
    
    Set hd_htdoc = ie.Document
    
    i = 1
    
    'HTMLソースの中の、「<A>タグの部分」を総ざらいします。
    For Each anc_anchor01 In hd_htdoc.getElementsByTagName("A")
    
        '「anc_anchor01.outerHTML」の中に、
        '「<h3」という<h3>タグの一部があったら、
        '検索結果の中のタイトルを取得できるっぽいので
        '以下の処理。

        'ヒットした各Webページの部分の、
        'タイトルやらURLやタグやら全部を変数に代入            
        s_HTML = anc_anchor01.outerHTML
        
        If 0 < InStr(1, s_HTML, "<h3", vbBinaryCompare) Then

            'ヒットした各Webページのタイトル部分のみを変数に代入                        
            s_txt = anc_anchor01.outerText
            
            'anc_anchor01.outerText（ヒットしたタイトル） の中に
            '「改行」がいくつか含まれてしまっていたので "--" に置換して消す。
            Range("A" & i) = Replace(s_txt, vbCrLf, "--", , , vbBinaryCompare)
            Range("B" & i) = anc_anchor01.href
            
            i = i + 1
            
        Else
            
        
        End If
        
    
    Next anc_anchor01
    


End Sub
 
 
 
'▼　URL画面の読み込み待ち　▼
Sub waitNavigation(ie As Object)

    Do While ie.Busy Or ie.ReadyState < 4
    DoEvents
    Loop

End Sub

たまたま家に「ExcelVBA IE を思いのままに操作できるプログラミング術」という本が読まずに置いてあったので、それの一部を少し読んでみたら、なんとかやれました。
ただ、結局本を読んでもあまりよくわからず、でも「参照設定」して変数を決め打ちすればインテリセンスが使えるので、それと、HTMLソースを見てなんとかやってみただけなので、本当はもっとちゃんとしたコードがあるようにも思います。

IEの操作はそういった本を1冊買っておいた方が早いかもしれません。

※追記
今、この本、ちゃんと最後までさらーっと読み直してみたら、すごくよさそうです。今後ももしIE操作を細かく自動化したかったら、買っておいても損はないかもです。
著者のサイト？かは不明ですが、以下のサイトもよさげです。本に書いてることよりも詳しい説明も載っていました。（本書にもこのようなことが書かれています。本から入った方がわかりやすいと思います。）
https://www.vba-ie.net/sp/element/getelementsbytagname.php
各Tipsの目次らしきページ→　https://www.vba-ie.net/qanda/qanda.cgi