AppleScriptで次の内容を実現する方法①ページ内のリンクURLを取得②フィルターをかけてリスト化③アンカーテキストでリスト表示させる

Question

前提・実現したいこと

恐れ入ります。

現在、AppleScriptにて下記のようなコードにチャレンジしています。

①ページ内に掲載されているリンクURLを取得
②取得したリンクURLにフィルタをかけてリスト化（アドセンスなど余計なリンクを取り除く）
③リストにはURLではなくアンカーテキストで表示させる（リストの中からページを選ぶ時にURLで表示されるとページの内容がわかりづらい）
④リストから選んだ順番でページを切り替える

このうち④は実現できたのですが、①②③を実現することができません。

不勉強で恐縮ですが、お知恵を拝借願えませんでしょうか？
お心当たりのある方、ご意見やご指摘、ご提案をお待ちしております。

参考までに、作成中のコードを以下に掲載させていただきます。

該当のソースコード

set theUrlList to {}
set i to 0
try
	repeat
		set i to i + 1 as string
		set theText to i & "件目のURLをコピーしてください。"
		tell application "Google Chrome"
			activate
		end tell
		tell application "System Events"
			display dialog theText
		end tell
		set theUrlList to theUrlList & (the clipboard)
		activate
		display dialog "繰り返しますか？" buttons {"いいえ", "はい"} default button "はい"
		if button returned of result = "いいえ" then exit repeat
		--リンクURLを一回ずつコピーしなければならないのが手間、ページ内のリンクURLを一括取得したい――
		--リンクURLを一括取得すると、アドセンスなどの余計なリンクも含まれる。フィルタをかけたい――
		--リストの中からページを選ぶ時にURLで表示されるとページの内容がわかりづらい、アンカーテキストで表示させたい――
	end repeat
end try
set counttheUrlList to count theUrlList
tell application "Google Chrome"
	set theWindow to (make new window)
	tell theWindow
		repeat with i from 1 to counttheUrlList
			set URL of active tab to (item i of theUrlList)
			tell application "System Events"
				with timeout of (1 * 60 * 60) seconds
					delay 5
					display dialog "次のページに進みますか？" buttons {"いいえ", "はい"} default button "はい"
					--画面中央に表示されて邪魔--
					if button returned of result = "いいえ" then exit repeat
				end timeout
			end tell
		end repeat
		close theWindow
		activate
		display dialog "終了しました"
	end tell
end tell

試したこと

1. Automatorの「リンクURLを取得」「URLにフィルタを適用」だと、ページ内のリンクURLの一括取得は可能だが、フィルタ項目に「〜を含まない」がないため、余計なリンクURLを取り除くことができない（「完全なURL」以外では不明）
2. Google Chromeのview sourceコマンドと、select　allコマンドから、AppleScriptのtext item delimiters of AppleScriptの検索を利用してリンクURLを抜き出せないかと考えたが、不勉強のためコードで再現することができない

###　まとめ・知りたい方法

①ページ内に掲載されているリンクURLを取得する方法
②取得したリンクURLにフィルタをかけて、条件に適合したURLのみをリスト化する方法
③リストを表示する時に、URLではなくアンカーテキストで表示させる方法

補足情報（FW/ツールのバージョンなど）

OS:macOS High Sierra　バージョン10.13.6
モデル：iMac (21.5-inch, Mid 2011)
プロセッサ：2.5 GHz Intel Core i5
メモリ：4 GB 1333 MHz DDR3
スクリプトエディタ バージョン2.10
Automator バージョン2.8

Answer 1

（１）と（２）だったら、こんな感じでしょうか。Safariで実行してみました。オープン中のページからリンクURLを抽出して、除外URLを除外します。実行前に、

http://piyocast.com/as/archives/3352

のように設定しておく必要があります。実行するとわかりますが、フル記述のURL以外の相対URLも取れるので、そのあたりをどうするかも問題です。

（３）は「アンカー」という日本語の意味がわかりません。もしかして、タイトルのことを指しているのでしょうか？

set aList to {}
set ngList to {"https://www.facebook.com/", "javascript:"} --フィルタ（除外）したいURL

tell application "Safari"
set targDoc to front document

set the link_count to (do JavaScript "document.links.length" in targDoc)
repeat with i from 0 to (link_count - 1)
	set aSRC to do JavaScript (("document.links[" & i as string) & "].getAttribute('href', 2)") in targDoc
	
	--ループで除外URLをのぞく
	set hitF to false
	
	repeat with ii in ngList
		set jj to contents of ii
		if aSRC begins with jj then
			set hitF to true
			exit repeat
		end if
	end repeat
	
	if hitF = false then
		set the end of aList to aSRC
	end if
end repeat

end tell

return aList

Comments

[okurage]

ご回答ありがとうございます。
AppleScriptの穴 – Useful & Practical AppleScript archive http://piyocast.com/as/
自分では半分も理解できていませんが、いつも勉強させていただいております。
いただいた回答を基に、早速色々と試してみたいと思います。
ありがとうございました！

[okurage]

追記
説明不足で申し訳ありません。ご指摘の通り、アンカーはタイトルのつもりで書きました。

[Piyomaru]

指定URLからのタイトルの取得なら、こんな感じではないでしょうか。
http://piyocast.com/as/archives/4845

[okurage]

重ね重ねありがとうございます！
学べば学ぶほど、わからないことが増えていく状態ですが、Piyomaruさんのように丁寧に回答してくれたり、ネット上で情報発信してくださる方々のおかげで何とか続けられています。
特にAppleScriptは情報が少なかったり英語だったりで、日本語のサイトには大変お世話になっております。
勝手ながら、今後もサイトを継続的に更新していただけることを願っております。