テキストファイル読み込みエラーの処理

Question

こんにちわ
VBAをかいています

テキストファイルから1行ずつデータを読み込み、特定の文字を見つけたらそこから2行データを抽出し、また次の行へと進んでいくマクロをかいています
このとき、特定の文字をみつけた次の次の行が空(ない)の時にエラー画面をだしたいのですが、どうかけばいいのかわかりません
以下がループ部分のコードです

Do Until EOF(txtnum)
   '2行目よみこみ
   Line Input #txtnum, line1
   If InStr(line1, "東京") > 0 Then
       tokyoFlg = "1"
   Else

   If tokyoFlg = "1" Then
                        
      '2行目が空
        If line1 = "" Then
   　     　MsgBox "不正なデータが含まれているため処理を終了します"
        End
        End If
　   3行目読み込み
        Line Input #txtnum, line2
                             
      '2行目日付を取得
        data = getdata(line1, data)
                            
　   '3行目が空
　     If line2 = "" Then
  　       MsgBox "不正なデータが含まれているため処理を終了します"
       End
　    End If

      '3行目場所を取得
        citydata = getcitidata(line2, citydata)
                                                               
 Print #filenum, data,citydata
      '初期化
      data = ""
      citydata = ""
      tokyoFlg = ""                           
End If
g = g + 1
End If
Loop

テキストファイルのイメージとしては、
東京
2018/08/29　はれ
大田区
東京
2018/08/30
世田谷区　くもり
…
こんな形で東京という行から２行分から必要な部分を抽出し出力させたいです
現在きちんと東京から2行分のデータがあればエラーもなく正常処理として終わるのですが、
たとえば、

東京
2018/08/29　くもり
大田区
東京
2018/08/29　はれ

こんな形で2行分きちんとデータがないときにエラーをだして処理を終了させたいです
データがないと
3行目読み込み
Line Input #txtnum, line2
の部分でエラーが出ます
もちろん次の行が読み込めないのでエラーになるのはわかるのですが、東京から次の一行目（日付、天気の行）は存在し、その次がない場合のエラー処理方法がよくわかりません

よろしくお願いいたします。

追記
皆様回答ありがとうございました
一番シンプルに解決したものをBAにさせていただきました

Answer 1

次の関数を呼出して、全部読込んでから処理した方がエラーもなく、効率が良いと思います。

※pathSRC: ファイルのFull Path

使用例：　

txtTEST = ReadTxt("C:\Temp\Test.txt")
For Each L In Split(txtTEST, vbCrLf)
...
Next

Function ReadTxt(pathSRC) As String
    Set objFS = CreateObject("Scripting.FileSystemObject")
    ReadTxt = objFS.OpenTextFile(pathSRC, 1).ReadAll
    Set objFS = Nothing
End Function

Answer 2

まず、「End」を使うのは禁止してください。
これはプログラムを強制終了させるもので、
Exit Do, Exit For, Exit Function, Exit Sub 等とする方が無難です。

インデントは下記のように揃えた方が見やすいです。

そして処理は、東京を１番目とするデータセットなので、
その通りにデータが何番目なのかカウントするようにすれば、
処理が明確かつ簡単になります。

読込処理を複数書くのは、メンテしにくいと思うので
１か所だけにした方が分かりやすい気がします。

そして処理の最後にちゃんとテキストファイルを閉じてください。

    Do Until EOF(txtnum)
        
        G = G + 1
        
        '1行よみこみ
        Dim LineVal As String
        Line Input #txtnum, LineVal
        
        If InStr(LineVal, "東京") > 0 Then
            Dim LineNo  As Long
            LineNo = 1
        Else
            LineNo = LineNo + 1
        End If
        
        Select Case LineNo
        Case 1  '東京
            'データのセット数をカウント
            Dim DataNo  As Long
            DataNo = DataNo + 1
            
        Case 2  '日付
            '2行目が空
            If LineVal = "" Then
                MsgBox "不正なデータが含まれているため処理を終了します"
                Exit Do
            End If
            
            '2行目日付を取得
            Dim DateVal As String
            DateVal = GetData(LineVal, Data)
            
        Case 3  '区
            '3行目が空
            If LineVal = "" Then
                MsgBox "不正なデータが含まれているため処理を終了します"
                Exit Do
            End If
            
            '3行目場所を取得
            citydata = getcitidata(LineVal, citydata)
            
            '書込み
            Print #FileNum, Data, citydata
            
            '初期化
            Data = ""
            citydata = ""
        End Select
        
    Loop
    
    'Close処理(txtnum、FileNumともに必須)

Answer 3

EOFでも構わず読む進めてしまっているのが原因ではないでしょうか。
現状読み込み結果が空文字かどうかで判定しているので、EOFかEOFではないときに読み込んだデータが空文字ならエラーにするべきです。
というわけでLine Input を関数化してしまうのが手っ取り早い対応かと思います。

' 読み込み処理
Function GetLine(txtnum As Integer) As String
    If EOF(txtnum) Then
        GetLine = ""
    Else
        Line Input #txtnum, GetLine
    End If
End Function

Line Input のところはこんな感じにする。

   Line Input #txtnum, line1
     ↓
   line1 = GetLine(txtnum)