ESP-wroom-02間でルーターを介したUDP通信に失敗する

Question

ESP-wroom-02(ESP8266)2台を使ってルーター経由でWiFiUDP通信をしようとしています。

（将来的にやりたいこととしては、無線でPCから数メートル先にあるセンサからセンサ値を取得し、その値に応じてPCで処理を行った後、また他の無線で接続されたオブジェクトのモーターを動かそうと思っています。）

こちらのリンクをコピペ（下のコード）で動かした所、ボタン入力からclient側でUDP.writeが正しく行われていることは確認できました。しかし、Server側で適宜printしてデバッグしたところ、UD.ParsePacket()=0になっており、rcvWiFiのループに入れていませんでした。
受信に失敗しているようですが、原因が思い当たりません。どなたか原因のわかる方がいらっしゃいましたらご教授いただけますと幸いです。

Client側コード

#include <ESP8266WiFi.h>
#include <WiFiClient.h> 
#include <WiFiUDP.h>

// UDP settings
WiFiUDP UDP;

// WiFi settings
IPAddress HOSTIP (192, 168, 4, 1);
IPAddress myIP(192, 168, 4, 2);
const char *ssid = "*";
const char *password = "*";

const int btn1 = 4;
const int btn2 = 5;
const int btn3 = 12;
const int btn4 = 2;

const int ledPin = 16;
const int wifiStatusPin = 13;

void connectWiFi() {
  WiFi.begin(ssid, password);
  WiFi.config(myIP, WiFi.gatewayIP(), WiFi.subnetMask());

  Serial.println("start_connect");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("CONNECTED!");
  digitalWrite(wifiStatusPin, HIGH);
}

void setup() {
  Serial.begin(115200);
  
  pinMode(ledPin, OUTPUT);
  pinMode(wifiStatusPin, OUTPUT);
  
  pinMode(btn1, INPUT_PULLUP);
  pinMode(btn2, INPUT_PULLUP);
  pinMode(btn3, INPUT_PULLUP);
  pinMode(btn4, INPUT_PULLUP);
  
  delay(500);
  digitalWrite(ledPin, HIGH);
  
  Serial.println("-");
  Serial.println("start");
  WiFi.mode(WIFI_STA);//重要!
  UDP.begin(893);
  connectWiFi();
}

void sendWiFi(char byteData[]) {
  if (UDP.beginPacket(HOSTIP, 893)) {
    UDP.write(byteData);
    UDP.endPacket();
    Serial.println(byteData);
  }
}

void loop() {
  char  b[4];
  b[0] = (digitalRead(btn1)) ? '1' : '0';
  b[1] = (digitalRead(btn2)) ? '1' : '0';
  b[2] = (digitalRead(btn3)) ? '1' : '0';
  b[3] = (digitalRead(btn4)) ? '1' : '0';
  Serial.println(b);
 
  sendWiFi(b);
  
  delay(17);
  end_loop();
}

void end_loop(){
  if (WiFi.status() != WL_CONNECTED) {
    WiFi.disconnect();
    digitalWrite(wifiStatusPin, LOW);
    Serial.println("disconnect!");
    connectWiFi();
  }
}

Server側コード

#include <ESP8266WiFi.h>
#include <WiFiClient.h> 
#include <WiFiUDP.h>

// Variable setting
char WiFibuff[4];

// UDP setting
WiFiUDP UDP;

// WiFi setting
IPAddress myIP(192, 168, 4, 1);
const char *ssid = "*";
const char *password = "*";

//led
const int ledPin = 16;
const int led1 = 4;
const int led2 = 5;
const int led3 = 12;
const int led4 = 2;

void setup() {
  Serial.begin(115200);
  
  pinMode(ledPin, OUTPUT);
  pinMode(led1, OUTPUT);
  pinMode(led2, OUTPUT);
  pinMode(led3, OUTPUT);
  pinMode(led4, OUTPUT);
  
  WiFi.mode(WIFI_AP);
  WiFi.softAP(ssid, password);
  WiFi.config(myIP, WiFi.gatewayIP(), WiFi.subnetMask());
  UDP.begin(893);

  digitalWrite(ledPin, HIGH);
  Serial.println("UDP.begin!");
}

void rcvWiFi() {
  UDP.read(WiFibuff, 4);
  Serial.print(WiFibuff);
  UDP.flush();
}

void loop() {
  if (UDP.parsePacket() > 0) {
    rcvWiFi();

    if(WiFibuff[0] == '0') { digitalWrite(led1, HIGH); } else { digitalWrite(led1, LOW); }
    if(WiFibuff[1] == '0') { digitalWrite(led2, HIGH); } else { digitalWrite(led2, LOW); }
    if(WiFibuff[2] == '0') { digitalWrite(led3, HIGH); } else { digitalWrite(led3, LOW); }
    if(WiFibuff[3] == '0') { digitalWrite(led4, HIGH); } else { digitalWrite(led4, LOW); }
  }
}

Answer 1

サーバー側コードがAPモードになってますが、
サーバーがアクセスポイントとして動いているならルーターいらなくないですか？

コピペ元のネットワーク構成は、アクセスポイントであるサーバーにクライアントが直接接続する形です。

そのあたり勘違いしてルーターのssidとパスをコードに書いてたりしませんか？

ルーター介したいならどちらもSTAモードです。

Comments

[Minnie]

ご回答ありがとうございます、完全に勘違いしていました。これは片方をアクセスポイントにしている形なんですね、きちんと読めていませんでした。ご回答をうけ、
①SSIDとパスを適当に同じものにする（clientはSTA、serverはAPモードのまま）
②SSIDとパスはルーターと同じものにし、両方STAモードにする
の2通りを試しましたがどちらもうまく行かず…初心者で理解が深くない故の質問かと思いますが、こちら解決方法ありましたらぜひご教授いただきたいです。よろしくお願いいたします。

Answer 2

ルーターでは、WiFi接続した機器間で通信を制限する設定がある場合がありますので、確認が必要です。

Comments

[Minnie]

ご回答ありがとうございます。なるほど、そうなんですね。どのように確認するのでしょうか…？重ねてのご質問申し訳ありません。

[Harahira]

ルータによって違いますので、何とも言えません。
ご自分のルータならマニュアルを、会社等のルータなら管理者に相談してみてください。

[Minnie]

承知しました。ご丁寧な回答をどうもありがとうございました。

Answer 3

なんか問題の多そうなコードですが、、

IPアドレスなんか、リンク先のをそのまま持ってきてますが、Wifiルータのネットワーク設定周りで、ブッキングしてるとかはないでしょうか。
まずはその２つのデバイスだけでWifiルータを動かしてみては。

Comments

[Minnie]

ご回答ありがとうございます。他の機器では使用せず、ローカルでwroom-02だけで使用しているのでおそらくないとは思いますが、確認してみようと思います。

Answer 4

こんにちは、私も似たような構成でUDP通信をしているのですが、結果はどうなったのでしょうか。
気になります。よろしくお願い申し上げます。