ユーザーフォーム Function Sub

Question

前提・実現したいこと

現在ユーザーフォームからボタンをクリックして
シートの内容を削除するよう実装しています。
CallではなくFunctionで呼び出したいです。

発生している問題・エラーメッセージ

オブジェクトは、このプロパティまたはメソッドをサポートしていません

エラーが出るソースコードではFunctionを使用しているのですが、
呼び出し方をCall All_Clear_Sheet (CONVERT_SHEET)
にして関数側をSub All_Clear_Sheet (CONVERT_SHEET)
にした場合にはエラーは表示されません。

何故エラーが出力されているのでしょうか。
よろしくお願いします。

該当のソースコード

'シートの内容を削除
Function All_Clear_Sheet(CONVERT_SHEET As Worksheet)
    CONVERT_SHEET.Activate
    CONVERT_SHEET.Cells.Clear
End Function

'ボタンを実行
Private Sub CommandButton1_Click()
Dim CONVERT_BOOK As Workbook
Dim CONVERT_SHEET As Worksheet

Set CONVERT_BOOK = ThisWorkbook
Set CONVERT_SHEET = CONVERT_BOOK.Worksheets("変換")

All_Clear_Sheet (CONVERT_SHEET)
End Sub

補足情報（FW/ツールのバージョンなど）

office2010

Answer 1

解決済みですが、微妙に間違いがあるので、指摘しておきます。

引数を持つSubプロシージャを呼び出すとき、または、引数を持つFunctionプロシージャを戻り値を受け取らずに呼び出すときは、

Call All_Clear_Sheet(CONVERT_SHEET)

または、CAll を省略するときは、

All_Clear_Sheet CONVERT_SHEET

です。
Callで呼び出すときは、プロシージャ名のあとの () は必須。
Callを省略した時は、プロシージャ名のあとに()は不必要です。
そういう仕様です。

All_Clear_Sheet (CONVERT_SHEET)

としたら、Sub でも Function でも、

オブジェクトは、このプロパティまたはメソッドをサポートしていません

のエラーになります。Callに関してSubもFunctionも違いはないです。

もちろん戻り値を受け取ることはFunctionしかできませんが。

下記の公式の解説をお読みください。上記のことがすべて記述してあります。

Call ステートメント | Microsoft Docs

Answer 2

オブジェクトは、このプロパティまたはメソッドをサポートしていません

このエラーがなぜ発生したかについて補足をしておきます。

根本原因は、hatena19さんの回答の通り呼び出し方が間違っているからです。

All_Clear_Sheet (CONVERT_SHEET)
と記述したとき、()は式の評価の順番を指定するものとして解釈されます。
（(1 + 2) * 3の()と同じ意味で、関数の引数をまとめるものではない。）

評価の順番を指定する必要があるということは、()の中身は何らかの値（数字・文字列）だとVBAは解釈します。

しかし、CONVERT_SHEETはWorksheet型のオブジェクトであり、値ではありません。
そのため、VBAはオブジェクトの「既定のメンバー」というものを参照し、オブジェクトを値に変換しようと試みます。
既定のメンバーの例：RangeのValueプロパティなど（正確には違うけれど）

しかし、Worksheet型には「既定のメンバー」が定義されていない（サポートされていない）ため、呼び出しに失敗し「オブジェクトは、このプロパティまたはメソッドをサポートしていません」のエラーが発生します。

Comments

[hatena19]

なるほど。「オブジェクトは、このプロパティまたはメソッドをサポートしていません」のエラーに違和感があったのですが、納得できました。既定のメンバーがあるオブジェクトを引数にした場合（Rangeなど）は、() で囲むと「オブジェクトが必要です」エラーになりますね。()で囲むことによって値として評価されてしまうためですね。String とか Long を引数にした場合は、()で囲んでも囲まなくてもエラーになりませんね。最初から値ですから当然ですね。納得、納得。

Answer 3

Functionは何かしら戻り値があるものだからです。

Function All_Clear_Sheet(CONVERT_SHEET As Worksheet) As String

として
最後に

All_Clear_Sheet = "何か適当な文字列"

とすればFunctionでもエラーは出ないはずです。

コード全体

Function All_Clear_Sheet(CONVERT_SHEET As Worksheet) As String
    CONVERT_SHEET.Activate
    CONVERT_SHEET.Cells.Clear
    All_Clear_Sheet = "何か適当な文字列"
End Function

ただ、何も返さないメソッドなのでしたらやはりSubが適当かと思います。

• Functionプロシージャの使い方について考える

「Subプロシージャは値を返さない」、「Functionプロシージャは値を返す」

Comments

[退会済みユーザー]

回答ありがとうございます
提示して頂いたコードに修正したのですが、
呼び出したタイミングでエラーが出力されます。

[m.ts10806]

すみません「未検証」と一言入れておけば良かったです。
念のため実際のコードとエラーメッセージを提示いただけますか？
ただ、回答で伝えたいのはコピペコードではなく「Function使いたいなら返り値は必須」ということなので。

[退会済みユーザー]

呼び出した側で戻り値を受け取るようにしないといけなかったみたいです。
Dim hoge
hoge = All_Clear_Sheet(CONVERT_SHEET)
このように修正して提示して頂いた内容に修正したらエラーが出力されませんでした。
ありがとうございました。

[m.ts10806]

あ、そうですね。返り値を受けとるようにしなきゃいけませんね。
ただやはり返り値を必要としない、実行しっぱなしの関数であれば返り値を受け取っても使わない、つまりその変数分の余計なコストがかかることになるので、意味に合わせて使い分けるようにしてください。