vbaでdialogのオブジェクトから引数を設定する

Question

vbaでダイアログの入力値を引数として利用したいのですが何度試してもエラーがでます。

ダイアログのeditboxesに入力した数値を
vbaのプロシージャの引数として利用したいのですが
可能でしょうか。何度やってもエラーが出ます。
以下内容です。
editboxesの値を変数cell_rowに入れています。
public cell_row as variantで定義しておりスコープ変数としています。

Sub zero_cross_color(cell_row)
'1個目のプロシージャ

    For x = 10 To 368
    
       If Cells(x, cell_row).Value >= 0 And Cells(x + 1, cell_row).Value <= 0 Then
     
       
       
       Range(Cells(x, cell_row), Cells(x, cell_row).Offset(1, 0)).Select
       Selection.Interior.Color = RGB(256, 256, 0)
       
       
       ElseIf Cells(x, cell_row).Value <= 0 And Cells(x + 1, cell_row).Value >= 0 Then

       
       Range(Cells(x, cell_row), Cells(x + 1, cell_row)).Select
       Selection.Interior.Color = RGB(256, 256, 0)
                   
       Else
       
       
       End If
    
    Next x
    
End Sub

Sub 呼び出し()
    Call zero_cross_color(DialogSheets("dialog1").EditBoxes("列").Text)
End sub

このvbaでしたいこと

Sin xθの波形でどこでプラマイに切り替わるか、などを調べています。このvbaはその一つですが、
どうしてもダイアログを使用して、引数を設定したいです。
2行目までは認識しているようですが、cell_rowの部分はダイアログ入力値が反映されています。
それ以降は定義が不明？かよくわかりません。

うまく伝えられませんがお手数ですがよろしくお願いします。

対処

• 変数にダイアログの値を使わずにそのまま入力すると普通に実行できます。
• 変数定義をintegerにしてもエラーは出ました。

Answer 1

解決対処

ベストアンサーにあるようにCInt()でeditboxesのtextを数値として扱うことで問題なくプロシージャは実行されました。定義については引数内で定義しなくとも今のところは問題ないようです。
他、ワークブックやシートの指定はしなくとも大丈夫でした！　ダイアログを開いても、アクティブ状態である様子です。

プロシージャはここに載せている以外にもいくつかあるので補足すると、CInt()は整数数値にするものなので必要に応じて小数として認識できるCSng()を使い分けるようにします。

Answer 2

エラーメッセージが書かれていないため推測で回答しますが、現段階では以下の2点を改善する必要があると思います。

1. zero_cross_color()内のCells, Rangeが含まれるシートを明確に示す
2. Cells() の引数に文字列でなく数値を渡す

Cells, Rangeが含まれるシートを明確に示す

シートを指定せずに単にCellsやRangeと書いた場合、アクティブなシート上のセルを参照します。
そのため、ダイアログシートがアクティブな状態で実行するとセルの参照先が見つからずにエラーが出ます。
今回の場合は以下のように、セルが属するシートを指定すれば良いと思います("シート名"は適切に設定してください)。

ThisWorkbook.Worksheets("シート名").Cells(i, j)
ThisWorkbook.Worksheets("シート名").Range(ThisWorkbook.Worksheets("シート名").Cells(i, j), ThisWorkbook.Worksheets("シート名").Cells(k, l))

Cells() の引数に文字列でなく数値を渡す

Cells()の引数には数値を入れる必要がありますが、EditBoxes("列").Textは文字列として取得されます。値を数値として渡すために、CInt()を用いて以下のようにプロシージャをコールしてみてください。

 Call zero_cross_color(CInt(DialogSheets("dialog1").EditBoxes("列").Text))

その他気になった点

public cell_row as variantで定義しておりスコープ変数としています。

との記述があり、おそらくcell_rowをモジュールレベルのスコープを持つ変数として宣言しているのでしょう。
しかし、今回はEditBoxesの値をzero_cross_color()に渡すだけなので、以下のようにすれば十分かと思います。

Sub zero_cross_color(ByVal cell_row as Integer)
    '省略
End Sub

Sub 呼び出し()
    Call zero_cross_color(CInt(DialogSheets("dialog1").EditBoxes("列").Text))
End Sub

お役に立てれば幸いです。

Comments

[nonnon8.]

ありがとうございました＾＾とても分かり易かったです！自己解決フォームに解決は載せます！
本当にありがとうございます＾＾