ExcelのVBAモジュールを複数のシートに一括処理させたいです。

Question

こんにちは、ExcelシートからCSVファイルを出力するマクロを作ってみました。

問題なく動きますが、これはシート１つに対して起動します。現在は、各シートにボタンを作り、そのボタンを押すとcsvExportを読みだしています。

やりたいのは、シートが約20枚あり、1枚目のシートに「一括出力」ボタンを作り、2~18番目のシートを対象にして、csvExportを実行させたいですが、VBAが全く分からなくてすごく困っています。2番から最後のシートまで繰り返し、19番と20番シート意外であれば、csvExportマクロを実行してCSVファイルを一括出力したいです。
一括出力するためのcsvExportAllをどのように書けばよろしいですか？こんな感じで書いてみたんですが、全然ダメでした。
何かヒントあれば、ぜひ教えてください。

Sub csvExportAll()

    Dim sht As Worksheet
    Dim ws_cnt As Integer
    Dim I As Integer
    ws_cnt = ActiveWorkbook.Worksheets.Count
    
    For I = 2 To ws_cnt
       If ws_cnt <> 19 Or ws_cnt <> 20 Then
         Module1.csvExport
       End If
    Next I

End Sub

これは、参考：CSVファイルを出力するVBA　を真似して書いたcsvExportです。

Option Explicit

Sub csvExport()

    'CONST値の設定
    Dim initYear As String
    Dim userName As String
    Dim userIdx As String
        
    initYear = Sheets(2).Range("D22").Value    '学年度
    userIdx = Sheets(2).Range("D23").Value   '契約ID
    userName = Sheets(2).Range("D24").Value  '契約者名
    
    Dim csv As String  ' CSV に書き込む全データ
    Dim line As String ' 1 行分のデータ
    Dim sheetName As String ' シート名
    
    ' CSV のシートを選択
    Dim ws As Worksheet
    Set ws = ActiveSheet      ' 選択しているシート
    sheetName = ws.Name & "マスタ"       'シート名取得
       
    ' データの範囲を選択
    Dim region As Range
    Set region = ws.Range("B4").CurrentRegion ' セル「A1」を含むデータの範囲を取得
    
    ' 見出し行を取り除く
    Set region = region.Offset(1, 0)                           ' 範囲を 1 行下にずらす
    Set region = region.Resize(RowSize:=region.Rows.Count - 1) ' 範囲を 1 行分縮める
    
    ' 区切り文字の選択
    Dim delimiter As String
    delimiter = ","   ' カンマ区切り
    
    Dim row As Range
    For Each row In region.Rows ' 行のループ
        
        line = ""
        Dim cell As Range
        For Each cell In row.Columns ' 列のループ
            
            ' カンマ区切りで結合
            Dim item As Variant
            
                item = """" & cell.Value & """"
                
            If line = "" Then
                line = item
            Else
                line = line & delimiter & item
            End If
            
        Next
        
        ' 行を結合
        If csv = "" Then
            csv = line
        Else
            csv = csv & delimiter & """" & """" & delimiter & """" & """" & vbCrLf & line
        End If
        
    Next
    
    ' 書き込み処理
    'UTF-8で保存するため、ADODB.Streamを使用する。
           
    Const adSaveCreateOverWrite = 2
    Const adTypeBinary = 1
    Const adTypeText = 2
    
    Dim adoTemp As Object
    Set adoTemp = CreateObject("ADODB.Stream")
    Dim adoUTF8 As Object
    Set adoUTF8 = CreateObject("ADODB.Stream")
    
    'ファイル名は、「契約者名」_「年度」_「シート名」マスタ_初期設定.csvとする。
    Dim initFileName As String
    initFileName = ThisWorkbook.Path & "\" & userName & "_" & initYear & "学年度_" & sheetName & "_" & "初期設定.csv"
    
    With adoTemp
      .Charset = "UTF-8" ' UTF-8 を指定
      .Open
      .WriteText """" & sheetName & """" & vbCrLf      ' 1行名にシート名を書き込む
      .WriteText csv ' 2行名から作成した CSV 形式のデータを書き込み
      .Position = 0
      .Type = adTypeBinary
      .Position = 3
    End With
    
    With adoUTF8 ' BOM を取り除いて保存
      .Type = adTypeBinary
      .Open
      adoTemp.CopyTo adoUTF8
      .SaveToFile initFileName, adSaveCreateOverWrite ' CSV ファイルに保存
    End With
    
    adoTemp.Close
    adoUTF8.Close
    
    Set adoTemp = Nothing
    Set adoUTF8 = Nothing
    
End Sub

Answer 1

何とか自分で解決できました。
出力したいシートの見出し色を赤（シート.Tab.ColorIndex = 3）にして、赤のシートだけ処理するようにしました。For文でSheets番号を増やしながら、Activate（シート選択）することで動きました。

Sub csvExportAll()

    Dim ws As Worksheet
    Dim ws_cnt As Integer
    Dim I As Integer
    Dim returlvar As Integer
    
    ws_cnt = ActiveWorkbook.Worksheets.Count
       
       
    returlvar = MsgBox("顧客IDと学年度を必ず確認してから実行してください、実行しても大丈夫ですか？", vbYesNo)
    
    If returlvar = 6 Then
          
        For I = 2 To ws_cnt
        
            Set ws = Sheets(I)
            ws.Activate
            
            If ws.Tab.ColorIndex = 3 Then
           
                Module1.csvExport
                
            End If
            
        Next I
    
        Set ws = Sheets(2)
        ws.Activate
        
        MsgBox "CSVファイル出力に成功しました！"
    
    Else
    
        MsgBox "CSVファイル出力をキャンセルしました。"
        
    End If

End Sub