ExcelVBAで、コードで生成した可変長の配列をセルに張りつけたい

Question

前提・実現したいこと

コードで作成した配列を、まとめて貼り付けたい。
※サイズの変動する配列を貼り付ける為、Resizeを使用したい。

Resizeでなくとも、可変長の配列を貼り付けられるのであれば、
手段は何でも構いません。

発生している問題・エラーメッセージ

下記ソースコードで貼り付けた結果、
F1～F3に、「aa」「aa」「aa」と表示されます。

該当のソースコード

Dim temp: temp = Array()
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "aa"
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "bb"
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "cc"

シート.Range("F1").Resize(UBound(temp, 1) + 1).value = temp

試したこと

Resizeが二次元配列だった場合については、
問題なく貼り付けることができましたが、
一次元配列になると途端に上手くいきません。
二次元配列（中身は1列）の場合は、参照した範囲で実行してますので下記のようなものです。

Dim temp: temp= シート.Range("A1:A3").value
シート.Range("F2").Resize(UBound(temp, 1), UBound(temp, 2)).value = temp

補足情報（FW/ツールのバージョンなど）

Microsoft Excel 2010

Comments

[unz.hori]

参考になるかな？：http://www.moug.net/tech/exvba/0100049.html

Answer 1

解決済みですが、参考までに。

可変長の一次元配列（動的配列）でも、Transpose関数で、縦一列の二次元配列に変換できます。

Dim temp: temp = Array()
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "aa"
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "bb"
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "cc"

temp = WorksheetFunction.Transpose(temp)
シート.Range("F1").Resize(UBound(temp)).Value = temp

Transpose関数の制限

Null値を含む配列はエラーがでるなどの制限があるようです。
詳細は下記のリンク先の後半の「後日談」を参照ください。

動的2次元配列の次元を入れ替えてシートへ出力（Transpose）｜VBA技術解説

Comments

[ttyp03]

そんな技があったのですね。さすが。

funmasさん
断然こちらをお勧めします。

[funmas]

気付くのが遅れ、返事が遅くなってしまいました。
コードをさらに短くできるのですね。
ttyp03さんのお勧めということもあり、BAを移動させていただきます。
お二方本当にありがとうございました。

Answer 2

一次元配列を貼り付けた場合、横方向のデータとして扱われてしまうようです。
配列をセルに一括で代入する
なので先頭のaaだけが縦方向に並んでしまいます。

正しく貼り付けるには二次元配列にするしかなさそうですが、可変長の二次元配列は最終次元しか可変にすることができません。
[VBA]多次元配列のRedimは最終次元しか変更できない

なので一次元配列でデータを作成してから二次元配列に移し変えてやる必要がありそうです。
こんな感じ。

Dim temp: temp = Array()
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "aa"
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "bb"
ReDim Preserve temp(UBound(temp) + 1)
temp(UBound(temp)) = "cc"

ReDim temp2(UBound(temp), 0)
For i = 0 To UBound(temp)
    temp2(i, 0) = temp(i)
Next

シート.Range("F1").Resize(UBound(temp) + 1).Value = temp2

Comments

[funmas]

回答ありがとうございます！
横向きになってしまっていたのですね。。
頂いた二次元に移し替えるプログラムで無事動かせることができました。
助かりました。ありがとうございます！