他のブックを開いてセル内の文字列を取得し、 取得した文字列を含むブックを検索したい

Question

前提・実現したいこと

ブックAを開いてA1セルの文字列を取得
取得した文字列を含むファイルのパスを取得したい

発生している問題・エラーメッセージ

エラーメッセージ

該当のソースコード

Option Explicit

Sub ファイルを探す()

Dim ex As New Excel.Application
Dim wb As Workbook
Dim sPath
Dim r As String
Dim sht As Worksheet
    
	'ブック「A」を開く
	sPath = ThisWorkbook.Path & "\A.xls"
	Set wb = ex.Workbooks.Open(Filename:=sPath)
	
	'「sheet1」の「A1」セルを取得
	r = wb.Worksheets("sheet1").Cells(1, 1).Value
	Debug.Print r
	
	'ブック「A」を閉じる
	Call wb.Close

	'フォルダ「B」から文字列rを含むファイルを検索
	Call FileSearch(ThisWorkbook.Path & "\B", "*" & r & "*")
    
End Sub

Sub FileSearch(Path As String, Target As String)

	Dim FSO As Object, Folder As Variant, File As Variant
	Set FSO = CreateObject("Scripting.FileSystemObject")

		For Each Folder In FSO.GetFolder(Path).SubFolders

		Call FileSearch(Folder.Path, Target)

		Next Folder

	For Each File In FSO.GetFolder(Path).Files

		If File.Name Like Target Then
		Debug.Print File.Path
        	End If

	Next File

End Sub

試したこと

上記のコードで、
・ブックAを開く
・A1セルの文字列を取得
・フォルダBの中から、取得した文字列をファイル名に含むファイルのパスを取得

は出来たのですが、ファイル名やシート名ではなく、
セル内に文字列を含むかどうかを判別したいです。

[If File.Name Like Target Then]でファイル名で検索しているのは分かるのですが、
Excel内のセルを対象にする方法が分からずに困っています。

補足情報（FW/ツールのバージョンなど）

Excel2013/Windows 7

Answer 1

正攻法で行くなら、ご自分で書いているようにブックを開いて検索する必要があります。

この部分を

If File.Name Like Target Then
Debug.Print File.Path
End If

こういう感じに直せば検索できると思います。

    Dim WS As Worksheet
    With Workbooks.Open(File.FullPath, False, True)
        For Each WS In .Worksheets
            If Not WS.Cells.Find(What:=target) Is Nothing Then
                '発見
                Debug.Print File.Path
                'このブックの検索は終了
                Exit For
            End If
        Next
        .Close False
    End With

※実際にデバッグはしていないので、ご自分で調整して下さい。
※ブック数が多いと時間がかかると思いますのでご注意を。

Comments

[seiya811]

返信が遅くなってしまい申し訳ありません。

修正していただいたコードで思い通りに動かすことが出来ました！
ありがとうございます！

Answer 2

対象フォルダ内のブックをひとつひとつ開いて検索しないといけないでしょうね。
ループで回すところはできているので、その中でブックを開く→検索を行えばいいだけですね。

Comments

[seiya811]

返信が遅くなってしまい申し訳ありません。

コメントありがとうございます。
アドバイスを参考に自分なりに作ってみます。