ExcelVBAで、呼び出す関数に与える引数が、関数側で初期化される

Question

すみません。長くなります。

特定のフォルダにあるBASファイルをインポートするマクロを作成しています。
0. 特定フォルダのファイルコレクションを取得する
0. 各ファイルコレクションのファイル名をチェックして、それがブックに存在すれば削除してからインポート、なければ単純にインポートする

嵌ってるところ

importer()という、2.のロジックが記述されているサブルーチンがあるのですが、ここで、ファイルチェックを関数checkBasExist()に処理が移る際に、引数が初期化? ""になります。

具体的に、checkBasExist(flist(i))で関数を呼ぶ際、
flist(i) = "hoge.bas" という値があることはデバック機能で確認できてます。
しかし、checkBasExist(bas)内では、bas = "" になってしまいます。

解決したいこと

何故こうなってしまうのか知りたい。

Option Explicit
Dim TARGET_PATH As String

Sub removeMod(bas As String)
    'モジュール削除
    ThisWorkbook.VBProject.VBComponents.Remove ThisWorkbook.VBProject.VBComponents(bas)
End Sub

Sub importMod(bas As String)
    'モジュールインポート
    ThisWorkbook.VBProject.VBComponents.Import bas
End Sub

'Function checkBasExist(bas As String) As Boolean
Function checkBasExist(ByVal bas As String) As Boolean
    'ブック内の各モジュールに、引数で指定したモジュールが存在するかどうかを返す
    Dim i As Integer
    With ThisWorkbook.VBProject
        For i = 1 To .VBComponents.Count
            If .VBComponents(i).Type = 1 Then
                If .VBComponents(i).Name = bas Then
                    checkBasExist = True
                    Exit Function
                End If
            End If
        Next
        checkBasExist = False
    End With
End Function

Function whatImport(w)
    'フォルダー内のbasファイルから、指定のbasを除いた名前一覧を返す
    Dim fso, fs As Object
    Dim tmp() As String
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set fs = fso.GetFolder(w).Files
    
    tmp = hyFolderer.convertFilesToStrs(fs)
    whatImport = hyStr.removeElementOfList("importBas.bas", tmp)
    
    Set fso = Nothing
    Set fs = Nothing
End Function

Sub importer(flist)
    'ブック内にモジュールが存在するか確認して、インポートの仕方を変える
    Dim i As Integer

    For i = LBound(flist) To UBound(flist)
        If flist(i) <> vbNullString Then
'--------------------------------------------------------------------
    '問題の部分
            If checkBasExist(flist(i)) Then  
            'ちゃんと実引数は入ってると思われる。デバッグ機能で確認できる
            'checkBasExist()側では "" になってしまうので、必ずElseの方を通ってしまう
'--------------------------------------------------------------------
                Call removeMod(flist(i))
                Call importMod(TARGET_PATH & "\" & flist(i))
            Else
                Call importMod(TARGET_PATH & "\" & flist(i))
            End If
        End If
    Next
End Sub

Sub main(e As String)
    'メインルーチン
    TARGET_PATH = ThisWorkbook.PATH & "\bas"
    
    Dim WHAT As String: WHAT = TARGET_PATH
    
    Select Case e
        Case "import"
            Call importer(whatImport(WHAT))
        Case "export"
    End Select
    
    TARGET_PATH = vbNullString
End Sub

hyFoldererモジュール

Function convertFilesToStrs(fs) As String()
    'ファイルコレクションのファイル名一覧を返す関数

    Dim l() As String
    Dim i As Integer

    Dim f As Object

    ReDim l(fs.Count)

    For Each f In fs
        l(i) = f.Name
        i = i + 1
    Next

    convertFilesToStrs = l()

    Set f = Nothing
    Set fs = Nothing

End Function

hyStrモジュール

Function removeElementOfList(el As String, list() As String)
    '文字列の配列から、特定要素を除外した配列を返す関数
    Dim i As Integer
    Dim flg As Boolean: flg = False
    For i = LBound(list) To UBound(list)
        If list(i) = el Then
            list(i) = list(i + 1)
            i = i + 1
            flg = True
        End If
    Next
    
    If flg Then
        ReDim Preserve list(UBound(list) - 1)
    End If
    
    removeElementOfList = list
    
End Function

Answer 1

直接の回答ではありません（私の環境では質問の内容が再現できなかったため）。

いくつか気になった点を記載しておきます。

通常の場合checkBasExistは常にFalseを返す

flistには、見つかったファイルの名前が「拡張子付き」で格納されています。
しかし、比較しているものがモジュール名のため、拡張子は付いておらず、違うものと判定されます。

そのため、通常の手段でモジュールをエクスポートしているのであれば、checkBasExistは常にFalseを返します。

---

ここからは参考程度の話です。

プロシージャの並び順

VBAでは、モジュール内におけるプロシージャの並び順に制限はありません（使うものを先に記述する必要はありません）。

私の感覚ですが、全体をまとめる処理（今回であればmain）が上の方にあり、子処理は下の方にある方が読みやすいと思われます。
子処理の中身を見たいときはShift+F2を押せば良いだけですし。

convertFilesToStrsの返り値

ローカルウィンドウなどを見ていればすぐわかる話だと思いますが、現状のconvertFilesToStrsでは末尾に空文字列が必ず入ります。
ReDim l(fs.Count)で0からfs.Countまでの大きさの配列、つまりfs.Count+1の大きさの配列を確保しているためです。

その無駄に確保している分があるため、importerの中でIf flist(i) <> vbNullString Thenを行う必要が出てきていると思われます。

結果が無かったことを示したい場合、Split(VBA.vbNullString)を評価するとString(0 To -1)の配列が得られるので、それを使う手もあります。

Comments

[Hayashi_Jelly]

checkBasExistに拡張子を除いた文字列を渡すように変更したところ、質問した現象は解消されました。解せないところではありますが・・・
その他にも色々と参考になるご意見ありがとうございました。プログラミング自体独学なので非常に参考になります

[imihito]

`bas = ""`をどのタイミングで確認されたかにもよるかもしれませんね。

ステップ実行時に`Function checkBasExist~`が黄色になっている段階では実引数が代入されておらず、そこから進むことで代入されます。