World座標を基準にしたBumped Diffuseシェーダー

Question

下記の質問に回答いただいているTileShaderシェーダーをNormalmap対応したいです。
https://teratail.com/questions/90669

やりたいこととしては、大小さまざまなCubeに対し、テクスチャのタイリングのサイズを固定して表示したいです。（Cubeのサイズに応じて個別のマテリアルを作成することなく。）

よろしくお願いします。

Answer 1

手軽にやるとしたら、アルベドと同じように法線も三方向を単純合成してやればいいかと思います。

ただし一点分かりづらい点がありまして、合成比率を決めるのにワールド法線が必要になりますが、ワールド法線の取得方法としてサーフェスシェーダーの記述 - Unity マニュアルには...

float3 worldNormal; INTERNAL_DATA - サーフェスシェーダーが o.Normal に書き込む場合のワールドの反射ベクトルを含みます。ピクセル法線マップに基づいて法線ベクトルを取得するには、WorldNormalVector (IN, o.Normal) を使用します。

とあります。「反射ベクトル」は正しくは「法線ベクトル」の間違いでしょうが、それにしても前半部だけを読むとo.Normalへの書き込みを行うシェーダーでもINTERNAL_DATAを付けるだけで同様にIN.worldNormalからワールド法線を取れるように思えます。ですが実際にはどうもうまくいかず、後半部に言及されているWorldNormalVectorを使う必要があるようです。

それをふまえて、KapustinさんのTileShaderを下記のように改造してみてはいかがでしょうか?

// Upgrade NOTE: upgraded instancing buffer 'Props' to new syntax.

Shader "Custom/BumpedTileShader" {
	Properties {
		_Color ("Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_BumpMap ("Normal", 2D) = "bump" {} // 法線マップ用のプロパティを追加
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
		_TileScale ("TileScale", Range(0.1, 10)) = 1
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200

		CGPROGRAM
		// Physically based Standard lighting model, and enable shadows on all light types
		#pragma surface surf Standard fullforwardshadows

		// Use shader model 3.0 target, to get nicer looking lighting
		#pragma target 3.0

		sampler2D _MainTex;
		sampler2D _BumpMap; // 法線マップ用の変数を追加

		struct Input {
			float2 uv_MainTex;
			float3 worldPos;
			float3 worldNormal;
			INTERNAL_DATA // surf内でo.Normalへの書き込みを行っているので、INTERNAL_DATAを付ける
		};

		half _Glossiness;
		half _Metallic;
		fixed4 _Color;
		half _TileScale;

		// Add instancing support for this shader. You need to check 'Enable Instancing' on materials that use the shader.
		// See https://docs.unity3d.com/Manual/GPUInstancing.html for more information about instancing.
		// #pragma instancing_options assumeuniformscaling
		UNITY_INSTANCING_BUFFER_START(Props)
			// put more per-instance properties here
		UNITY_INSTANCING_BUFFER_END(Props)

		void surf (Input IN, inout SurfaceOutputStandard o) {
			// o.Normalへの書き込みを行っている場合はsurfの動作が変化し、IN.worldNormalからはワールド法線を取得できなくなる
			// 代わりに、接空間における凹凸なしベクトル(0, 0, 1)をワールド空間に変換しワールド法線とする
			// IN.worldNormalは使用していないためInput中のworldNormal宣言は無駄に思えるが、かといって削除してしまうとうまくいかない
			float3 worldNormal = WorldNormalVector(IN, float3(0.0, 0.0, 1.0));

			// factorX、factorY、factorZの合計が1になっていないようだったため、1にするよう変更
			float3 factor = abs(worldNormal);
			factor /= dot(factor, 1.0);

			float3 scaledWorldPos = IN.worldPos / _TileScale;

			fixed4 cx = tex2D (_MainTex, float2(scaledWorldPos.z, scaledWorldPos.y)) * factor.x;
			fixed4 cy = tex2D (_MainTex, float2(scaledWorldPos.x, scaledWorldPos.z)) * factor.y;
			fixed4 cz = tex2D (_MainTex, float2(scaledWorldPos.x, scaledWorldPos.y)) * factor.z;

			fixed4 c = (cx + cy + cz);

			// アルベドと同様に、法線も三方向からサンプリングして合成する
			float4 nx = tex2D (_BumpMap, float2(scaledWorldPos.z, scaledWorldPos.y)) * factor.x;
			float4 ny = tex2D (_BumpMap, float2(scaledWorldPos.x, scaledWorldPos.z)) * factor.y;
			float4 nz = tex2D (_BumpMap, float2(scaledWorldPos.x, scaledWorldPos.y)) * factor.z;

			float3 n = UnpackNormal(nx + ny + nz);

			o.Albedo = c.rgb;
			o.Normal = n;
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG
	}
	FallBack "Diffuse"
}

実はよく見ると凹凸部分の陰影がおかしいことにお気付きになるかもしれません。
以前別の方の類似したご質問にUnity - unityのマテリアルのサイズが一定にならない｜teratail（あちらはワールド基準ではなくオブジェクト基準でのマッピングですが、理屈としては同じです）というものがあって調査したのですが、陰影の狂いを修正するには少々ややこしいことをやらねばならなそうでした。
多少陰影がおかしくても問題ないならいいのですが、さもなければ法線の向きを正しく修正するようコードを追加する必要があるかと思います。

Comments

[nomet]

返信が遅くなりまして、大変失礼しました。
いただいたシェーダーで実行したところ、やりたいことは実現できました。
ありがとうございました。