VBA ActiveWorkbook.PrintPreviewの範囲とActiveWorkbook.ExportAsFixedFormatの出力内容が違う

Question

いつもお世話になっております。

エクセル内に「印刷シート」「アカウントデータ」の2つがあり、「アカウントデータ」シートの「pdfを作成」ボタンを押すと「印刷シート」内の変数を替えながら1,2…という名前のsheetを作成し、それをまとえてpdf化するという流れを考えております。

ひとまず実験的にアカウントデータに２つのデータを入れ、1,2という名前のシートを作成その2つをまとめたpdfが出力されるようにしようと思っているのですが、うまくいきません。

「ActiveWorkbook.PrintPreview」でプレビューを見た場合には2つのシートが選択されているのですが、ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, fileName:=fileNameでpdfを出力するとすべてのシートがpdf化してしまう状況です。

1,2という名前のシートは正しく作成されています。

下記がコードとなっております。
ご教示いただけますと幸いです。
よろしくお願いいたします。

Sub 結合pdf化()
    Dim LastRow As Long
    Dim i As Long
    Dim myNo As Long
    Dim SaveDir As String
    Dim WSH As Object
    Dim FSO As Object
    
    Dim DesktopPath As String
    
    

    If vbNo = MsgBox("pdfを作成しますがよろしいですか？", vbYesNo) Then Exit Sub

    Set WSH = CreateObject("Wscript.Shell")
    Set FSO = CreateObject("Scripting.FileSystemObject")
    DesktopPath = WSH.SpecialFolders("Desktop")
    SaveDir = DesktopPath & "\新規フォルダ\"
    Set FSO = Nothing
    Set WSH = Nothing
    
     
    ' デスクトップにフォルダがなければ作成する
    If Dir(SaveDir, vbDirectory) = "" Then
        MkDir SaveDir
    End If
    
    With Worksheets("アカウントデータ")
        LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row

        For i = 1 To LastRow

            myNo = .Range("A" & i).Value

            Worksheets("印刷シート").Range("J4").Value = myNo
            Worksheets("印刷シート").Copy After:=Worksheets(Worksheets.Count)
            ActiveSheet.Name = i
            
        Next i
    End With
    
    Dim fileName As String
    fileName = SaveDir & "新規フォルダ" & ".pdf"
 
    Dim ws As Worksheet
    For Each ws In Worksheets(Array("1", "2"))
 
        With ws.PageSetup
 
            .Zoom = False
            .FitToPagesWide = 1
            .FitToPagesTall = 1
            .PrintArea = "A1:F30"
            .CenterHorizontally = True
            .TopMargin = Application.CentimetersToPoints(1)
            .BottomMargin = Application.CentimetersToPoints(1)
 
        End With
 
    Next ws
 
    Worksheets(Array("1", "2")).Select
    'ActiveWorkbook.PrintPreview
    ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, fileName:=fileName, 
    IgnorePrintAreas:=False
    
    MsgBox "pdf作成が終わりました"

End Sub

Answer 1

出力する箇所でActiveSheetを使ってみてください。

ActiveWorkbook.ExportAsFixedFormat ～
 ↓
ActiveSheet.ExportAsFixedFormat ～

Comments

[lyzmfeqpxs54]

早速のご回答ありがとうございます。
ご教示いただいた方法で無事解決できました。

また何かの際に、ご教示いただけましたら幸いです。

[ttyp03]

前回の質問から割りと早く解決できたようでよかったです。
解決できたようなので、解決済みに設定お願いします。