Imageの保存が出来ない

Question

※当方C#も読めるというのと、C#の方が人口が多いだろうという理由でタグをつけました。
C#での回答も歓迎しております。

前提・実現したいこと

PCに接続したカメラで画像を撮影、保存するプログラムを作成しています。
ですが、たまに例外が出て保存ができない時があります。
保存できない条件が判明していないため、「こういった場合だと保存出来ないことがある」等の
アドバイスがございましたら、ご教授いただければ幸いです。

発生している問題・エラーメッセージ

GDI+ で一般的なエラーが発生しました

   場所 System.Drawing.Image.Save(String filename, ImageCodecInfo encoder, EncoderParameters encoderParams)
   場所 System.Drawing.Image.Save(String filename, ImageFormat format)
   場所 ***.SaveShotImage() 場所 ***.vb:行 664

該当のソースコード

コード一部抜粋(保存先は本来コンフィグファイルで設定していますが、今は固定で入れています)

    Private Sub SaveShotImage()
        Dim saveDir As String
        Dim savePath As String
        For Each data As DataDto In DataDtoList
            If data.SnapShotImage Is Nothing Then Continue For

            Try
                saveDir = System.IO.Path.Combine("C:\Users\MYNAME\Desktop", Strings.Format(Now, "yyyyMMdd"))
                If Not System.IO.Directory.Exists(saveDir) Then System.IO.Directory.CreateDirectory(saveDir)

                Do
                    savePath = System.IO.Path.Combine(saveDir, Strings.Format(Now, "yyMMddHHmmss") & ".jpg")
                    If Not System.IO.File.Exists(savePath) Then Exit Do
                Loop

                data.SnapShotImage.Save(savePath, Imaging.ImageFormat.Jpeg) 'ここで落ちる
            Catch ex As Exception
                Throw New Exception("画像保存に失敗しました。" & ex.Message, ex)
            End Try

            data.ImageFilePath = savePath
        Next
    End Sub

DataDto.vb

Namespace Test

    Public Class DataDto

#Region "プロパティ"

        ''' <summary>画像ファイルパス</summary>
        Public Property ImageFilePath As String

        ''' <summary>画像格納用(スナップショット格納用)</summary>
        Public Property SnapShotImage As System.Drawing.Image = Nothing

#End Region

#Region "メソッド"

        ''' <summary>
        ''' データをコピーする
        ''' </summary>
        ''' <param name="target">コピー先対象</param>
        ''' <remarks></remarks>
        Public Sub CopyData(ByRef target As DataDto)
            target.ImageFilePath = ImageFilePath
            target.SnapShotImage = SnapShotImage?.Clone
        End Sub

        ''' <summary>
        ''' データをクリアにする
        ''' </summary>
        ''' <remarks></remarks>
        Public Sub Clear()
            ImageFilePath = Nothing
            SnapShotImage = Nothing
        End Sub

        ''' <summary>
        ''' 同一データの作成(別インスタンス)
        ''' </summary>
        ''' <remarks></remarks>
        Public Function Clone() As DataDto
            Dim dto As New DataDto With {
                .ImageFilePath = ImageFilePath,
                .SnapShotImage = SnapShotImage?.Clone
            }

            Return dto
        End Function

#End Region

#Region "コンストラクタ"

        Public Sub New()
            Me.Clear()
        End Sub

#End Region

    End Class

End Namespace

他にこういった個所のコードを開示してほしい等ありましたら随時開示いたします。

試したこと

書き込み権限が無い→保存できる時とできない時があるので権限が無いわけではなさそうです。
imageインスタンスのデータがおかしい→保存できる時とできない時でのデータに差はなさそうです。

補足情報（FW/ツールのバージョンなど）

VB 2012
.NET Framework 4

どうぞよろしくお願いいたします。

追記1

カメラの実装部分です。

Imports System.Drawing
Imports System.Runtime.InteropServices

#Region "Private変数"

        Private mGrp As IGraphBuilder       'グラフ
        Private mFlt As IBaseFilter         'キャプチャフィルタ
        Private mPin As IPin                'キャプチャフィルタの出力ピン
        Private mSmp As ISampleGrabber      'サンプルグラバフィルタ

        Private mSize As Size               '映像サイズ
        Private mBuff As IntPtr             'ビットマップ取得用バッファ

        Private mFmt As PIXELFORMATYPE      'ピクセル形式

        Private mVisible As Boolean         'カメラ映像を表示するか？

#End Region

'----一部省略----

        Public Function snapShot() As Bitmap
            If mGrp Is Nothing Or mSmp Is Nothing Then Throw New Exception("キャプチャーが取得できません。")

            'イメージの取得
            Try
                '画像データサイズ取得
                Dim bmpsz As Integer = 0
                mSmp.GetCurrentBuffer(bmpsz, IntPtr.Zero)

                '画像取得領域確保
                Dim bmpptr As IntPtr = Marshal.AllocHGlobal(bmpsz)

                'イメージ取得
                mSmp.GetCurrentBuffer(bmpsz, bmpptr)

                '画像サイズを取得
                Dim vsz As Size
                vsz = GetVideoSize(mGrp)
                '描画
                Dim bmpdata As Bitmap
                bmpdata = New Bitmap(vsz.Width, vsz.Height, vsz.Width * 3, Imaging.PixelFormat.Format24bppRgb, bmpptr)
                bmpdata.RotateFlip(RotateFlipType.RotateNoneFlipY) '上下反転させる

                snapShot = bmpdata
            Catch ex As Exception
                Throw New Exception("スナップショットに失敗しました。" & " : " & ex.Message, ex)
            End Try
        End Function

追記2

色々調べてIDisposable実装してみました……。
これでうまく動くのが一番理想ですがまだ動きません……。

DataDto.vb

    Public Class DataDto
        Implements IDisposable

#Region "プロパティ"

        ''' <summary>画像ファイルパス</summary>
        Public Property ImageFilePath As String

        ''' <summary>画像格納用(スナップショット格納用)</summary>
        Public Property SnapShotImage As System.Drawing.Image = Nothing

#End Region

#Region "メソッド"

        ''' <summary>
        ''' データをコピーする
        ''' </summary>
        ''' <param name="target">コピー先対象</param>
        ''' <remarks></remarks>
        Public Sub CopyData(ByRef target As DataDto)
            target.ImageFilePath = ImageFilePath
            target.SnapShotImage = SnapShotImage?.Clone
        End Sub

        ''' <summary>
        ''' データをクリアにする
        ''' </summary>
        ''' <remarks></remarks>
        Public Sub Clear()
            ImageFilePath = Nothing
            SnapShotImage = Nothing
        End Sub

        ''' <summary>
        ''' 同一データの作成(別インスタンス)
        ''' </summary>
        ''' <remarks></remarks>
        Public Function Clone() As DataDto
            Dim dto As New DataDto With {
                .ImageFilePath = ImageFilePath,
                .SnapShotImage = SnapShotImage?.Clone
            }

            Return dto
        End Function

