CODE（....）という出力で返ってくることの対処法

Question

よろしくお願いいたします。

 　　open(IN, "file.txt");
     .....
     $hensu = sub {
             if    ($letter =~ /0/) { return "OK"; }
             elsif ($letter =~ /1/) { return "warn"; }
             elsif ($letter =~ /2/) { return "error"; }
             else { return "nothning"; }
     },

と記すと、$hensuに帰ってくるのが「CODE（0x....）」になってしまいます。

CODEで出力させたくない、上記例だとOKやERRORという文字列で返したい場合はどうすれば良いのでしょうか。
ご教授いただけると幸いです。

<追記 5/15>
返事が大変遅くなり申し訳ございませんでした。
いただいたご回答、すべてベストに選びたいのですが１つしか選べず心苦しいです。
本当にありがとうございました。

Comments

[m.ts10806]

プログラムコード(およびエラーメッセージ)は```で囲ってください。（わからなければ質問編集画面でコード部分を選択し<code>ボタンを押してください）正しく反映されているかどうかは質問編集画面のプレビューを見ながら編集していってください。

[KojiDoi]

mt10806さんのコメントに補足。https://teratail.com/questions/123033 この質問の中で、LouiS0616さんが図で分かりやすく説明されているので参考にしてください。 これにより、コード部分が視覚的に区別しやすくなり、インデントも再現され、なにより、回答者が自分の環境でコードを実行しようとするときにコピペが大変簡単になります。

[wkbiz]

コメント有難うございました。

Answer 1

なぜcode何タラと返ってくるのかというと、$hensuの中身はそのオブジェクト（無名関数）そのものであって、それを関数として実行した結果ではないからですね。

質問文に寄り添ったコードを書くとすれば、次のような感じになるでしょう。

#!/usr/bin/perl -w
use strict;

my $hensu = sub {
  my($letter)=@_;
  if    ($letter =~ /0/) { return "OK"; }
  elsif ($letter =~ /1/) { return "warn"; }
  elsif ($letter =~ /2/) { return "error"; }
  else { return "nothing"; }
};

for my $i (0, 1, 2, 3){
  printf "$i %s\n", $hensu->($i);
}

Comments

[wkbiz]

ご回答ありがとうございました。
なぜそうなるのか、についてご説明いただきとても嬉しかったです。

Answer 2

ご提示のコードを極力生かすのであればeval でしょうか。

#!/usr/bin/perl

$letter = "1";

$hensu = eval {
	if ($letter =~ /0/) {
		return "OK";
	} elsif ($letter =~ /1/) {
		return "warn";
	} elsif ($letter =~ /2/) {
		return "error";
	} else {
		return "nothing";
	}
};

print($hensu . "\n");

実行結果

$ ./do01.pl
warn

ですが、普通にサブルーチン形式で定義した方が使い易いと思います。

#!/usr/bin/perl

sub func1 {
	if ($_[0] =~ /0/) {
		return "OK";
	} elsif ($_[0] =~ /1/) {
		return "warn";
	} elsif ($_[0] =~ /2/) {
		return "error";
	} else {
		return "nothing";
	}
};

$letter = "0";
$hensu = func1($letter);
printf("letter=%s, %s\n", $letter, $hensu);

$letter = "2";
$hensu = func1($letter);
printf("letter=%s, %s\n", $letter, $hensu);

$letter = "9";
$hensu = func1($letter);
printf("letter=%s, %s\n", $letter, $hensu);

実行結果

$ ./do02.pl
letter=0, OK
letter=2, error
letter=9, nothing

Comments

[wkbiz]

ご回答いただき有難うございました。
evalはちょっと考えたんですけど、やっぱり勉強不足ですね。精進します。

Answer 3

質問の意図が、「条件式の結果を変数に入れたい」と言う事なら

$hensu = sub {
    if    ($letter =~ /0/) { return "OK"; }
    elsif ($letter =~ /1/) { return "warn"; }
    elsif ($letter =~ /2/) { return "error"; }
    else { return "nothning"; }
}->() ;

で、無名サブルーチンをその場で実行すればいい。

ただ、これをするなら、通常は do{} や三項演算子など、
他にもっと方法がある。

# do{}
$hensu = do{
    if    ($letter =~ /0/) {  "OK"; }
    elsif ($letter =~ /1/) {  "warn"; }
    elsif ($letter =~ /2/) {  "error"; }
    else {                    "nothning"; }
} ;

# 三項演算子
$hensu = $letter =~ /0/ ? "OK"
       : $letter =~ /1/ ? "warn"
       : $letter =~ /2/ ? "error"
       :                  "nothning"
       ;

Comments

[wkbiz]

ご回答ありがとうございました。
勉強不足でしかないですが、無名や三項は思いつかなかったです。