特定の文字を見つけたらﾙｰﾌﾟを終了したい

Question

こんにちわ。
Excelでマクロを書いています。

テキストファイルから、最初の5行を読み飛ばし
そのあと4行ごと取得し、必要な部分を出力し
1行目に特定の文字がでてきたらﾙｰﾌﾟを終了するというものを書きたいです。

Sub Run()
    Dim OpenFileName As String
    'ファイルを開くダイアログ
    ChDir ThisWorkbook.Path & "\"
    OpenFileName = Application.GetOpenFilename("テキストファイル,*.txt")
    
    If OpenFileName <> "False" Then
        Open OpenFileName For Input As #1
    End If
    
    Dim buf As String
    '5行読み飛ばし
    Line Input #1, buf
    Line Input #1, buf
    Line Input #1, buf
    Line Input #1, buf
    Line Input #1, buf
    
    Do While InStr(line1, "おわり") > 0
    
    Dim line1 As String
    Dim line2 As String
    Dim line3 As String
    Dim line4 As String
    
    '4行読み込み
    Line Input #1, line1
    Line Input #1, line2
    Line Input #1, line3
    Line Input #1, line4
    
    Close #1
    
-処理（省略）-
    
    Debug.Print , a + b + c + d ;
    
    Loop
    
    Close

    End Sub

1行目に　おわり　という文字がきたらﾙｰﾌﾟを抜けたいです。
今これを実行すると、
コンパイルエラー
同じ適用範囲内で宣言が重複しています。
というエラーが　Do While InStr(line1, "おわり") > 0
の部分ででてきます。
line1は1度しか宣言していません。
省略している処理の中ではline1に関しては何も記述はありません。
なぜこのようなエラーがでてきるのでしょうか？
解決方法があれば、アドバイスいただけますと嬉しいです。

よろしくお願いいたします。

Answer 1

Do...Loopの条件が変ではありませんか？

現在の条件は、「line1におわりが含まれている間ループする」となっています。

質問にある動作を行う場合、「読み取ってから判定する」となるため
Whileを使わず、Exit Doでループを抜けた方が書きやすいと思われます。

Sub Run()
    Dim OpenFileName As String
    'ファイルを開くダイアログ
    ChDir ThisWorkbook.Path & "\"
    OpenFileName = Application.GetOpenFilename("テキストファイル,*.txt")
    
    If OpenFileName = CStr(False) Then
        MsgBox "選択がキャンセルされました。", vbInformation
        Exit Sub
    End If
    
    Open OpenFileName For Input As #1
        
        Dim buf As String
        '5行読み飛ばし
        Dim i As Long
        For i = 1 To 5
            Line Input #1, buf
        Next i
        
        Do
            Dim line1 As String
            Dim line2 As String
            Dim line3 As String
            Dim line4 As String
            
            '4行読み込み
            Line Input #1, line1
            'Whileの代わり
            If InStr(1, line1, "おわり") > 0 Then
                Exit Do
            End If
            
            Line Input #1, line2
            Line Input #1, line3
            Line Input #1, line4
            
            'Dim a, b, c, d
            '-処理（省略）-
            
            Debug.Print , a + b + c + d;
            
        Loop

    Close
End Sub

Comments

[pro-poke5]

Do...Loopの考え方をきちんと理解していませんでした…。
Do whileで条件をかくことばかり考えてExit Doの考え方が思いつきませんでした。
ありがとうございます。

Answer 2

何のために「Dim 〇〇」と宣言していると思ってますか？

その意味が分かれば、宣言前に使っていたらエラーになるのは、当たり前のことだと理解できますよ。

あと、ステップ実行、ローカルウィンドウ、イミディエイトウィンドウ等を使って
自分でデバッグしてから出直してください。

Answer 3

こんにちは。
下記Afterのように、Dim文をWhile文よりも前に出してみるといかがでしょうか。

#Before

Do While InStr(line1, "おわり") > 0

    Dim line1 As String
    Dim line2 As String
    Dim line3 As String
    Dim line4 As String

#After

Dim line1 As String
Dim line2 As String
Dim line3 As String
Dim line4 As String

Do While InStr(line1, "おわり") > 0

Dim文をWhileループ内で実行しているために何度も実行されてしまうのではないでしょうか。

Comments

[pro-poke5]

ありがとうございます。
エラーはでなくなりましたが、何も出力されなくなりました。。。
もちろんﾙｰﾌﾟ文なしの状態でじゃうまく出力できていました。