ＶＢAでオブジェクト型の変数をモジュールレベルでコンストラクタするには？

Question

失礼いたします

帳簿処理用のユーザーフォームいくつかを作っています。
それぞれのフォームの構造が似ているので、イベント時の動作が変わらないコントロールに関してはコントロール名を変数化すればコードの使い回しができるだろうと思い

Set targetShSub = ThisWorkbook.Worksheets("顧客マスタ")
Set fmObjSub = fmCustomerEntry
Set fmObjContr1Sub = fmCustomerEntry.liv_Customer
Set fmObjContr2SUb = fmCustomerEntry.cob_Mode

といったコードを各プロジャーの先頭に記述したのですが、これではメンテナンスが面倒ではないかと思いました。

ではモジュールレベルでできないかと思い

Set targetShSub = ThisWorkbook.Worksheets("顧客マスタ")

をモジュールの先頭にもっていくがダメ

ではと

Private Const targetShSub as Object = ThisWorkbook.Worksheets("顧客マスタ")

としてみますが、これもダメ

調べてみると、オブジェクト型は値を設定する際、インスタンス化しないとだめなので定数にはできないとのこと

では参照渡しではどうかと、フォームのinitialize時に以下のプロジャー呼び出す用にしてみました。

Sub fmCustomerEntryName_Config(ByRef targetShSub As Worksheet, fmObjSub, fmObjContr1Sub, fmObjContr2SUb As Object)
'<<対象シート名、フォーム、コントロール名のセット>>


Set targetShSub = ThisWorkbook.Worksheets("顧客マスタ")
Set fmObjSub = fmCustomerEntry
Set fmObjContr1Sub = fmCustomerEntry.liv_Customer
Set fmObjContr2SUb = fmCustomerEntry.cob_Mode


End Sub

動くようににはなり、モジュールレベルでコントロール名を設定できるようにはなりました。

とりあえずは問題ないようですが、ほかに方法はないのか？この方法で問題はないのか？悩んでいます

お答えをいただければ幸いです

Answer 1

ご質問の件について、的外れかもしれませんが、フォーム内のコントロールオブジェクトの部品化について、私は、フォームの中からフォーム内のオブジェクト部品をコントロールするクラス（例えば、整数を入力するクラス）を作って実現しています。
例えば、整数を入力するクラスでは、数値を入力するTextBox等を指定を引数にして初期化メソッドを呼び出すと自動的にTextBoxの右隣にスピンボタンが配置され、このスピンボタンをクリックして値を変化させたり、数値以外のデータが入力されるとエラーメッセージを表示することができます。

簡単なのでソースコードを以下示します。
まず、上記のクラスは以下のように書いています。ポイントは、WithEventsです。これにより、引数で渡されたコントロールに対するイベントをクラス内で定義することができます。

Private WithEvents txtBox As MSForms.TextBox
Private WithEvents spnButton As MSForms.spinButton
Private WithEvents refButton As MSForms.CommandButton
Private myMsg As String

Public Sub InitNumber(ByVal myForm As UserForm, ByVal tBox As MSForms.TextBox, ByVal eMsg As String, ByVal init As String)
    Set txtBox = tBox
    myMsg = eMsg
    txtBox.Value = init
    txtBox.MultiLine = False
    Set spnButton = myForm.Controls.Add("Forms.SpinButton.1")
    With spnButton
        .Top = txtBox.Top
        .Left = txtBox.Left + txtBox.Width
        .Height = txtBox.Height
    End With
End Sub


Private Sub txtBox_Change()
    Dim i As Integer
    Dim j As Integer
    Dim s As String
    
    If txtBox.Value <> "" Then
    If Not IsNumeric(txtBox.Value) Then
            MsgBox myMsg
            txtBox.Value = ""
        End If
    End If
End Sub

Private Sub spnButton_SpinUp()
    Dim i As Integer
    
    i = CInt(txtBox.Value)
    txtBox.Value = CStr(i + 1)
End Sub

Private Sub spnButton_SpinDown()
    Dim i As Integer
    
    i = CInt(txtBox.Value)
    If 0 < i Then txtBox.Value = CStr(i - 1)
End Sub

次に呼び出し方ですが、フォームオブジェクトの初期処理であるUserForm_Initializeで、上記のクラスを以下のように呼び出します。

Call text1.InitNumber(Me, Me.TextBox1, "数値ではありません", "1")

