for文に変数を入れる方法

Question

前提・実現したいこと

初心者なので変なことをしていてもお許しください。
現在バッチファイルを使って特定の名前のディレクトリ作成を複数行おうと思っています。
ですが、for文をうまく使えないため、ディレクトリの作成を名前の分だけだらだら書いていてしつこいような形になっています。例えば下記のようなコードになります。
またそれぞれmkdirのあとにデータを移動する命令文等が入ります。

該当のソースコード

mkdir C:\Users\りんご
...
mkdir C:\Users\バナナ
...
mkdir C:\Users\みかん
...

他10種類ほど入ります。

試したこと

事前に入れたい名前はわかっているので（りんご、バナナなど）
変数（数字）に名前を入れてfor文で組もうと思いましたが、上手くいきませんでした。
確認で使ったコードが下記です。

set 1=りんご
set 2=バナナ
set 3=みかん
for /l %i in (1,1,3) do echo %%i%

で試したところ、
%1%
%2%
%3%
となりました。forの値と変数にした数字の値では同じにならないっていうのはわかったのですが、for文の中に変数を入れる（または決まった名前を順番に入れる）方法がありましたらご教示ください。
よろしくお願いいたします。

補足情報（FW/ツールのバージョンなど）

windows10

Answer 1

@echo off
setlocal enabledelayedexpansion

set LIMIT=2
set ARRAY[0]="りんご"
set ARRAY[1]="ばなな"
set ARRAY[2]="みかん"

for /l %%n in (0,1,!LIMIT!) do (
  echo !ARRAY[%%n]!
)

Comments

[arcana]

こちらの例が配列のようにしているコードですね・・勉強になります！
ありがとうございました。

Answer 2

配列っぽいことを考えているようですが、、バッチファイルで配列っぽいことをするのは割と高度なテクニックが必要なので、単純に名前をそのまま使って処理した方が簡単です。

例1

for %%A in (りんご バナナ みかん ……) do (
	mkdir C:\Users\%%A
	何かの処理
		:
		:
)

例2

call :proc りんご
call :proc バナナ
call :proc みかん
	:
	:
goto :eof

:proc
mkdir C:\Users\%1
何かの処理
	:
	:
goto :eof

Comments

[arcana]

例1のやり方が単純で一番わかりやすかったです！
ありがとうございました。

[arcana]

ちなみに例１で「りんご　１」のように空白を入れたい場合はどのようにすれば宜しいでしょうか？""で囲うと「"りんご　1"」と表示されてしまいます・・。

[catsforepaw]

""でくくるのは正しいやり方です。基本的にはそのまま""でくくられた状態でコマンドに渡しても問題ないのですが(というか、特にファイルパスの場合はそうしないと問題になる場合が多い)、外したい場合は「%%~A」のように「~」(チルダ)を入れて渡せば良いです。

Answer 3

例えばファイルを使う方法として、以下のようにも実現できます。

@echo off

cd /d %~dp0

set ROOTDIR=C:\Users

for /f %%s in (list.txt) do (
	mkdir %ROOTDIR%\%%s
)

list.txtというファイルに、以下のように作成したいフォルダの一覧を記載して、batと同じフォルダに置いて実行すればOKです。

りんご
バナナ
みかん

Comments

[arcana]

この方法なら情報の追加も簡単そうですね！
ありがとうございました。