#End Region

#Region "コンストラクタ"

        Public Sub New()
            Me.Clear()
        End Sub

#End Region

#Region "IDisposable Support"
        Private disposedValue As Boolean ' 重複する呼び出しを検出するには

        ' IDisposable
        Protected Overridable Sub Dispose(disposing As Boolean)
            If Not disposedValue Then
                If disposing Then
                    SnapShotImage.Dispose()
                End If

                ' TODO: アンマネージド リソース (アンマネージド オブジェクト) を解放し、下の Finalize() をオーバーライドします。
                ' TODO: 大きなフィールドを null に設定します。
            End If
            disposedValue = True
        End Sub

        ' TODO: 上の Dispose(disposing As Boolean) にアンマネージド リソースを解放するコードが含まれる場合にのみ Finalize() をオーバーライドします。
        Protected Overrides Sub Finalize()
            ' このコードを変更しないでください。クリーンアップ コードを上の Dispose(disposing As Boolean) に記述します。
            Dispose(False)
            MyBase.Finalize()
        End Sub

        ' このコードは、破棄可能なパターンを正しく実装できるように Visual Basic によって追加されました。
        Public Sub Dispose() Implements IDisposable.Dispose
            ' このコードを変更しないでください。クリーンアップ コードを上の Dispose(disposing As Boolean) に記述します。
            Dispose(True)
            ' TODO: 上の Finalize() がオーバーライドされている場合は、次の行のコメントを解除してください。
            GC.SuppressFinalize(Me)
        End Sub
#End Region

    End Class

    Private Sub SaveShotImage()
        Dim saveDir As String
        Dim savePath As String
        For Each data As DataDto In DataDtoList
            If data.SnapShotImage Is Nothing Then Continue For

            Try
                saveDir = System.IO.Path.Combine("C:\Users\MYNAME\Desktop", Strings.Format(Now, "yyyyMMdd"))
                If Not System.IO.Directory.Exists(saveDir) Then System.IO.Directory.CreateDirectory(saveDir)

                Do
                    savePath = System.IO.Path.Combine(saveDir, Strings.Format(Now, "yyMMddHHmmss") & ".jpg")
                    If Not System.IO.File.Exists(savePath) Then Exit Do
                Loop

                Using image As New Bitmap(data.SnapShotImage)
                    image.Save(savePath, Config.ImageFormat) ' ここで落ちる
                    image.Dispose()
                    data.Dispose()
                End Using
            Catch ex As Exception
                Throw New Exception("画像保存に失敗しました。" & ex.Message, ex)
            End Try

            data.ImageFilePath = savePath
        Next
    End Sub

Comments

[izmktr]

例外が出るのであれば、出ている例外のメッセージも添えてください

[heart_crimson]

メッセージありがとうございます。exceptionのMesseageは「GDI+ で汎用エラーが発生しました。」のみです。スタックトレースについては追記しましたのでご確認のほどよろしくお願いいたします。

