schemeでdoループを利用してlistを作りたい

Question

schemeでdoループを利用してvector3のlistを作りたいと思っています。
doループの部分は何とか出来ました。

(do ((x -5 (+ x 1)))
     ((> x 5))
   (do ((y -5 (+ y 1)))
       ((> y 5))
     (print x " " y "\n")))

ここで、このループを利用して、このループの走る順番に要素(x,y,0)の入ったvector3を要素とするlistを作りたいと思っています。

vector3の説明

ですが、どのようにしたらいいかわかりません。
分かる方がいらっしゃったらお願いします。

Answer 1

doを使わなくてよければ、こんな感じですかね。

(map (lambda (x) (map (cut vector3 x <> 0) (iota 11 -5)))
     (iota 11 -5))

Answer 2

いくつかの方法が考えられますがそのような形で do を使ったループを前提とするならば、リストを末尾から組み立てて、最後に反転させるのが最も簡単な方法だと思います。

(let ((r '()))
  (do ((x -5 (+ x 1)))
      ((> x 5))
    (do ((y -5 (+ y 1)))
        ((> y 5))
      (set! r (cons (vector3 x y 0) r))))
  (reverse r))

Answer 3

線形リストの最後にどんどん追加していく方法もありますねっ。(・∀・)

(define my-vector3-list
  (let* ((queue (list #f)) (queue_last queue)) ; queue_last は線形リストの最後セルだよっ。
    (do ((x -5 (+ x 1))) ((> x 5))
      (do ((y -5 (+ y 1))) ((> y 5))
        (set-cdr! queue_last (list (vector3 x y 0)))
        (set!     queue_last (cdr queue_last))
      )
    )
    (cdr queue) ; 先頭の #f はゴミデータだから捨てるんだ
  )
)