引数にTextBoxを指定しているのは、フォームオブジェクト内のテキストに関する位置をフォームのエディター上で確認するためだけですので、引数で座標を指定するようなインターフェースも可能かもしれません。

コントロールの部品化では、このような方法もあるのではと思っています。

Comments

[kazuo4465]

ご返答ありがとうございます。

今回は、ttyp03さんとimihitoさんの意見を参考して、目的は達成しました。

クラスをつかってコントロールイベントの共有化は考えていたので参考になりました。

ありがとうございました

Answer 2

応用、最適化は一旦置いておいて
モジュールレベルのスコープで、読み取り専用（実行中に中身が変わらない）のオブジェクト型変数のようなものを作りたい場合、
Function / Property Get プロシージャを作成するのも一つの手です。

Private Function targetShSub() As Excel.Worksheet
    Set targetShSub = ThisWorkbook.Worksheets("顧客マスタ")
End Function

Private Property Get targetShSub() As Excel.Worksheet
    Set targetShSub = ThisWorkbook.Worksheets("顧客マスタ")
End Property

上記ふたつは動作上微妙に違いがありますが、今回の使い方であればほぼ無視できます。

役割・目的を考えるとProperty Getの方が適当ですが、馴染みが薄いと思われますので自分がわかりやすい方で良いでしょう。

ただし、必要なオブジェクトの数だけ作成する必要があるため、コードが肥大化しやすいです。

Comments

[kazuo4465]

ご返答ありがとうございます。

今回は、ttyp03さんとimihitoさんの意見を参考して、目的は達成しました。

UesrForm本体以外のコントロールと対象シートは
NameをString型で定数化して
Controls(xxxx)で指定

UserForm本体はオブジェクト型でProperty Getをつかってセットする方法をとりました

ありがとうございました

Answer 3

イベント時の動作が変わらないコントロールに関してはコントロール名を変数化すればコードの使い回しができるだろうと思い

下記のようなことでしょうか。

複数のコントロールのイベントを一つのプロシージャにまとめる(ExcelVBA) - パソコンカレッジ　スタッフのひとりごと

追記

他の人の回答へのコメントを見ました

それぞれのユーザーフォームをみたとき、似たようなイベントするコントロールがあることに気付く。
このばあいイベント内の共有部分を標準モジュールでサブルーチン化して呼び出すほうが、コード量が減るし、コードの改変が容易になる。
だたし、各フォームによって、似たようなイベントをもつコントロールであってもコントロール名が異なる。
一つの方法しては変数をpublicにするのも手だがグローバルにすると予想もつかない動きをする可能性があるので変数はフォーム内で閉じておきたい。

やはり、クラスモジュールで対応するのがベストかと思います。
具体的に何をしたいのか不明ですが、とりあえずシンプルなサンプルを。

クラスモジュール MyTextBox

Private WithEvents txtb As MSForms.TextBox

'クラスとテキストボックスを関連付け
Public Sub Bind(ByVal c As MSForms.TextBox)
    Set txtb = c
End Sub

'共通処理
Public Sub ProcA()

    MsgBox "テキストボックスの値は「" & txtb.Value & "」です。"
    
    'ここに共通処理を記述

End Sub

Private Sub txtb_Change()
    Debug.Print "テキストが「" & txtb.Value & " 」に更新されました。"
End Sub

ユーザーフォームのモジュール

Option Explicit

Dim cTextbox As New MyTextbox

Private Sub CommandButton1_Click()
    cTextbox.ProcA
End Sub

Private Sub UserForm_Initialize()
    cTextbox.Bind Me.TextBox1
End Sub

追記2

質問の、fmCustomerEntryName_Configプロシージャを見ると複数のコントロールとシートが必要のようなので、下記の方が希望に近いかな。

クラスモジュール　MyProc

Option Explicit

Private targetSh As Worksheet
Private mtxt1 As MSForms.TextBox
Private mcob1 As MSForms.ComboBox

Public Sub Init(ByRef ws As Worksheet, ByRef tb As MSForms.TextBox, ByRef cb As MSForms.ComboBox)
    Set targetSh = ws
    Set mtxt1 = tb
    Set mcob1 = cb
End Sub

Public Sub Exec()
    targetSh.Range("A1").Value = mtxt1.Value
    targetSh.Range("A2").Value = mcob1.Value
End Sub

ユーザーフォームのモジュール

Option Explicit

