多次元配列のループについて

Question

現在業務でVBAを触っています。
そこで、1点質問です。

　Dim itm As Variant
　Dim arr(1 To 2, 1 To 3) As String

　arr(1, 1) = "あ"
　arr(1, 2) = "い"
　arr(1, 3) = "う"
　arr(2, 1) = "Y"
　arr(2, 2) = "Y"
　arr(2, 3) = "N"

　For Each itm In arr()
　　MsgBox itm
　Next itm

上記のような多次元配列をループしている際に多次元配列の値がYであればNに、NならばYに変更したい場合どのようにソースを変更すればよいのでしょうか？
結果としては以下のようにしたいです。。。
arr(2, 1) = "Y"→arr(2, 1) = "N"
arr(2, 2) = "Y"→arr(2, 2) = "N"
arr(2, 3) = "N"→arr(2, 3) = "Y"

Comments

[m.ts10806]

ソースコードはマークダウンのcode機能を利用してください

Answer 1

Sub test()
    Dim i As Long
    Dim arr(1 To 2, 1 To 3) As Variant

    arr(1, 1) = "あ"
    arr(1, 2) = "い"
    arr(1, 3) = "う"
    arr(2, 1) = "Y"
    arr(2, 2) = "Y"
    arr(2, 3) = "N"

    For i = LBound(arr, 2) To UBound(arr, 2)
        Select Case arr(2, i)
            Case "Y": arr(2, i) = "N"
            Case "N": arr(2, i) = "Y"
        End Select
    Next
    
    'シート上で結果の確認
    ActiveSheet.Range("A1:C2").Value = arr
End Sub

参考まで。。。

Answer 2

ごめんなさい、以下のコードはMsgboxの表示としては入れ替わりますが、これでは配列内容は入れ替わりません
natoさんの回答が正しいです

---

値がYであればNに、NならばYに変更したい

シンプルに、そのまま、コードにすれば良いと思います

For Each itm In arr()
    If itm = "Y" Then
      itm = "N"
    ElseIf itm = "N" Then
      itm = "Y"
    End If
　　MsgBox itm
Next itm

Answer 3

同じ要素を書き換えるなら、こんな感じで判断して代入するだけで良いかと

失礼しました。

For Eachの場合itmに代入した値がarrには反映されないので質問されたのだと考えます。
従って次のコードのように配列の初めから終わりまでカウンタでループさせて代入してください。

    Dim i As Long, j As Long
    For i = LBound(arr, 1) To UBound(arr, 1)
        For j = LBound(arr, 2) To UBound(arr, 2)
            arr(i, j) = IIf(arr(i, j) = "Y", "N", IIf(arr(i, j) = "N", "Y", arr(i, j)))
        Next
    Next