Outlook VBA 受信メールの添付ファイルを新規メールへ添付したい

Question

現在Windows10(64bit)のOutlook2016で以下の処理をVBAで実装しております。
・特定のフォルダに受信されたメールの添付ファイルを、新規作成するメールへ添付して送信

下部のように書いたプログラムを実行すると
nMail.Attachments.Add vAttachments
の部分でエラーになります。
エラー内容は「ファイルが見つかりません。パスとファイル名が正しいかどうかを確認してください。」です。

Outlook上では該当の受信メールの添付ファイルは正常に開けて、保存もできます。
同じプログラムで1日前まで動いていたのですが、突然動かなくなりました。

また、新規作成メールへ添付する際に、パス指定だとエラー無く添付することが出来ます。

そのため1度ローカルへ保存しようと試みましたが、エラーになります。
エラー内容は「添付ファイルを保存できません。この操作を行うために必要なアクセス権がありません。」です。

稚拙な文となってしまい申し訳ございませんが、八方塞状態です。
お知恵を拝借できないでしょうか。
他にも必要な情報等ありましたら、ご質問ください。
よろしくお願いします。

以下実装しているプログラムの抜粋となります。

'新規メールの作成前に mITEM に受信メールを設定しておく

'新規メールの作成
Dim nMail As Outlook.MailItem
Set nMail = Application.CreateItem(0)

'受信メールから添付ファイルを取得
Dim vAttachments As Variant
vAttachments = mITEM.Attachments.Item(1)

'新規メールに 件名、宛先、本文、添付ファイルをセット
nMail.Subject = "件名"
nMail.To = "[e-mail]"
nMail.Body = "本文です。"

'パス指定だと添付できる
nMail.Attachments.Add "C:\Users\test.pdf"

'1度ローカルへ保存しようとするがエラーになる
'mITEM.Attachments.Item(1).SaveAsFile "C:\Users\jushintemp.pdf"

'受信メールの添付ファイルが新規作成メールに添付できない  
nMail.Attachments.Add vAttachments  '←ここでエラー


'送信
nMail.Send

Answer 1

AttachmentオブジェクトをAttachments.Addするのは、こちらで実行してみてもエラーになりました。
申し訳ないですが、原因は分かりません。(動いていたとの事なので、OfficeのUpdateでNGになったのでしょうか・・・)

とりあえず、ローカルに保存するアイデアで問題ないと思います。
保存に失敗するのは”C:\Users”フォルダの書き込み権限がないからです。
ですので、代わりにユーザー別の一時ファイルフォルダ等を使用すればよいです。

以下、参考までに添付ファイルコピー関数を貼っておきます。

'添付ファイルをコピー
Sub CopyAttachments(oSourceMail, oTargetMail)
   Set FSO = CreateObject("Scripting.FileSystemObject")
   '一時ファイルフォルダ取得
   Set fldTemp = FSO.GetSpecialFolder(2)
   
   '添付ファイルコピー開始
   For Each oItem In oSourceMail.Attachments
      '一時ファイル保存
      sFile = FSO.BuildPath(fldTemp.Path, oItem.FileName)
      oItem.SaveAsFile sFile
      '添付ファイル追加
      oTargetMail.Attachments.Add sFile, , , oItem.DisplayName
      '一時ファイル削除
      FSO.DeleteFile sFile
   Next

   Set fldTemp = Nothing
   Set FSO = Nothing
End Sub

Comments

[thachi]

ご回答ありがとうございます。

そちらでもエラーが出ましたか。
やはり安定して稼動させるのは難しそうです。

保存についてもご回答、サンプルのご教示ありがとうございます。
こちらの環境で試したところ正常に保存でき、保存したファイルを添付することを確認できました。

OutlookのVBAに関してはなかなか情報が少なく難儀しておりましたが助かりました。
ありがとうございました。