ＶＢＡでCSVから読み込んだものをすべてセルに入れる

Question

csvを読み込んだものを配列にし、セルの範囲を指定しないで入れたいのですがどうしたらよろしいでしょうか？

「Range("A10:D10") = tmp」このようにセルの範囲を指定をせずにCSVに入ってる情報すべてを貼り付けたいです。

foreachを使えばよろしいでしょうか？

csvの中身は
yamada,山田,[e-mail]
suzuki,鈴木,[e-mail]

Sub csv読み込み()
Dim buf As String, tmp As Variant, n As Long
Open "user.csv" For Input As #1
Do Until EOF(1)
Line Input #1, buf
tmp = Split(buf, ",")
Loop
Close #1

Range("A10:D10") = tmp
End Sub 

Answer 1

CopyFromRecordset で貼り付けたらどうでしょうか。

Microsoft ActiveX Data Object #.# Library に参照設定

    Dim Cn As New ADODB.Connection
    Dim RS As New ADODB.Recordset

    With Cn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .Properties("Extended Properties") = "Text;HDR=NO"
        .Open "G:\TEST\"
    End With

    Set RS = Cn.Execute("SELECT * FROM tera16369.csv")

    Range("A10").CopyFromRecordset RS
    
    RS.Close: Set RS = Nothing
    Cn.Close: Set Cn = Nothing

Answer 2

色々な実装方法がありますので、一例をご紹介致します。

Sub csv読み込み()
    
    Dim oFileSys As Object
    Dim oTxtStream As Object
    Dim sPath As String
    Dim sFile As String
    Dim sTxt As String
    Dim s As Variant
    Dim I As Integer
    
    ' CSVファイル一括読み込み
    Set oFileSys = CreateObject("Scripting.FileSystemObject")
    sPath = ThisWorkbook.Path
    sFile = oFileSys.BuildPath(sPath, "user.csv")
    Set oTxtStream = oFileSys.OpenTextFile(sFile, 1)
    
    If oTxtStream.AtEndOfStream = False Then
        sTxt = oTxtStream.ReadAll
    End If
    
    oTxtStream.Close
    Set oTxtStream = Nothing
    Set oFileSys = Nothing
    
    With ActiveSheet
        'csvデータ貼り付け
        I = 0
        For Each s In Split(sTxt, vbCrLf)
            I = I + 1
            .Cells(I, 1).Value2 = s
        Next s
        
        ' 区切り位置調整
        .Cells(1, 1).Resize(I).TextToColumns Comma:=True
    End With
    
End Sub

＜簡単な説明＞
0. Excelブックと同じフォルダに存在する「user.csv」をテキストファイルとしてオープンし一括読み込み
0. 行単位に分割し A1 セルから順に列方向に貼り付け
0. 区切り位置の調整（TextToColumns）でカンマ区切りを指定

Answer 3

こんにちは。

貼り付けについて回答します。
速度の面から言って範囲貼り付けで良いと思います。

固定で指定するのではなく変数に格納された配列数から動的に範囲を指定してみてはどうでしょう。

Sub 貼り付け()
    Dim tmp As Variant
    tmp = Csv読み込み()
    Const row As Integer = 1
    Const startCol As Integer = 1
    
    Range(Cells(row, startCol), Cells(row + UBound(tmp, 1), startCol + UBound(tmp, 2))) = tmp
End Sub

Function Csv読み込み() As Variant
    Dim value(1, 2) As String
    
    value(0, 0) = "yamada"
    value(0, 1) = "山田"
    value(0, 2) = "[e-mail]"
    
    value(1, 0) = "suzuki"
    value(1, 1) = "鈴木"
    value(1, 2) = "[e-mail]"
    
    Csv読み込み = value
    
End Function

CSV読み込みについてはそれ上手くいってますか？
ループごとにセル出力するか、ループの中で多次元配列を組み立てるか検討してみてください。

http://www.moug.net/tech/exvba/0060086.html

うまくいってるのであれば余計でした。すみません。

Answer 4

こんにちは。

「配列に読み込んで、それを貼り付ける」という方法からは外れてしまいますが、
CSVファイルをワークブックとして読み込んで(少し表現がおかしいかも知れませんが.)
そこから貼り付けをする方法もあるかと思いましたので、投稿させてもらいました。

対象のCSVファイルがExcelでオープンできる事が前提になります。

Excel 2010で確認しています

Sub PasteFromCSV()
  Const CSV_FILE = "d:\test\sample.csv"
  Dim ReadWBk As Workbook
  Dim WriteWBk As Workbook
  Dim WriteSht As Worksheet
  Dim Rng As Range
  
  '貼り付け先をアクティブなシートとする
  Set WriteWBk = ActiveWorkbook
  Set WriteSht = WriteWBk.ActiveSheet
  
  '対象のCSVファイルをオープンし、値の入っている範囲をコピー
  Set ReadWBk = Workbooks.Open(CSV_FILE)
  Set Rng = ReadWBk.Worksheets.Item(1).UsedRange
  Rng.Copy
  
  '指定のセル(A10)を起点として貼り付け(形式を選択して貼り付け→値)
  WriteSht.Range("A10").PasteSpecial xlPasteValues, xlPasteSpecialOperationNone, False, False
  
  'CSVファイルをクローズ
  ReadWBk.Close
  Set ReadWBk = Nothing
End Sub