VBAの質問です pagesetup.pages.countの結果が0になる

Question

前提・実現したいこと

（例）VBAでexcelファイルを自動印刷できるコードを書いています。
印刷枚数を取得する機能を実装中に以下のエラーメッセージが発生しました。

発生している問題・エラーメッセージ

あるワークシートにおいて、手動で印刷枚数を確認すると１０枚印刷されると表示されるにも関わらず、pagesetup.pages.countで印刷枚数を取得すると0枚となる。

該当のソースコード

dim howmanyP as long
dim ws as worksheets

'中略
for each ws in worksheets
howManyP = howManyP + Worksheets(ws.Name).PageSetup.Pages.Count
Next

試したこと

すべてのシートで0枚になるわけではなく、例えばセルA1:Z100のセルの背景色を設定したページにおいて発生します。

手動でそのシートを印刷しようとすると印刷枚数が１０枚になりますと出てくるので、pagesetup.pages.countで取得しても同じように10が入ると思ったのですが、0となってしまいます。

いろいろなサイトを調べたのですが、0になる理由がどうしても出てこなかったので教えていただけると嬉しいです。
また、正しく印刷枚数を把握できる代案があればよろしくお願いいたします。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Comments

[imihito]

`ws`と`Worksheets(ws.Name)`を使い分ける意味はあるのでしょうか？

[ken8888]

ご指摘ありがとうございます。

Answer 1

Excel 2007と2010ではPages.Countにバグがあるようですね。
https://support.microsoft.com/ja-jp/help/2439589

これに該当するか分かりませんが、一応改ページにしてから枚数取得するようにしてみてはどうでしょう。
あとはイミディエイトウィンドに情報を吐いて枚数が正しくないページを見比べることで原因が切り分けられるかもしれません。

細かい点ですが wsの宣言は「Worksheets」じゃなくて「Worksheet」でしょうか。（s無し）

Dim howmanyP As Long
Dim ws As Worksheet

For Each ws In Worksheets
    '改ページ表示
    ws.Activate
    ActiveWindow.View = xlPageBreakPreview

    '枚数取得
    howmanyP = howmanyP + Worksheets(ws.Name).PageSetup.Pages.Count
    
　　'イミディエイトウィンドに各シートの名前と枚数表示
　　Debug.Print ws.Name, Worksheets(ws.Name).PageSetup.Pages.Count
Next

一応、代案の書き方もありますが、これも正しく取得できないケースがあるので参考までということで。
https://support.microsoft.com/ja-jp/help/2838848

For Each ws In Worksheets
    ws.Activate
    howmanyP = howmanyP + Application.ExecuteExcel4Macro("get.document(50)")
Next

Comments

[ken8888]

お返事ありがとうございます。
kobacさんの改ページコードを追加したところ、正常に動くようになりました！
ありがとうございました！

[kobac]

「質問への追記」でimihitoさんがご指摘されてますが
howmanyP = howmanyP + Worksheets(ws.Name).PageSetup.Pages.Count　の記述は
howmanyP = howmanyP + ws.PageSetup.Pages.Count　でいいですね

[ken8888]

そうですね。ご指摘ありがとうございます。