【VBA】ダイアログボックスで取得したパスを別プロシージャで使いたい

Question

前提・実現したいこと

VBAでダイアログボックスで取得したパスを別プロシージャで使いたいと思っています。
例があまりよくないかもしれませんが、
列削除プロシージャでダイアログボックスでパスを取得し、列削除(処理1)を行い、
その後、行削除(処理2)のみ行いたいとき、同様のパスを使用するにはどのように書けばよいでしょうか？

このソースコードで書くと列削除のみ、行削除のみで実行できず、
行削除プロシージャで列削除プロシージャが呼び出されて、どちらも実行されてしまいます。

※列削除、行削除はあくまで例となります。
※初心者でもわかりやすく教えて頂けるととても嬉しいです。

該当のソースコード

Sub 列削除(ByRef OpenFilePath As String)
   Dim OpenFilePath As String    
   OpenFilePath = Application.GetOpenFilename("Microsoft Excelブック,*.xls?")
   
   '列削除の処理
End Sub

Sub 行削除()
   Dim filePath As String
   Call 列削除(filePath)

   '行削除の処理
End Sub

Answer 1

提示のコードだと宣言重複エラーになりますよね。
下記のように宣言重複している行をコメントアウトすれば動作はします。

Public Sub 列削除(ByRef OpenFilePath As String)
'   Dim OpenFilePath As String
   OpenFilePath = Application.GetOpenFilename("Microsoft Excelブック,*.xls?")

   '列削除の処理
End Sub

Public Sub 行削除()
   Dim filePath As String
   Call 列削除(filePath)

   '行削除の処理
End Sub

このソースコードで書くと列削除のみ、行削除のみで実行できず、
行削除プロシージャで列削除プロシージャが呼び出されて、どちらも実行されてしまいます。

そのようにコードを書いていますから当然そうなります。

まず、やりたいことを整理しましょう。

特定のワークブックに対して、列削除、行削除をしたい。
両方実行する場合もあり、また、片方だけ実行したい場合もある。

ということだとします。
列削除、行削除は、ワークブックに対して行う処理なので、パスを渡すとその処理の中でワークブックを開く処理が必要になりますが、両方実行する場合、無駄になりますよね。あるいは、既に開いているかどうか確認する処理とかも必要になり複雑になります。
ワークブックオブジェクトを渡せば、単純に、列削除、行削除のみのコードを書けばいいのでシンプルになります。

そうすれば、列削除、行削除 を呼び出すときに、ワークブックを開いてそれを引数で渡すか、開いているなら開いているワークブックを引数に渡せばいいだけです。

例えば、ユーザーがダイアログで指定したワークブックに対して、行削除、列削除を実行したいなら、下記のようなコードになります。

Public Sub Test()
    Dim OpenFileName As String
    Dim wb As Workbook
    
    OpenFileName = Application.GetOpenFilename("Microsoft Excelブック,*.xls?")
    If OpenFileName <> "False" Then
          Set wb = Workbooks.Open(OpenFileName)
          Call 行削除(wb)
          Call 列削除(wb)
    Else
        MsgBox "キャンセルされました"
    End If
End Sub

Public Sub 列削除(ByRef wb As Workbook)
    With wb

        'ワークブックに対する列削除の処理
        MsgBox .Name & "に対して列削除"
    End With
End Sub

Public Sub 行削除(ByRef wb As Workbook)
    With wb

        'ワークブックに対する行削除の処理
        MsgBox .Name & "に対して行削除"
    End With
End Sub

Answer 2

その例だと行削除の中で列削除してしまいますが大丈夫ですか・・・？
別々に行いたいものと仮定してお答えします。

ダイアログを求める部分と処理を行うプロシージャを分割するのが一般的です。

Sub 列削除(ByVal filePath As String)
    '列削除の処理
End Sub

Sub 列削除_dlg()
    Dim filePath As String
    filePath = Application.GetOpenFilename("Microsoft Excelブック,*.xls?")
    Call 列削除(filePath)
End Sub

Sub 行削除(ByVal filePath As String)
   '行削除の処理
End Sub

Sub 行削除_dlg()
    Dim filePath As String
    filePath = Application.GetOpenFilename("Microsoft Excelブック,*.xls?")
    Call 行削除(filePath)
End Sub

Sub 行と列削除_dlg()
    Dim filePath As String
    filePath = Application.GetOpenFilename("Microsoft Excelブック,*.xls?")
    Call 列削除(filePath)
    Call 行削除(filePath)
End Sub

プロシージャ分割をしたくない場合はこんな方法も考えられます。
※ただしエクセルが再起動したり「END」ステートメントが実行されるまで、ダイアログが二度と要求されなくなりますので、都度確認が必要な場合は使えません。

Function ファイル選択() As String
    Static OpenFilePath As String
    If OpenFilePath = "" Then
        OpenFilePath = Application.GetOpenFilename("Microsoft Excelブック,*.xls?")
    End If
    ファイル選択 = OpenFilePath
End Function

Sub 列削除()
    Dim filePath As String
    filePath = ファイル選択
    
    '列削除の処理
End Sub

Sub 行削除()
    Dim filePath As String
    filePath = ファイル選択

   '行削除の処理
End Sub

Sub 行と列削除()
    Call 列削除
    Call 行削除
End Sub

Comments

[ff.kk]

後者のような実行をしたかったのです。
乏しい質問内容からご回答いただきありがとうございました！