processingでの直方体の絵画とカメラの視点固定ができない

Question

プログラミング初心者です。

box(100,150,150)の中心をカメラの視点として固定したいのですが、box(10,15,10)の中心に注視点が固定されているようです。
どのようにするといいのでしょうか。。。

又、box(10,15,10)をbox(100,150,150)内の左下奥に配置し、その隣にbox(30,50,10)を配置するにはどうするとよいのでしょうか。。。
実際にやってみたのですがうまくいきません(泣

float camX = 0, camY = 0;
// cspped
float speed = 12;

void setup() {
  size(960, 540, P3D);
 
}

void draw() {
  background(255);
  translate(width/2, height/2, 0);//座標中心

  // cmove
  if (keyPressed) {
    if (keyCode == LEFT) camX -= speed;
    if (keyCode == RIGHT) camX += speed;
    if (keyCode == UP) camY -= speed;
    if (keyCode == DOWN) camY += speed;
  }
  // cset
  camera(camX, camY, 200, 0, 0, 0, 0, 1, 0);
  //parette
  stroke(0);
  noFill();
  box(100,150,150);
  //nimotsu1
  stroke(0);//nitsu1
  noFill();
  box(10,15,10);
  box(30,50,10);
  

  stroke(255, 0, 0);
  line(0, 0, 0, 500, 0, 0);
  stroke(0, 255, 0);
  line(0, 0, 0, 0, 500, 0);
  stroke(0, 0, 255);
  line(0, 0, 0, 0, 0, 500);
}
````コードの表示()`

Comments

[KSwordOfHaste]

(A)別の立方体に視点がされている
「視点がされている」という表現だと何を意味するかはっきりわかりません。ちなみに視点はカメラがある位置で、注視点はカメラが狙っている位置です。(A)は「注視点」でしょうか？「視点」でしょうか？いずれにしても意味が通じない気がします。本コードの全てのboxの中心は同じ(座標原点)だからです。(A)が何を意味するか質問文を編集して補足してほしいです。

[15meisei136]

修正補足致しました！

Answer 1

P3Dは得意じゃありませんが。

box(100,150,150)の中心をカメラの視点として固定したいのですが、box(10,15,10)の中心に注視点が固定されているようです。

なんか日本語としてよくわからないのですが。固定したいのは視点で、なぜそこで注視点の話になるのでしょう? しかも、プログラムのカメラ設定camera(camX, camY, 200, 0, 0, 0, 0, 1, 0);からはその意図が読み取れないのですが...どの辺が「固定したい」の指定?

それはともかく。

box(10,15,10)をbox(100,150,150)内の左下奥に配置し、その隣にbox(30,50,10)を配置するにはどうするとよいのでしょうか

の方が話が先な気がします。だって、これが出来ないとbox(10,15,10)の場所が特定出来ないのですから。ところで「隣」っていろいろ考えられるけど。

boxは常に座標原点の周りに描画されるわけで、だから位置指定がなくてサイズ情報だけなんですよね。だとすればtranslateで適切な位置に原点を移動して、その位置を中心にboxを描画することになるのでは。

cameraのデフォルトがY軸正方向が上なので、「左下奥」ってどっちよ? となってしまうのですがカメラをZ軸正方向を"上"に設定してx軸は右が正、y軸は手前が正とするように見るなら、box(X,Y,Z)の-X/2,-Y/2,-Z/2が左下奥ということになるはずです。

とにかく描いてみると、こんな感じ?

void setup(){
  size(960,540,P3D);
  noFill();
}

boolean once=false;
void draw(){
  background(255);
  translate(width/2,height/2,0);
//ここを基準座標としてカメラを設定後pushして保存、popして回復しながら描いていく
  camera(
  100/2,150/2,150/2,//カメラ位置(視点)=box(100,150,150)の中心
  10/2,15/2,10/2,//カメラ注視点=box(100,150,150)の左下隅のbox(10,15,10)の中心
  0,0,-1);//Z軸正方向が上

  pushMatrix();
  translate(100/2,150/2,150/2); //左下奥隅が保存した原点になるように配置
  box(100,150,150);
  popMatrix();

  pushMatrix();
  translate(10/2,15/2,10/2); //左下奥隅にbox(10,15,10)を配置
  box(10,15,10);
  popMatrix();

  pushMatrix();
  translate(10+30/2,50/2,10/2); //隣(適当に決めた)にbox(30,50,10)を配置
  box(30,50,10);
  popMatrix();
}

camera()をいじるとなにか内部状態も変わっちゃうみたいで、Processingで3Dグラフィックスを扱う上での注意点 "camera()の挙動"あたりを見てみるもいろいろ難しそう...

---

注視点を移動してみました。

void setup() {
  size(960, 540, P3D);
  textSize(8);
  textAlign(CENTER, CENTER);
}
float x=10./2;
float y=15./2;
float z=10./2;

float vx=1;
float vy=1.3;
float vz=0.7;

boolean once=false;
void draw() {
  background(255);
  translate(width/2, height/2, 0);
  //ここを基準座標としてカメラを設定後pushして保存、popして回復しながら描いていく
  camera(
    100./2, 150./2, 150./2, //カメラ位置(視点)=box(100,150,150)の中心
    x, y, z, //カメラ注視点=box(100,150,150)の左下隅のbox(10,15,10)の中心
    0, 0, -1);//Z軸正方向が上

  pushMatrix();
  //注視点移動
  x=x+vx;
  y=y+vy;
  z=z+vz;
  if (x<0 || x>100) {
    vx*=-1;
  }
  x=constrain(x, 0, 100);
  if (y<0 || y>150) {
    vy*=-1;
  }
  y=constrain(y, 0, 150);
  if (z<0 || z>150) {
    vz*=-1;
  }
  z=constrain(z, 0, 150);

  translate(x, y, z); //注視点
  noStroke();
  fill(192);
  sphere(3);
  text(String.format("%.1f, %.1f, %.1f", x, y, z), 0, 5, -5);
  popMatrix();

  pushMatrix();
  translate(100./2, 150./2, 150./2); //左下奥隅が保存した原点になるように配置
  noFill();
  stroke(0);
  box(100, 150, 150);
  popMatrix();

  pushMatrix();
  translate(10./2, 15./2, 10./2); //左下奥隅にbox(10,15,10)を配置
  noFill();
  stroke(0, 255, 0);
  box(10, 15, 10);
  popMatrix();

  pushMatrix();
  translate(10+30./2, 50./2, 10./2); //隣(適当に決めた)にbox(30,50,10)を配置
  noFill();
  stroke(0, 0, 255);
  box(30, 50, 10);
  popMatrix();
}