VBAでカンマ区切りの文字列を分割したい

Question

以下のような文字列があります。

Dim str As String: str = "(1,2,3,4,5,6,…,55)"

これを以下のように要素数が10個ずつの文字列になるようにしたいですが方法が思いつきません。
なにかよい方法はないでしょうか?
よろしくお願いいたします。

Dim str1 As String: str1 = "(1,2,3,…10)"
Dim str2 As String: str2 = "(11,12,13,…20)"
…
Dim str5 As String: str5 = "(41,42,43,…50)"
Dim str6 As String: str6 = "(51,52,53,54,55)"

Comments

[ttyp03]

格納先は配列にしないのでしょうか？str1,str2ではなく、str(1),str(2)のように。

[kh101]

最終的に文字列として取得したいです。

[ttyp03]

いや、それはわかるのですが、
Dim str1 As String
Dim str2 As Striing
～
Dim str6 As Striing
と変数を分けないといけないのか、
Dim str2(5) As String
と配列にしてもよいのか、ということです。

Answer 1

回答待ってる間に両パターンかけてしまったので貼っておきます。

格納先変数をそれぞれ分ける場合。

Sub test()
    Dim str As String: str = "(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55)"
    Dim str1 As String
    Dim str2 As String
    Dim str3 As String
    Dim str4 As String
    Dim str5 As String
    Dim str6 As String
    Dim cols As Variant
    Dim temp() As Variant
    ReDim Preserve temp(9)
    
    cols = Split(Mid(str, 2, Len(str) - 2), ",")
    
    For i = 0 To UBound(cols)
        temp(i Mod 10) = cols(i)
        If i Mod 10 = 9 Or i = UBound(cols) Then
            ReDim Preserve temp(i Mod 10)
            Select Case Application.WorksheetFunction.RoundDown(i / 10, 0)
                Case 0: str1 = "(" & Join(temp, ",") & ")"
                Case 1: str2 = "(" & Join(temp, ",") & ")"
                Case 2: str3 = "(" & Join(temp, ",") & ")"
                Case 3: str4 = "(" & Join(temp, ",") & ")"
                Case 4: str5 = "(" & Join(temp, ",") & ")"
                Case 5: str6 = "(" & Join(temp, ",") & ")"
            End Select
            ReDim temp(9)
        End If
    Next
End Sub

格納先を配列にする場合。

Sub test2()
    Dim str As String: str = "(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55)"
    Dim str2(5) As String
    Dim cols As Variant
    Dim temp() As Variant
    ReDim Preserve temp(9)
    
    cols = Split(Mid(str, 2, Len(str) - 2), ",")
    
    For i = 0 To UBound(cols)
        temp(i Mod 10) = cols(i)
        If i Mod 10 = 9 Or i = UBound(cols) Then
            ReDim Preserve temp(i Mod 10)
            str2(Application.WorksheetFunction.RoundDown(i / 10, 0)) = "(" & Join(temp, ",") & ")"
            ReDim temp(9)
        End If
    Next
End Sub

Answer 2

()が邪魔ですが、splitで一度区切ってから、10個づつ整形し直すのが良いと思います。

ttyp03さんの仰る通り、ReDim Preserveを使いば配列の要素数を増やすことが可能な為、
配列で行うのがベストだと思います。

Answer 3

なにかよい方法

ステップで書くと

1. 対象文字列から()を取る
2. ↑で得た文字列をSplitでわける
3. ↑で得た配列の個数を得る
4. ↑を10で割り、最終的に得る文字列群の個数を得る。その個数の文字列配列を宣言
5. 文字列群の個数のForをする
6. 10回のForにする

7. 外側forのindexから判明する最終文字列群の1つの要素に対して、外側forと内側forから2.で得た配列の番地を計算し、文字列連結する