Dim Prc As New MyProc

Private Sub CommandButton1_Click()
    Prc.Exec
End Sub

Private Sub UserForm_Initialize()
    Prc.Init Sheet1, Me.TextBox1, Me.ComboBox1
End Sub

標準モジュールに、Public変数とプロシージャを記述することでコードの一元化は可能ですが、クラスにすることのメリットは、コードの一元化ができて、なおかつ、

　一つの方法しては変数をpublicにするのも手だがグローバルにすると予想もつかない動きをする可能性がある

という危険性も回避できます。
例えば、ユーザーフォームを同時に２つ開いて、それぞれで、MyProcクラスを生成して、対象シート、コントロールを設定しても、両者で競合することなく、正しく処理が実行されます。２つは別インスタンスになり、それぞれが独自に変数を所持できますので。

Comments

[kazuo4465]

ご返答ありがとうございます。

今回は、ttyp03さんとimihitoさんの意見を参考して、目的は達成しました。

クラスをつかってコントロールイベントの共有化は考えていたので参考になりました。

ありがとうございました

Answer 4

やりたいことがよくわからないです。
通常共通の処理を行いたい場合は、共通関数を作成し、それを呼び出す形になります。
次のような感じです。

フォームA
　イベントa
　　共通イベントa処理呼び出し
フォームB
　イベントa
　　共通イベントa処理呼び出し
標準モジュール
　共通イベントa処理

共通処理内で、特定のフォームやコントロールの情報が必要であれば、引数で渡してあげればよいです。

それから質問タイトルの「コンストラクタするには？」の意味がわからないのですが、どういった意味でしょうか。

Comments

[kazuo4465]

こちらの質問の仕方が悪かったようです。

一旦整理します

【テキストボックスA】というコントロールを配置した【ユーザーフォームA】があり、似たような仕様のフォームが複数存在するとします。

【ユーザーフォーム.モジュール.プロジャー】レベル
プロジャーのコード内に【テキストボックスA】の値を尋ねてくる記載が何度も出てくる。
その度に【ユーザーフォームA】.【テキストボックスA】.value
と書いていると打ち間違えもあるので
fmContrというオブジェクト型の変数を宣言して

fmContr＝【ユーザーフォームA】.【テキストボックスA】

としてfmContr.valueにしてやれば、打ち間違えも減るし、【テキストボックスA】の名前を【テキストボックスＢ】に変えた場合も
プロジャーの先頭に記載した
fmContr＝【ユーザーフォームA】.【テキストボックスB】.valueを１ヶ所変えればすむ

【ユーザーフォーム.モジュール】レベル
各プロジャーを取りまとめたモジュールレベルで見たとき【テキストボックスA】の値を尋ねてくる記載がモジュール内のほかのプロジャーでもあることに気付く。

ならば

fmContr＝【ユーザーフォームA】.【テキストボックスA】

をモジュールレベルで設定できれば、

各プロジャーの先頭に
fmContr＝【ユーザーフォームA】.【テキストボックスA】

を記載する必要がなくなり、【テキストボックスA】のコントロール名の変更があってもコードの改変をする箇所がモジュールレベルで１ヶ所ですむ

【ユーザーフォーム】レベル
それぞれのユーザーフォームをみたとき、似たようなイベントするコントロールがあることに気付く。
このばあいイベント内の共有部分を標準モジュールでサブルーチン化して呼び出すほうが、コード量が減るし、コードの改変が容易になる。
　だたし、各フォームによって、似たようなイベントをもつコントロールであってもコントロール名が異なる。
　一つの方法しては変数をpublicにするのも手だがグローバルにすると予想もつかない動きをする可能性があるので変数はフォーム内で閉じておきたい。

　となると、引数をつかって値を渡すというがおそらく正しい判断。

　これで問題はないが、変数の値を【ユーザーフォーム.モジュール】レベルで設定できないとモジュール内のプロジャー事に変数値の設定が必要になり、やはり面倒

・・・・こうした前提で今回質問したというわけです。

[ttyp03]

いろいろありますが、ひとつずつ。

> プロジャー
「プロシージャ」のことですか？
間違った名前を使っていると、それだけで伝わりづらいので気をつけてください。

> その度に【ユーザーフォームA】.【テキストボックスA】.value

自フォーム内であれば、わざわざフォームオブジェクトを指定する必要はありません。
【テキストボックスA】.value
と書けます。

