エクセルのセルに入っている数字とその座標を出力するマクロ（ＶＢＡ）

Question

シート上の指定したセルのアドレスを(1,A)→(1,1),(1,B)→(1,2)...というふうに (列番号,行番号) の形にし、さらにセルに入っている数字をその後に付け足して(列番号、行番号、数字)の形にしてCSVファイルに出力したいです。
※エクセルでは普通は (行番号,列番号) ですが、xy座標なので (列番号,行番号) と考えてください(^_^;)

単数字（たとえば1）を入力してそのxy座標を取り出すようなマクロは

Sub NumberOnes()
Dim buf As String
Dim rng As Range

buf = ""
For Each rng In ActiveSheet.UsedRange
If rng.Value = 1 Then _
buf = buf & """(" & rng.Column & "," & rng.Row & ")"","
Next
buf = Left(buf, Len(buf) - 1)

Open ThisWorkbook.Path & "\data.csv" For Output As #1
Print #1, buf
Close #1
End Sub

なのですが、つまり、これをシート上の1～50の数字に対して同時に実行し、1つのCSVファイルに(列番号、行番号、数字)を出力したいということです。

マクロに詳しい方、よろしくお願いいたします(>_<)

Comments

[takito]

例となる実際のエクセルシート（入力）とＣＳＶファイルの完成形（出力）を手作りし、それらのイメージを張りつけていただくと、やりたいことの理解が早くよい回答が得られると思いますよ

Answer 1

色々な実装方法があると思いますので、処理対処のセル範囲を一旦配列に読み込んでしまってから一括処理する方式にしてみました。

Sub NumberOnes()

    Dim buf() As String
    Dim uRng As Range, vRng As Variant
    Dim endRow As Long, endCol As Long
    Dim num As Long, val As Long
    Dim i As Long, j As Long
    

    ' num までの整数を探してcsv出力
    num = 50
    ReDim buf(1 To num)
    
    ' "A1"からデータ入力済みの"最終行/列"までの入力データをvRngへ取り込む
    With ActiveSheet
        Set uRng = .UsedRange
        endRow = uRng.Row + uRng.Rows.Count - 1
        endCol = uRng.Column + uRng.Columns.Count - 1
        Set uRng = Nothing
        vRng = .Range(.Cells(1, 1), .Cells(endRow, endCol)).Value
    End With
    
    ' 入力値が整数で１～num の範囲に入っていたらcsv出力する
    ' i：行番号、j：列番号
    For i = 1 To UBound(vRng, 1)
        For j = 1 To UBound(vRng, 2)
        
            ' データが数値の場合のみ対象
            If WorksheetFunction.IsNumber(vRng(i, j)) Then
                val = vRng(i, j)
                
                ' データが整数かつ１以上num以下の場合のみ対象
                If val = Int(val) And 1 <= val And val <= num Then
                    buf(val) = CStr(i) & "," & CStr(j) & "," & CStr(val)
                End If
                
            End If
            
        Next j
    Next i
    
    ' 結果をcsvファイルへ出力
    Open ThisWorkbook.Path & "\data.csv" For Output As #1
    For i = 1 To num
        If buf(i) = "" Then Exit For
        Print #1, buf(i)
    Next i
    Close #1
    
End Sub

文字列や小数などが入力されていた場合は無視し、整数のみを出力します。

Answer 2

まず値が１のセルのリスト、次に値が２のセルのリスト、次に値が3のセルのリスト、……、最後に値が50のセルのリストという形式のcsvファイルを作るプログラムを求めていらっしゃるのではないでしょうか。
だとすれば、以下のようなプログラムになります。

Sub NumberOnes()
  Dim buf(1 to 50) As String, result as String
  Dim rng As Range
  Dim num as Integer

  'リストを記録する文字列の配列を初期化する
  for num = 1 to 50
    buf(num) = ""
  next num

  'セルの値が1～50の間なら、その値に対応する文字列にセルの列、行、値を追加する。
  For Each rng In ActiveSheet.UsedRange
    num=rng.Value
    If (0 < num And num < 51) Then
      buf(num) = buf(num) & """(" & rng.Column & "," & rng.Row & "," & num & ")"","
    EndIf
  Next

  '値ごとのリストを１つの文字列 result にまとめる
  result=""
  for num=1 to 50
    result = result & buf(num)
  next

  ’最後の","を取り除く
  '  1～50のセルが１つも無かった場合はresultが空文字列となるので、エラーが起きないようにIfで判断
  if result<>"" Then
    result= Left(result, Len(result) - 1)
  EndIf

  Open ThisWorkbook.Path & "\data.csv" For Output As #1
  Print #1, result
  Close #1
End Sub

Answer 3

理解が間違っていたらすみませんが、
質問者様のコードでほぼ答えは出ているのではないでしょうか？

数字が1-50と決まっているのであれば

Sub NumberOnes()
Dim buf As String
Dim rng As Range

buf = ""
For Each rng In ActiveSheet.UsedRange
If (0 < rng.Value And rng.Value < 51) Then _
buf = buf & """(" & rng.Column & "," & rng.Row & "," & rng.Value & ")"","
Next
buf = Left(buf, Len(buf) - 1)

Open ThisWorkbook.Path & "\data.csv" For Output As #1
Print #1, buf
Close #1
End Sub

これでどうでしょうか？