OutLookのVBAにて、MailItemが思った動作をしない事

Question

Outlook2010で、Aのﾒｰﾙを開いた時に何かしら処理をして
又、そのAのﾒｰﾙを閉じた時に、別の処理(ﾒｰﾙ作成、送信)をしようと考えています。

Outlook　vba　の　ThisOutlookSessionに下記のｺｰﾄﾞを入力しますと
通常は、

'''vba
Private WithEvents g_mailItem As mailItem ''(1)

Private Sub g_mailItem_Open(Cancel As Boolean) ''(2)
Ａのメールを開いた時の処理をする
End Sub
Private Sub g_mailItem_Open(Cancel As Boolean) ''(3)
Ａのメールを閉じた時の処理
'（別の送信ﾒｰﾙを作成し、送る）
Dim objOutlook As Outlook.Application
Dim objMail As Outlook.MailItem
Dim wsMail As Worksheet

Set objOutlook = New Outlook.Application
Set wsMail = ThisWorkbook.Sheets("メール内容")
Set objMail = objOutlook.CreateItem(olMailItem)
With wsMail
objMail.To = "[e-mail]" 'メール宛先
objMail.Subject = .Range("B1").Value 'メール件名
objMail.BodyFormat = olFormatPlain 'メールの形式
objMail.Body = .Range("B2").Value 'メール本文
objMail.Send
End With
Set objOutlook = Nothing

End Sub
Private Sub Application_ItemLoad(ByVal Item As Object) ''(4)
Dim mailItem As mailItem
If TypeOf Item Is mailItem Then
Set g_mailItem = Item
End If
End Sub
'''

にて、正常に動作しているのですが

下記の動作をした時に動作しません
⓵　Ａのﾒｰﾙを開いてから、Ｂのﾒｰﾙを開き、ＡかＢのﾒｰﾙを閉じた時のｲﾍﾞﾝﾄ
⓶　Ａのﾒｰﾙを開いてから、Ａのﾒｰﾙを閉じ、受信ﾌｫﾙﾀﾞｰで他のﾒｰﾙを選択しないで
再びＡのﾒｰﾙを開いた時

⓵の場合、g_maileitemの内容が、ＡのﾒｰﾙからＢのﾒｰﾙの内容に変わり、
closeのｲﾍﾞﾝﾄが、動作しない
⓶の場合、OUTLOOKの受信ﾌｫﾙﾀﾞで、他のﾒｰﾙを選択しないで同じﾒｰﾙを選択すると
ItemLoadのｲﾍﾞﾝﾄが、動作しない

と思われます。

別に、Ａのﾒｰﾙを開いた後、Ｂのﾒｰﾙを開いても　cansel=true等で　開かなくてもいいです。
何か方法は無いですか？

Comments

[imihito]

情報の追記の依頼：①このコードはどのホスト上（Excel or Outlook or ...）のどのモジュールに記述していますか？ 修正の依頼：①タグにVBAを追加してください / ②コード全体の前の行に空行+「```vba」、後の行に「```」+空行、を追加しコードにシンタックスハイライトが適用されるようにしてください

[toshikida]

ｱﾄﾞﾊﾞｲｽして頂き、有難うございました

Answer 1

通常、Excel外部からThisWorkbookは参照できないはずなのですが、それはさておき。

Outlook2016だと以下のコードで、希望と思われる動作になりました（最低限のロジックに絞っています）。

'ThisOutlookSession

Private WithEvents currentMailItem As Outlook.MailItem
Private currentMailIsOpend As Boolean

Private WithEvents cancelMailItem As Outlook.MailItem


Private Sub currentMailItem_Open(Cancel As Boolean)
    currentMailIsOpend = True
    Debug.Print "メールを開いた時の処理:"; currentMailItem.Subject
End Sub

Private Sub currentMailItem_Close(Cancel As Boolean)
    currentMailIsOpend = False: Set cancelMailItem = Nothing
    Debug.Print "メールを閉じた時の処理:"; currentMailItem.Subject
End Sub


'Ａのﾒｰﾙを開いた後、Ｂのﾒｰﾙを開いても　cansel=true等で　開かなくてもいい
Private Sub cancelMailItem_Open(Cancel As Boolean)
    Cancel = True
    Debug.Print "cancelMailItem Cancel"
End Sub


Private Sub Application_ItemLoad(ByVal Item As Object)
    If Not TypeOf Item Is Outlook.MailItem Then Exit Sub
    
    If currentMailIsOpend Then
        Debug.Print "Cancel load"
        Set cancelMailItem = Item
    Else
        Debug.Print "Current load"
        Set currentMailItem = Item
    End If
    
End Sub

⓵　Ａのﾒｰﾙを開いてから、Ｂのﾒｰﾙを開き、ＡかＢのﾒｰﾙを閉じた時のｲﾍﾞﾝﾄ
Ａのﾒｰﾙを開いた後、Ｂのﾒｰﾙを開いても　cansel=true等で　開かなくてもいいです。

初期状態だとcurrentMailIsOpendがFalseなので、ロードしたItemはcurrentMailItemにセットされます。
メールが開かれるとcurrentMailIsOpendがTrueになります。

currentMailItemが開いている間はcurrentMailIsOpendがTrueなので、ロードしたItemはcancelMailItemにセットされ、Cancel = Trueによって開かれません。

メールが閉じられるとcurrentMailIsOpendがFalseになるため、他のメールを開けるようになります。

⓶の場合、OUTLOOKの受信ﾌｫﾙﾀﾞで、他のﾒｰﾙを選択しないで同じﾒｰﾙを選択すると

ItemLoadのｲﾍﾞﾝﾄが、動作しない

何もしなくても再度開いたときにMailItem_Openなどは動くので、特に対処はしていません。