エクセルvba マウス操作による範囲選択のやり方

Question

前提・実現したいこと

エクセル2013 VBAでのマウス操作で範囲選択を行いたいです。
（対象はエクセルのセルではなく、例えばデスクトップだったり、IEだったりします）

該当のソースコード

Declare PtrSafe Function SetCursorPos Lib "User32" (ByVal x As Long, ByVal y As Long) As Long
Declare PtrSafe Sub mouse_event Lib "User32" ( _
    ByVal dwFlags As Long, _
    Optional ByVal dx As Long = 0, _
    Optional ByVal dy As Long = 0, _
    Optional ByVal dwDate As Long = 0, _
    Optional ByVal dwExtraInfo As Long = 0)
Sub main()
    SetCursorPos 800, 400 '左から800ピクセル、上から400ピクセルの位置にカーソルを移動
    mouse_event 2  '左ボタン押下（範囲選択のクリックのつもり）
    SetCursorPos 1000, 600 '範囲選択のマウス移動のつもり
    mouse_event 4  '左ボタン解放
end Sub

補足情報

マウスの位置指定、
左クリック押しっぱなし、
マウス位置指定（移動のつもり）、
左クリック離す
の動作を行いたかったのですが、うまくいきません。
範囲選択のapiが見つかりません。
どのように行えば良いでしょうか。

Comments

[beginner_t]

操作対象がエクセルではないアプリケーション等ということですが、エクセルのVBAを使わないといけない理由があれば教えてください。特段、エクセルでなくても操作できれば良いということであれば、別のマクロソフトを推奨します。

[expy]

セキュリティがガチガチで、インストール等が禁止となっています。

Answer 1

やっていること自体は問題なさそうですが、ノータイムで連続処理すると反映が追い付かないようですね。

例えば以下のようにSleepで短いウェイトを挟んであげることで、私の環境では動作しました。

Declare PtrSafe Function SetCursorPos Lib "User32" (ByVal x As Long, ByVal y As Long) As Long
Declare PtrSafe Sub mouse_event Lib "User32" ( _
    ByVal dwFlags As Long, _
    Optional ByVal dx As Long = 0, _
    Optional ByVal dy As Long = 0, _
    Optional ByVal dwDate As Long = 0, _
    Optional ByVal dwExtraInfo As Long = 0)

'Sleep用のAPI宣言
Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

'mouse_event用の定数宣言
Private Const MOUSEEVENTF_ABSOLUTE = &H8000
Private Const MOUSEEVENTF_MOVE = &H1
Private Const MOUSEEVENTF_LEFTDOWN = &H2
Private Const MOUSEEVENTF_LEFTUP = &H4
Private Const MOUSEEVENTF_RIGHTDOWN = &H8
Private Const MOUSEEVENTF_RIGHTUP = &H10
Private Const MOUSEEVENTF_MIDDLEDOWN = &H20
Private Const MOUSEEVENTF_MIDDLEUP = &H40

Sub main()

    SetCursorPos 800, 300 '左から800ピクセル、上から400ピクセルの位置にカーソルを移動
    
    Sleep 100
    
    mouse_event MOUSEEVENTF_LEFTDOWN  '左ボタン押下（範囲選択のクリックのつもり）
    
    Sleep 100
    
    SetCursorPos 1000, 600 '範囲選択のマウス移動のつもり
    
    Sleep 100
    
    mouse_event MOUSEEVENTF_LEFTUP  '左ボタン解放

End Sub

お試しください。

Comments

[expy]

できました！
ありがとうございました。

[jawa]

無事解決されたようで、なによりです。

余談ですが、
`mouse_event MOUSEEVENTF_ABSOLUTE Or MOUSEEVENTF_MOVE, x座標, y座標`
でもマウスの移動は可能です。

ただ、座標の指定方法がマウスの最小移動量であるミッキー数という単位での指定となっており、OSや環境設定に依存する単位のため扱い難いです。
このためピクセル単位で座標指定ができるSetCursorPosを利用される方が多いようですね。

ミッキー数はマイクロソフトが作り出した単位のようで、mouse_eventの説明にも「ミッキーの詳細については、MSDN ライブラリの［検索］タブで「(" ミッキー " OR "mickey") AND (" マウス " OR "mouse")」を検索」と記載されていました。
…開発者の遊び心ですね(^-^;