Answer 1

ファイル名に半角スラッシュが入っているのが原因のようでした。
出力する際、ファイル名として使えない半角スラッシュが入っているため、
正常にファイルを出力出来ず、例外が出ているようでした。
エラー内容が「GDI+で汎用エラーが発生しました。」であるため、
画像ファイルが何か悪さをしているのだとすっかり勘違いしておりました。

皆様のお時間頂戴して申し訳ございませんでした。
この度は様々なご意見をいただき、誠にありがとうございました。

Answer 2

Do...Loop内で、現在時刻でファイル名を生成し、それが存在する場合は次の秒まで待つ、といったことをしていますが、その間にdata.SnapShotImageが利用不可（Disposeされている等）となってはいませんか？
そもそも、このDo...Loopの使い方は無駄にループを行っているため、あまり良い方法とは言えません。

例えば、System.IO.Path.GetRandomFileNameのようなものでランダムなファイル名を生成し、即座に保存してみてもエラーが発生しますか？

ところで、data.SnapShotImageには、具体的にどのような形式の画像データが入っているのでしょうか？

Comments

[heart_crimson]

コメントありがとうございます。Do～Loopをコメントアウトし、「savePath = System.IO.Path.Combine(saveDir, System.IO.Path.GetRandomFileName)」とすると、例外が出なくなりました。「Loopしている間にSnapShotImageが利用不可になっている」という点に心当たりが無く判断ができないのですが、本文に書きました通りFor Each外でやると問題無く出力出来ますので、原因は恐らくこれなのでしょうか。
ループは無駄だろうなとは薄々感じていたのですが、思いつかずにこのままで放置しておりました。時間以外の部分でファイル名を一意に出来ないか考えます。
もう少しDispose周辺も見直してみて、扱えなさそうでしたらこちらを採用しようと思います。ベストアンサーはしばらくお待ちください。
カメラ周辺の実装はまだきちんと目を通せてないのですが、追記しますので、恐れ入りますがご確認いただけますでしょうか。

Answer 3

Image.Save()でのエラー
原因は色々あるようですが、とりあえず新しいBitmapを作ってみては？

(new Bitmap(data.SnapShotImage)).Save(savePath, ImageFormat.Jpeg)

Comments

[heart_crimson]

コメントありがとうございます。記載してくださったコードを参考に(質問文追記)直してみたのですが、同様の例外が出てしまいます。他に心当たりはございませんか？　提示していただいたサイトも拝見したのですが、このdata.SnapShotImageはまだファイルにしていないImage型のデータであり、ストリームで開いていないため、「ストリームが閉じている」という原因にピンと来ておりません。申し訳ありません。

Answer 4

ぱっと思いつくのは2つぐらいです。
1.data.SnapShotImage　の 元のStream が閉じてしまっている。
2.data.SnapShotImage　を破棄してないためGDI+のリソース不足。

1の場合はdata.SnapShotImageから新しく、Bitmapを生成して保存してください。
2は、data.SnapShotImage　を　Dispose　してください。

Comments

[heart_crimson]

コメントありがとうございます。質問なのですが、SnapShotImageをDisposeしてから、どうすればよいのでしょうか？　DisposeしてしまったらそのインスタンスでSaveは出来ませんよね？

[hihijiji]

使う前ではなく、使った後に Dispose してください。

[heart_crimson]

data.SnapShotImage.Save(...)してから、FinallyでDisposeする、ということでしょうか？

[hihijiji]

原則 生成から破棄までを Using で括ります。
IDisposeの実装を除いて、別の場所でDisposeするのはお勧めしません。
逆に言うと、Using で括れるように考えてコードを書くことが大切です。

[heart_crimson]

コードを書いてみましたが、やはりsaveで例外が発生します。追記しましたので、恐れ入りますがご覧いただけますでしょうか。

[hihijiji]

DataDtoList の定義と生成を書いてください。

[heart_crimson]

「Private DataDtoList As New SortableBindingList(Of DataDto)」　です。それ以外でDataDtoListをNewしている所はありません。

[hihijiji]

Dispose を実装しているリソースは、極力フィールドに持たずに都度生成-破棄するか、引数で受渡ししてください。
さらにそのコレクションをフィールドにするともっと厄介です。
フィールドに持つ場合は、そのクラスでIDisposeを実装して、フィールドのリソースをDisposeする必要があります。

[hihijiji]

VB 2012 でしたね。
前記の Is Nothing Then云々は間違いです。

[heart_crimson]

色々調べてみたのですが、IDisposeがまだ十分理解出来ておりません。大変申し訳ありません。DataDtoListにIDisposeにImplements IDisposableをして、Visual Studioに自動実装してもらって、Dispose(disposing As Boolean)内にSnapShotImage.Dispose()を書けばいいのでしょうか？

[hihijiji]

DataDto から見直すと良いと思います。