VBA 条件付き書式の一括設定

Question

条件付き書式のループ処理について質問させて下さい。

以下ソースコード
Sub test()
Dim a As Integer, b As Integer
With Sheets("プロパティ")
a = .Range("C2").Value
b = .Range("D2").Value

    With Range("D11")
    .FormatConditions.Add Type:=xlExpression, Formula1:="=AND($D11>=" & a & ",$D11<" & b & ")"
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    .FormatConditions(1).Interior.Color = 65535
    .FormatConditions.Add Type:=xlExpression, Formula1:="=$D11>=" & b
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    .FormatConditions(1).Font.Bold = True
    .FormatConditions(1).Interior.Color = 255

    With Range("E11")
    .FormatConditions.Add Type:=xlExpression, Formula1:="=AND($E11>=" & a & ",$E11<" & b & ")"
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    .FormatConditions(1).Interior.Color = 65535
    .FormatConditions.Add Type:=xlExpression, Formula1:="=$D11>=" & b
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    .FormatConditions(1).Font.Bold = True
    .FormatConditions(1).Interior.Color = 255

End sub

上記コードでD11,E11セルに対して条件付き書式の設定を行う事が出きたのですが
AG11セルまで同様の条件付き書式を設定したいのですが
1つ1つ設定するのはコード量が多くなるため出来るだけ避けたく
for文で回せないか考えたのですか、Cellsによる処理の記載方法が調べても理解が出来ませんでした。

詳しい方、ご教授お願い致します。

Answer 1

解決している問題に解答をつけるのもなんですが、対象のセルに設定する条件が同じ(要はC3セル以上かC4セル以上)ならば、ループにせずとも、セル範囲に対して条件式中の評価対象セルは絶対参照をしないように($D11の記述をD11へ)した条件付き書式をつければ済むのでは。

With Range("D11:AG11")
    .FormatConditions.Add Type:=xlExpression, Formula1:="=AND(D11>=" & a & ",D11<" & b & ")"
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    .FormatConditions(1).Interior.Color = 65535
    .FormatConditions.Add Type:=xlExpression, Formula1:="=D11>=" & b
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    .FormatConditions(1).Font.Bold = True
    .FormatConditions(1).Interior.Color = 255
End With

あとで見たときに分かりにくくなるのであまり好きな使い方ではありませんが。

Answer 2

書式設定の処理も実装してみました。

Sub test2()

    Dim a As Integer, b As Integer
    Dim row As Long
    Dim col As Long
    Dim formula1 As String
    Dim formula2 As String

    With Worksheets("プロパティ")
        a = .Cells(2, 3).Value
        b = .Cells(2, 4).Value
    End With

    ' 1('A')～33('AG')までループ
    row = 11
    For col = 1 To 33
    
        With Range(Cells(row, col), Cells(row, col))
            
            formula1 = "=AND(R" & row & "C" & col & " >= " & a & ",R" & row & "C" & col & " < " & b & ")"
            formula2 = "=R" & row & "C" & col & " >= " & b
            
            .FormatConditions.Add Type:=xlExpression, formula1:=formula1
            .FormatConditions(.FormatConditions.Count).SetFirstPriority
            .FormatConditions(1).Interior.Color = 65535
            
            .FormatConditions.Add Type:=xlExpression, formula1:=formula2
            .FormatConditions(.FormatConditions.Count).SetFirstPriority
            .FormatConditions(1).Font.Bold = True
            .FormatConditions(1).Interior.Color = 255
            
        End With
    Next

End Sub

Comments

[chihuahua_house]

ありがとうございます。
無事処理ができました。

Answer 3

こんな感じでどうでしょう。

Sub test()

Dim row As Long
Dim col As Long

row = 11
For col = 1 To 20

    With Range(Cells(row, col), Cells(row, col))
        .Value = col
    End With
Next

End Sub