正規表現を用いた住所内に含まれる漢数字の置換

Question

前提・実現したいこと

番地等の区切りについてハイフンや丁目番地表記が混在している住所のテキストデータを、
ハイフン区切りに統一したいと考えております。
正規表現を使えば何とかなりそうということが分かったので調べながらやってみました。
正規表現に触れるのはこれが初めてです。

発生している問題・エラーメッセージ

例えば
"ほげ町三丁目２０１８"
というテキストを
"ほげ町三－２０１８"
と置き換えたいと思い、下記のコードを書いてみました。
しかし結果としては「ほげ町－２０１８」と三丁目が丸ごと消えてしまいました。

途中でmsgboxを出す時には「丁目」だけを拾えているようなので
それをReplaceメソッドで置換に使えばいいのかと思ったのですが、うまくいきません。

該当のソースコード

Private Function 丁目番を正規表現で拾って置き換え(ByVal 文字列 As String) As String

Dim re_choume As New RegExp
Dim mc_choume As MatchCollection
Dim m As Match
Dim i As Long
Dim tex As String
Dim returntex As String

tex = 文字列

re_choume.Pattern = "[一二三四五六七八九十〇]+(丁目)"
re_choume.Global = True
Set mc_choume = re_choume.Execute(tex)

For Each m In mc_choume
    For i = 0 To m.SubMatches.Count - 1
        MsgBox m.SubMatches(i)'ここでは「丁目」だけが表示される
    Next
Next m

returntex = re_choume.Replace(tex, "－")
丁目番を正規表現で拾って置き換え = returntex


End Function


'テスト用コード↓
Sub tesuto()
Dim aa As String
Dim bb As Variant

aa = "ほげ町三丁目２０１８"
bb = 丁目番を正規表現で拾って置き換え(aa)

Debug.Print bb

End Sub

''結果↓
'ほげ町－２０１８

試したこと

正規表現の定義？でカッコでくくる位置を変えてみたりしました。
「丁目」を‐に直接置換する方法も考えましたが、
あとあと～番～号みたいな住所の置換もあるだろうことを踏まえて
できれば正規表現でクリアしたく考えております。

根本的に正規表現に関する理解の浅いところであり大変恐縮ですが、
よろしくお願いいたします。

Comments

[think49]

「銀座一丁目駅」が「銀座一駅」に置換されるのはいいのでしょうか。

[yksg]

ご指摘ありがとうございます。対象とするデータに、駅名が入ることはないので大丈夫です。でもそういう問題もあるのですね…

Answer 1

補足。
SubMatchesは、正規表現パターンに一致した文字列のうち、括弧で囲ったかたまりごとに一致したものが入ります。

[一二三四五六七八九十〇]+(丁目)

であれば、括弧は1つ、丁目しか囲われていないので、サブマッチは1つ、「丁目」のみ。
ここで、正規表現パターンを2つの括弧に変更して、メッセージボックスに何が出るかを試してみてください。

([一二三四五六七八九十〇]+)(丁目)

前半の番地と、丁目の2つが表示されるはずです。
で、Replace処理の「置換先の文字」に「$1」や「$2」を入れると、それはサブマッチの1番目、2番目の文字に置き換わります。上記の例だと、番地の数字部分が「$1」、丁目が「$2」になります。

otnさんのサンプルコードでは、括弧を番地の部分だけにして「$1」には番地の数字が入るようにし、そこは残したまま残りの部分をハイフンに置換しているのですね。

Comments

[yksg]

丁寧なご説明いただきありがとうございます。
とても分かりやすく、otnさんの回答と合わせて試したところ少し分かったような気がします。
試行錯誤しながら理解を深めていきたいと思います。
ご回答いただけましたお二方とも大変助かりました。

Answer 2

なんか、replaceの機能を理解できてない気がします。

re_choume.Pattern = "([一二三四五六七八九十〇]+)丁目"
re_choume.Global = True

returntex = re_choume.Replace(tex, "$1－")
丁目番を正規表現で拾って置き換え = returntex

Comments

[yksg]

早々にご回答いただきありがとうございます。
正直に申しますとまだ理屈からしっかり理解できていない感じはあるのですが、
ご教示いただいたコードで期待通りの結果を出せました。
大変助かりました。