com.android.support:appcompat-v7のimplementation文で波線がでる。

Question

前提・実現したいこと

Appのbuild.gradleで以下のように波線がでます。
ビルド自体は通りますが、ランタイムクラッシュにつながる可能性もあると書かれているので解決したいです。

apply plugin: 'com.android.application'

apply plugin: 'kotlin-android'

apply plugin: 'kotlin-android-extensions'

android {
    compileSdkVersion 26
    defaultConfig {
        applicationId "jp.co.iwatsu.connectviewgo"
        minSdkVersion 16
        targetSdkVersion 26
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    buildToolsVersion '26.0.2'
}

dependencies {
    implementation fileTree(include: ['*.jar'], dir: 'libs')
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jre7:$kotlin_version"
    implementation 'com.android.support:appcompat-v7:26.1.0'
                    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    implementation 'com.android.support.constraint:constraint-layout:1.0.2'
    implementation 'com.android.support:design:26.1.0'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'com.android.support.test:runner:1.0.1'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.1'
    implementation 'com.github.bumptech.glide:glide:4.4.0'
    kapt 'com.github.bumptech.glide:compiler:4.4.0'
}

発生している問題・エラーメッセージ

エラーメッセージ
All com.android.support libraries must use the exact same version specification (mixing versions can lead to runtime crashes). Found versions 27.0.2, 26.1.0. Examples include com.android.support:support-compat:27.0.2 and com.android.support:animated-vector-drawable:26.1.0 縮小... (Ctrl+F1) 
There are some combinations of libraries, or tools and libraries, that are incompatible, or can lead to bugs. One such incompatibility is compiling with a version of the Android support libraries that is not the latest version (or in particular, a version lower than your targetSdkVersion.)

補足情報（FW/ツールのバージョンなど）

Android Studio 3.0.1
gradle 3.0.1
kotlin 1.2.30

解決法

Appのbuild.gradleを以下のように変更しました。

dependencies {
    implementation fileTree(include: ['*.jar'], dir: 'libs')
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jre7:$kotlin_version"
　　// glideのimplementationを変更
    implementation('com.github.bumptech.glide:glide:4.4.0') {
        exclude group: "com.android.support"
    }
　　// glideが使用するsupport libraryのバージョンが27のようなので変更
    implementation 'com.android.support:support-v4:27.1.0'
    implementation 'com.android.support.constraint:constraint-layout:1.0.2'
　　// glideが使用するsupport libraryのバージョンが27のようなので変更
    implementation 'com.android.support:design:27.1.0'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'com.android.support.test:runner:1.0.1'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.1'
    kapt 'com.github.bumptech.glide:compiler:4.4.0'
}

Answer 1

    implementation ("com.github.bumptech.glide:glide:4.4.0") {
        exclude group: "com.android.support"
    }

とすると消えるようです。

参照：http://bumptech.github.io/glide/doc/download-setup.html

Comments

[shikasama]

無事解決できました。
また、参照URLを見て、ほかに発生していたNoSuchMethodErrorも解決できました。
本当に助かりました。ありがとうございました。