ToonLitシェーダでテクスチャの透過がされない

Unity標準のToon/Litシェーダを改変したものを使っているのですが
テクスチャに使っているpng画像のアルファ値が反映されなくなってしまいました。

どうしたら良いでしょうか。

Shader "ToonLitRemake" {
    Properties {
        _Color ("Main Color", Color) = (0.5,0.5,0.5,1)
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _Ramp ("Toon Ramp (RGB)", 2D) = "gray" {} 
    }

    SubShader {
        Tags { "IgnoreProjector"="True"  "RenderType" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha
        LOD 200
    Pass
        {
            ZWrite ON
            ColorMask 0

        }

    Pass{
            Name "BASE"
            //Cull Off

    }

        CGPROGRAM
        #pragma surface surf ToonRamp

        sampler2D _Ramp;

        // custom lighting function that uses a texture ramp based
        // on angle between light direction and normal
        #pragma lighting ToonRamp exclude_path:prepass
        inline half4 LightingToonRamp (SurfaceOutput s, half3 lightDir, half atten)
        {
            #ifndef USING_DIRECTIONAL_LIGHT
            lightDir = normalize(lightDir);
            #endif

            half d = dot (s.Normal, lightDir)*0.5 + 0.5;
            half3 ramp = tex2D (_Ramp, float2(d,d)).rgb;

            half4 c;
            c.rgb = s.Albedo * _LightColor0.rgb * ramp * (atten * 2);
            c.a = 0;
            return c;
        }


        sampler2D _MainTex;
        float4 _Color;

        struct Input {
            float2 uv_MainTex : TEXCOORD0;
        };

        void surf (Input IN, inout SurfaceOutput o) {
            half4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
            o.Albedo = c.rgb;
            o.Alpha = c.a;
        }
        ENDCG


    } 

    Fallback "Diffuse"
}

【追記】
閲覧してくださった方ありがとうございます。
こちらを参考に自分で作ってみました。リンク内容
・PNGテクスチャのアルファ有効
・前後関係の正しい半透明処理有効

Shader "ToonLitRemake" {

         Properties {
             _Color ("Main Color", Color) = (0.5,0.5,0.5,1)
        _MainTex ("Alpha Blended (RGBA) ", 2D) = "white" {}
             _Ramp ("Toon Ramp (RGB)", 2D) = "gray" {} 
         }

         SubShader {
             Tags {"Queue"="Transparent" "RenderType"="Transparent"}
             Blend SrcAlpha OneMinusSrcAlpha
             LOD 200

        Pass{
            ZWrite ON
            ColorMask 0
        }



     CGPROGRAM
     #pragma surface surf ToonRamp  alpha:fade

     sampler2D _Ramp;

     // custom lighting function that uses a texture ramp based
     // on angle between light direction and normal
     #pragma lighting ToonRamp exclude_path:prepass
     inline half4 LightingToonRamp (SurfaceOutput s, half3 lightDir, half atten)
     {
         #ifndef USING_DIRECTIONAL_LIGHT
         lightDir = normalize(lightDir);
         #endif

         half d = dot (s.Normal, lightDir)*0.5 + 0.5;
         half3 ramp = tex2D (_Ramp, float2(d,d)).rgb;

         half4 c;
         c.rgb = s.Albedo * _LightColor0.rgb * ramp * (atten * 2);
         c.a = s.Alpha;
         return c;
     }


     sampler2D _MainTex;
     float4 _Color;

     struct Input {
         float2 uv_MainTex : TEXCOORD0;
     };

     void surf (Input IN, inout SurfaceOutput o) {
         half4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
         o.Albedo = c.rgb;
         o.Alpha = c.a;
     }
     ENDCG

         } 

         Fallback "Diffuse"
     }