【Access】レコードセットに渡すSQLに「LIKE検索」を使うと、レコードセットからExcel出力した際になぜか空

Question

Access for Office 365、Win10です。

テーブルデータをレコードセット経由でExcel出力してます。

レコードセットに渡す条件に、「LIKE検索」を使うと、何故かExcel側で空っぽ（列名行だけ）になります。
一意検索などその他は、問題なく出力されます。

空っぽになる際も、エラーは出ません。
LIKE検索自体は、Accessクエリで出力できたので文法的も問題ないようです。

分かる方教えていただけないでしょうか。

宜しくお願い致します。

Private Sub cmdExcelOut_Click()

    Dim strsql          As String
    
    Dim xlapp           As Object
    Dim myCn            As New ADODB.Connection
    Dim myRs            As New ADODB.Recordset
    Dim colcnt          As Integer
    
    
    On Error GoTo Err_Exit
     
    
    Dim ReturnArray As Variant
    ReturnArray = GetFileName(False, "EXCELファイル (*.xlsx,*.xls)", "Excelファイルの保存")
    If ReturnArray(0) = -302 Then
        'キャンセルボタンが押されたときの処理を記述
        Exit Sub
   
    End If
    
    
    'EXCELｱﾌﾟﾘｹｰｼｮﾝを起動
    Set xlapp = CreateObject("Excel.Application")
    
    Set myCn = CurrentProject.Connection
    
    'これはなぜかダメ
    strsql = "SELECT * FROM M_事業所 WHERE comp_name_kana Like 'カブ*'"
    
    'これはOK
    'strsql = "SELECT * FROM M_事業所 WHERE status = 0"

    'これもOK
    'strsql = "SELECT * FROM M_事業所 WHERE comp_name_kana = 'カブシキカイシャ　テスト'"
    
    Debug.Print strsql
    
    'ﾚｺｰﾄﾞｾｯﾄｵｰﾌﾟﾝ
    myRs.Open strsql, myCn, adOpenForwardOnly, adLockReadOnly
    
    
    With xlapp
        .DisplayAlerts = False
        'ｾｯﾄする過程が見えないよう一旦不可視
        .Visible = False
        
        '新しいBookを追加
        .Workbooks.Add
        .Worksheets("Sheet1").Select
        
        'ﾚｺｰﾄﾞｾｯﾄのﾌｨｰﾙﾄﾞ名（見出し）出力処理
        For colcnt = 0 To myRs.Fields.Count - 1
            .Worksheets("Sheet1").Cells(1, colcnt + 1).Value = myRs.Fields(colcnt).Name
        Next
            
        '結果値出力処理(1行目はﾍｯﾀﾞｰなので、2行目1列目からｾｯﾄ
        .Cells(2, 1).CopyFromRecordset myRs
        
        '列幅自動調整
        .Cells.EntireColumn.AutoFit
        
        '完了したら保存
        .ActiveWorkBook.SaveAs FileName:=ReturnArray
        
        MsgBox "出力しました。", vbOKOnly + vbInformation
        
        .DisplayAlerts = True
    End With
    
    Set myRs = Nothing: Close
    Set myCn = Nothing: Close
    
    'Excelを終了します
    xlapp.Quit
    
    
    
    
    Exit Sub
    
Err_Exit:
    MsgBox Err.Number & ":" & Err.Description, vbOKOnly + vbCritical, "OutputExcel()"
    Set myRs = Nothing: Close
    Set myCn = Nothing: Close
    xlapp.Quit
End Sub

Answer 1

ADOでのワイルドカードは'*'ではなく%です。

SELECT * FROM M_事業所 WHERE comp_name_kana Like 'カブ%'

Comments

[pecchan]

sazi様
有難う御座います。

入れ違いになってしまいました！
すみません。有難う御座います！

Answer 2

下記を参考に自己解決しました。

http://ivystar.jp/ms-office/access/wild-card-and-ado-access-is-different/

*→%
に変えることで取得出来ました。