VBScriptでArrayListを使って二次元配列を作りたい

Question

前提・実現したいこと

私、VBScriptでArrayListを使い2×2の二次元配列を作ろうとしておりますが、実行時の処理が思い通りにいかず困っています。

原因または解決策をご存じの方はいらっしゃいませんか。

ただ今後、要素が増える可能性がございますので、要素が増えても対応できる処理にしようと考えております。
私の行った手順は以下です。

該当のソースコード

Option Explicit
On Error Resume Next

''''ArrayListの作成''''
Dim myArrayList				'全データ保存用配列
 Set myArrayList = CreateObject("System.Collections.ArrayList")

Dim oneArrayList			   'データ追加用配列
 Set oneArrayList = CreateObject("System.Collections.ArrayList")

''''要素の追加''''　　　　　　　　 
oneArrayList.add   "A-A"
oneArrayList.add   "A-B"

myArrayList.add oneArrayList	'A,Bが入った配列を保存用に追加

oneArrayList.Clear()			'要素を削除

oneArrayList.add   "B-A"
oneArrayList.add   "B-B"

myArrayList.add oneArrayList	'C,Dが入った配列を保存用に追加

'=======================
'"A"->"B"->"C"->"D"の順に表示されるはずが、
'"C"->"D"->"C"->"D"の順に表示されてしまう。
'======================

''''要素の表示''''			
Dim inAry
Dim inData
For Each inAry In myArrayList
	For Each inData In inAry
		Wscript.Echo inData
	Next
Next

Set myArrayList = Nothing
Set oneArrayList = Nothing

試したこと

・oneArrayListを使い回さずに、新たにtwoArrayListを追加した場合、処理はうまくいきますが、
今後、three,four...と増やす訳にはいきませんので解決には至りませんでした。

補足情報（FW/ツールのバージョンなど）

WSH の バージョン :5.812
デバッガー:使っておりません、メモ帳で作成して実行しています。
OS:Windows 10
メモリ:8GB

以上です。よろしくお願い致します。

Comments

[sazi]

入れた順番で取り出すという事がしたいのですか？

Answer 1

myArrayList.add oneArrayList    'A,Bが入った配列を保存用に追加

oneArrayList.Clear()            '要素を削除

上記の部分を以下の二つどちらかに変えれば、動作としては意図したものになるはずです（実際起きていることはそれぞれ違います）。

' パターン1
' oneArrayList の中身をVariant型の配列にコピーする
myArrayList.Add oneArrayList.ToArray()    'A,Bが入った配列を保存用に追加

oneArrayList.Clear()            '要素を削除

' パターン2
myArrayList.Add oneArrayList    'A,Bが入った配列を保存用に追加

' myArrayListに追加したものとは別に"System.Collections.ArrayList"を生成する
Set oneArrayList = CreateObject("System.Collections.ArrayList")

パターン1の場合、myArrayListの中にはVariant型配列が入っています。
パターン2の場合、myArrayListの中にはSystem.Collections.ArrayListが入っています。

蛇足：値型と参照型

プログラムの中で変数などに入れて扱えるものには値型と参照型の2種類があります。

VBA / VBScript に限定して言うと、
代入時にSetを付けなくていいもの→数字・文字列・日付・配列などは値型
Setを付ける必要があるもの→オブジェクトは参照型
になります（正確には違うもの、他の言語だと違う場合もありますが簡易説明のため触れません）。

値型のものは他の変数に代入したり、myArrayList.Addをすると、コピーされます。
元のものをいじっても、他に影響は出ません。
（イメージはファイルのコピー）

対して参照型は、他の変数に代入したり、myArrayList.Addをしてもコピーされず、同じものを指しています。
（イメージはショートカットの作成）

今回使用しているSystem.Collections.ArrayListはオブジェクトなので参照型です。

そのため、今回の質問のコードだとoneArrayListは一つしかないので
myArrayListの1個目と2個目には同じものが入っていることになり、
oneArrayListに対する変更は両方に適用されます。

私のコードでは、ToArray()メソッドによって別の配列としてコピーしたり、
CreateObjectで新しいSystem.Collections.ArrayListを用意することで上記の問題を解決しています。

Comments

[leonhalt]

素早いご回答ありがとうございました。