> fmContrというオブジェクト型の変数を宣言して

この方法（元の質問で是非を質問している）がそもそもあまりしっくりきません。
フォームにはControlsオブジェクトがあるので、オブジェクト名でアクセスすることができます。
例えばこんな感じです。
Controls("TextBox1").Value = 10
なので、フォームモジュール内先頭に
Const TEXTBOX_ID = "TextBox1"
などと定義しておいて、
Controls(TEXTBOX_ID).Value = 10
とするほうがフォームロード時の処理も不要になりよいかと思います。

もしくはテキストボックスの値を取得する共通関数を用意し、それ経由にすれば対象のテキストボックスにアクセスする場所は一箇所に集約できます。
Function GetTextBoxValue() as String
GetTextBoxValue = TextBox1.Value
End Function

あとは本当にフォーム間で共通の処理などは初めに回答したとおり、共通関数を使って処理すればよいかと思います。

[kazuo4465]

ご返答ありがとうございます。

今回は、ttyp03さんとimihitoさんの意見を参考して、目的は達成しました。

UesrForm本体以外のコントロールと対象シートは
NameをString型で定数化して
Controls(xxxx)で指定

UserForm本体はオブジェクト型でProperty Getをつかってセットする方法をとりました

ありがとうございました

Answer 5

ＶＢＥでシートオブジェクトが見えますよね？
オブジェクト名を自分で変えて、その名前でコーディングすればいいかと。

Comments

[ExcelVBAer]

質問の意味を誤解してたようです。
処理対象等が異なるけど、
フォームの動作がほぼ同じだから、
同じ変数名で書いていきたいって感じですかね？

フォームの頭に変数を宣言して、
フォームのInitializeでセットして使う。
そんな感じでいいんじゃないすかねぇ。

イベント関係も合わせたいなら、
WithEvents を使うと対応できますよ。

[kazuo4465]

返答ありがとうございます

こちらの質問の仕方が悪かったようです。

一旦整理します

【テキストボックスA】というコントロールを配置した【ユーザーフォームA】があり、似たような仕様のフォームが複数存在するとします。

【ユーザーフォーム.モジュール.プロジャー】レベル
プロジャーのコード内に【テキストボックスA】の値を尋ねてくる記載が何度も出てくる。
その度に【ユーザーフォームA】.【テキストボックスA】.value
と書いていると打ち間違えもあるので
fmContrというオブジェクト型の変数を宣言して

fmContr＝【ユーザーフォームA】.【テキストボックスA】

としてfmContr.valueにしてやれば、打ち間違えも減るし、【テキストボックスA】の名前を【テキストボックスＢ】に変えた場合も
プロジャーの先頭に記載した
fmContr＝【ユーザーフォームA】.【テキストボックスB】.valueを１ヶ所変えればすむ

【ユーザーフォーム.モジュール】レベル
各プロジャーを取りまとめたモジュールレベルで見たとき【テキストボックスA】の値を尋ねてくる記載がモジュール内のほかのプロジャーでもあることに気付く。

ならば

fmContr＝【ユーザーフォームA】.【テキストボックスA】

をモジュールレベルで設定できれば、

各プロジャーの先頭に
fmContr＝【ユーザーフォームA】.【テキストボックスA】

を記載する必要がなくなり、【テキストボックスA】のコントロール名の変更があってもコードの改変をする箇所がモジュールレベルで１ヶ所ですむ

【ユーザーフォーム】レベル
それぞれのユーザーフォームをみたとき、似たようなイベントするコントロールがあることに気付く。
このばあいイベント内の共有部分を標準モジュールでサブルーチン化して呼び出すほうが、コード量が減るし、コードの改変が容易になる。
　だたし、各フォームによって、似たようなイベントをもつコントロールであってもコントロール名が異なる。
　一つの方法しては変数をpublicにするのも手だがグローバルにすると予想もつかない動きをする可能性があるので変数はフォーム内で閉じておきたい。

　となると、引数をつかって値を渡すというがおそらく正しい判断。

　これで問題はないが、変数の値を【ユーザーフォーム.モジュール】レベルで設定できないとモジュール内のプロジャー事に変数値の設定が必要になり、やはり面倒

・・・・こうした前提で今回質問したというわけです。

[kazuo4465]

ご返答ありがとうございます。

今回は、ttyp03さんとimihitoさんの意見を参考して、目的は達成しました。

ありがとうございました