バッチで当月日付のついたファイルのみ処理をしたい

Question

以下のように任意のディレクトリにあるファイルで当月のついたものだけ抽出、その後し加工を行いたいと考えています。

c:\test
test_1000_201807.db
test_2000_201807.db
test_1000_201808.db
test_2000_201808.db
test_1000_201809.db
test_2000_201809.db

処理をする月が2018年9月の場合、ファイル名に201809のものだけ抽出し、順番に処理を行いたいです。

以下のようにfor文でバッチを書きましたが、ファイルが1つしか抽出されません。

@echo off
set WORK_DIR=C:\test
set COPY_DIR=%WORK_DIR%\temp
set LOG=%WORK_DIR%\test.log

call :LOG "*** 処理開始 ... ***"
for /F "tokens=1* delims=" %%a in ('dir /b /O:D %WORK_DIR%*.db') do set filename=%%a
copy "%filename%" %COPY_DIR%
sqlite3 %filename% < test.query >> test_%filename%.csv
)
call :LOG "*** 処理終了 ... ***"
:LOG
echo %DATE%-%TIME% %~1>>%LOG%

どのようにすれば抽出したファイルを順番に変換することができますでしょうか。
知見が無く困っております。大変恐縮ですが、皆さんのお知恵を貸していただければ幸いです。

Answer 1

for文のところはこれでいいのでは？

set t=%date:~0,4%%date:~5,2%

for %%f in (%WORK_DIR%*%t%.db) do (
  echo %%f
)

Comments

[work307]

回答ありがとうございます。
*201809.dbが抽出されてしまい該当するファイルが抽出できません。
以下の2ファイルを抽出してCSV変換したいのですが他に方法はありますでしょうか。
test_1000_201809.db
test_2000_201809.db

[YAmaGNZ]

そのファイルの他に何のファイルが抽出されているのですか？
例に挙げられているファイル名の他に*201809.dbにマッチするファイル名が存在するということですか？

[work307]

申し訳ありませんこちらのミスでした。
問題なく表示できました。

Answer 2

質問のコードだと、そもそも、年月で抽出していませんが？

@echo off
set WORK_DIR=C:\test
set COPY_DIR=%WORK_DIR%\temp
set LOG=%WORK_DIR%\test.log
set YYYYMM=%DATE:~0,4%%DATE:~5,2%

call :LOG "*** 処理開始 ... ***"
for /F "delims=" %%a in ('dir /b /O:D %WORK_DIR%*%YYYYMM%.db') do call :EXEC %%a
call :LOG "*** 処理終了 ... ***"
goto :EOF
:LOG
echo %DATE%-%TIME% %~1>>%LOG%
goto :EOF
:EXEC
set filename=%1
copy "%filename%" %COPY_DIR%
sqlite3 %filename% < test.query >> test_%filename%.csv
goto :EOF

#追記
普通はこうか。

@echo off
set WORK_DIR=C:\test
set COPY_DIR=%WORK_DIR%\temp
set LOG=%WORK_DIR%\test.log
set YYYYMM=%DATE:~0,4%%DATE:~5,2%

call :LOG "*** 処理開始 ... ***"
for /F "delims=" %%a in ('dir /b /O:D %WORK_DIR%*%YYYYMM%.db') do (
  copy %WORK_DIR%\%%a %COPY_DIR%
  sqlite3 %WORK_DIR%\%%a < test.query >> test_%%a.csv
)
call :LOG "*** 処理終了 ... ***"
goto :EOF
:LOG
echo %DATE%-%TIME% %~1>>%LOG%
goto :EOF

Comments

[work307]

回答ありがとうございます。
*201809.dbが抽出されてしまい該当するファイルが抽出できません。
以下の2ファイルを抽出してCSV変換したいのですが他に方法はありますでしょうか。
test_1000_201809.db
test_2000_201809.db

[otn]

> *201809.dbが抽出されてしまい該当するファイルが抽出できません。
とは、具体的にどんな現象でしょうか？

[work307]

申し訳ありません。こちらのミスでした。
追記していただいた内容で当月の日付のファイルが抽出できました。

質問ばかりで申し訳ありませんが、201808のファイルだけ抽出したい場合はどのように記述を行えば宜しいでしょうか。
SETを以下のように指定しましたが、今度はすべてのファイルが表示されるようになってしまいました。

```SET
set YYYYMM=%DATE:~0,4%%DATE:~5,2%
set /TEST dd=%YYYYMM%-1
```

[otn]

？？2行目のSETは、どういうつもりですか？エラーになりませんか？

> 201808のファイルだけ抽出したい場合
set YYYYMM=201808

[work307]

はい。エラーになります。
当月日付201809からマイナス1したもの201808で抽出したいのですが上手くいきません。

[otn]

年またぎがあるので、1文では無理ですね。計算は set /a です。
set YYYYMM=%DATE:~0,4%%DATE:~5,2%
set /a YYYYMM-=1
if %YYYYMM:~4,2% == 00 set /a YYYYMM=YYYYMM-100+12

[work307]

ありがとうございます。
目的のファイル名が抽出できました。

[work307]

if %YYYYMM:~4,2% == 00 set /a YYYYMM=YYYYMM-100+12
↑
この部分が全く理解できないのが恥ずかしいです。

[otn]

考えれば分かるレベルなので、考えてください。
%YYYYMM:~4,2%
は、5文字目から2文字、つまり月の部分です。

[work307]

ありがとうございます。

Answer 3

BAT など不要。
そう、PowerShell 芸ならね！

$WORK_DIR = 'C:\test'
$COPY_DIR = "$WORK_DIR\temp"
$LOG = "$WORK_DIR\test.log"

function Log
{
    Param([String] $Message)
    $time = [DateTime]::Now.ToString("yyyy-MM-dd hh:mm:ss")
    "$time $Message" >> $LOG
}

Log "*** 処理開始 ***"

$mon = [DateTime]::Today.ToString("yyyyMM")
Get-ChildItem *_$mon.db | ForEach-Object {
    Copy-Item $_ $COPY_DIR
    Get-Content test.query | sqlite3 $_ >> test_$_.csv
}

Log "*** 処理終了 ***"

Comments

[work307]

ありがとうございます。
PowerSlellとても勉強になります。

[Zuishin]

これはほぼ冗談の回答ですが、bat より強力で扱いやすいので、本気で移行を考える価値はあります。
bat を使い続けるのであれば、他に C++ など exe を作れるものや Python などのスクリプト言語を扱える能力が必要となると思います。