UnityのCustomShaderで頂点描画の前後がおかしくなる箇所ができる

Question

前提・実現したいこと

Unity3Dを用いてhttp://nn-hokuson.hatenablog.com/entry/2017/06/06/202953を参考に物体の頂点が法線方向に飛び散って消えるエフェクトを作成しようと考えています。

発生している問題・エラーメッセージ

物体が頂点表示になった時に頂点が他の物体の奥にあるにも関わらず手前に点が表示される（透けて見える）ことがあります。これを解決したいです。

該当のソースコード

以下のコードをSphereオブジェクトにアタッチし、effectMatに下記のEffectShaderを設定したMaterialを与えて実行しました。displacementの値を適当に変えながらcube等のオブジェクトを手前においてみると再現できると思います。

using System.Collections;
using System.Collections.Generic;
using UnityEngine;

public class Effecter : MonoBehaviour
{
    [SerializeField, Range(0, 1)]
    private float displacement;
    [SerializeField]
    private Material effectMat;
    private Material defaultMat;
    private Renderer ren;
    private Mesh mesh;
    private bool isEffecting;

    private void Start()
    {
        mesh = GetComponent<MeshFilter>().mesh;
        ren = GetComponent<Renderer>();
        defaultMat = ren.material;
    }

    private void Update()
    {
        if (displacement > 0)
        {
            if (!isEffecting)
            {
                isEffecting = true;
                ChangeTopology(true);
            }
        }
        else
        {
            if (isEffecting)
            {
                isEffecting = false;
                ChangeTopology(false);
            }
        }

        if (isEffecting)
        {
            ren.material.SetFloat("_Displacement", displacement);
        }
    }

    private void ChangeTopology(bool isEffect)
    {
        if (isEffect)
        {
            ren.material = effectMat;
            mesh.SetIndices(mesh.GetIndices(0), MeshTopology.Points, 0);
        }
        else
        {
            ren.material = defaultMat;
            mesh.SetIndices(mesh.GetIndices(0), MeshTopology.Triangles, 0);
        }
    }
}

Shader "Custom/EffectShader"
{
	Properties
	{
		_Displacement("Displacement",Range(0,1)) = 0
		_PointColor("PointColor",Color) = (1,1,1,1)
	}

	SubShader
	{
		Tags{"RenderType" = "Transparent" }
		Cull Off ZWrite On Blend SrcAlpha OneMinusSrcAlpha
		LOD 100
	
		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag			
			#include "UnityCG.cginc"

			struct v2f {
			float4 pos : SV_POSITION;
			float3 worldPos : TEXCOORD0;
			};

			float _Displacement;
			half4 _PointColor;

			v2f vert (appdata_base v)
			{
				v2f o;
				float3 n = UnityObjectToWorldNormal(v.normal);
				o.pos = UnityObjectToClipPos(v.vertex) + float4(n * _Displacement, 0);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				return o;
			}
			
			fixed4 frag (v2f i) : COLOR
			{
				return half4(_PointColor.r,_PointColor.g,_PointColor.b,max(1- _Displacement,0));
			}
			ENDCG
		}
	}
}

補足情報（FW/ツールのバージョンなど）

Unity 2017.3.1f1

回答よろしくお願いします。

Answer 1

頂点座標をUnityObjectToClipPosでクリッピング座標に変換した後で、それをワールド座標における法線方向に移動させているために、頂点が正しい位置に移動していないのではないでしょうか?

順序としては、

• 頂点のモデル座標をワールド座標に変換する
• ワールド座標をワールド法線の向きにずらす
• ワールド座標をクリッピング座標に変換する（ビュー変換・プロジェクション変換を行う）
• 最終的なクリッピング座標をo.posにセットする

となるかと思います。

vertを下記のように変更してみましたが、いかがでしょうか?
上記の順序に合わせて変数を用意した冗長な形になっていますが、適宜行をまとめても問題ないでしょう。

Shader "Custom/EffectShader"
{
    Properties
    {
        _Displacement("Displacement",Range(0,1)) = 0
        _PointColor("PointColor",Color) = (1,1,1,1)
    }

    SubShader
    {
        Tags{"RenderType" = "Transparent" }
        Cull Off ZWrite On Blend SrcAlpha OneMinusSrcAlpha
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag            
            #include "UnityCG.cginc"

            struct v2f {
            float4 pos : SV_POSITION;
            // float3 worldPos : TEXCOORD0; // worldPosは使用していないようなので、削除してもいいでしょう
            };

            float _Displacement;
            half4 _PointColor;

            v2f vert (appdata_base v)
            {
                v2f o;
                float3 n = UnityObjectToWorldNormal(v.normal); // ワールド法線
                float3 p = mul(unity_ObjectToWorld, v.vertex).xyz; // モデル座標→ワールド座標
                float3 offset = n * _Displacement; // ワールド座標のずらし量
                float3 pOffset = p + offset; // ずらし後のワールド座標
                float4 pClip = mul(UNITY_MATRIX_VP, float4(pOffset, 1.0)); // ワールド座標→クリッピング座標（XYZ成分だけでなくW成分も必要なので、pOffsetにW成分として1を加えてfloat4としてから変換）
                o.pos = pClip; // pClipを最終的なo.posとして以降の描画プロセスへ送る
                // o.worldPos = pOffset; // worldPosは使用していないようなので、削除してもいいでしょう
                return o;
            }

            fixed4 frag (v2f i) : COLOR
            {
                return half4(_PointColor.r,_PointColor.g,_PointColor.b,max(1- _Displacement,0));
            }
            ENDCG
        }
    }
}

Comments

[TS627]

うまく動作しました。
詳しい説明ありがとうございます。