zshのこの記法が理解できないのですが

Question

zsh + screen で端末に表示されてる文字列を補完する
に記載されている下記コードのうち、"${reply[@]%[*/=@|]}"の部分が理解できません。
これがどのように展開されるのか説明していただけないでしょうか？

# dabbrev
HARDCOPYFILE=$HOME/tmp/screen-hardcopy
touch $HARDCOPYFILE

dabbrev-complete () {
        local reply lines=80 # 80行分
        screen -X eval "hardcopy -h $HARDCOPYFILE"
        reply=($(sed '/^$/d' $HARDCOPYFILE | sed '$ d' | tail -$lines))
        compadd - "${reply[@]%[*/=@|]}"
}

zle -C dabbrev-complete menu-complete dabbrev-complete
bindkey '^o' dabbrev-complete
bindkey '^o^_' reverse-menu-complete

Answer 1

まず、ls -Fコマンドで、ファイル名の後にファイルの属性に応じて、* / = @ |が付くのはご存じでしょうか？[*/=@|]は、それらにマッチするワイルドカードです。

${変数名%文字列}は、変数の中身の文字列の内、末尾の「文字列部分」を削除します。ここではワイルドカードが使えます。つまり、${変数名%[*/=@|]}は、変数の中身の文字列が上記の文字で終わっていた場合、それを削除します。

${reply[@]}は、配列変数replyの全ての要素を示します。

全部合わせると、${reply[@]%[*/=@|]}は、「配列変数replyの全ての要素について、その要素の文字列が* / = @ |で終わっている場合それを削除したもの」をつなげたものです。

% ls -F
foo/ bar baz*
% A=(`ls -F`)
% echo ${A[@]}
foo/ bar baz*
% echo ${A[@]%[*/=@|]}
foo bar baz
%