VB.NET リスト(of T)配列の生成方法

Question

前提・実現したいこと

VB.NETで下記の最後にある「箱は 配列型　List<int>[ ] → 中に入っている小箱は int 型の List」を実装したいと思っております。
http://koshinran.hateblo.jp/entry/2017/06/22/202924

C#であれば問題ないのですが、案件がVB.NET縛りです。

発生している問題・エラーメッセージ

エラーメッセージ

該当のソースコード

Public Class clsNOandID_Ctrl
    ' ## NoとIDの対応表定義（リスト配列） ##
    Private lstNoId As List(Of Integer)()

    'コンストラクタ
    Public Sub New()
        lstNoId(0) = New List(Of Integer)()
        lstNoId(1) = New List(Of Integer)()
    End Sub

    ' ## 添字と値を受け取りリスト配列にAddする ##
    Public Sub setListNoId(ByVal idx As Integer, ByVal val As Integer)
        lstNoId(idx).Add(val)
    End Sub

    Public Function getListNoId()
        Return lstNoId
    End Function


End Class

試したこと

上記コードのクラスをインスタンス化(Dim c As New clsNOandID_Ctrl)すると、System.NullReferenceExceptionが発生いたします。
こちらはソースコード3行目がlstNoIdの宣言がインスタンス化されていないものだと認識いたしましたので、下記コードに変更いたしました。

Public Class clsNOandID_Ctrl
    ' ## NoとIDの対応表定義（リスト配列） ##
    Private lstNoId As List(Of Integer)()

    'コンストラクタ
    Public Sub New()
        lstNoId = New List(Of Integer)()     ' !!!!!!!!! この行を追加 !!!!!!!
        lstNoId(0) = New List(Of Integer)()
        lstNoId(1) = New List(Of Integer)()
    End Sub

    ' ## 添字と値を受け取りリスト配列にAddする ##
    Public Sub setListNoId(ByVal idx As Integer, ByVal val As Integer)
        lstNoId(idx).Add(val)
    End Sub

    Public Function getListNoId()
        Return lstNoId
    End Function


End Class

すると、エラー BC30311 型 'List(Of Integer)' の値を 'List(Of Integer)()' に変換できません。
おそらくNew List(Of Integer)()が配列化されていない、というエラーかと思うのですが、何方か良い解決案をご存知でしたらご教授頂きたく存じます。
よろしくお願いいたします。

Answer 1

.NET Frameworkプログラミングらしくなくなってしまうとは思うのですが、Visual Basic からの配列アクセス用にReDim を使えばご要望の動きになるかと思います。ReDim ステートメント

要素数3での例を示します。

' VB.NET
    Public Sub New()

        '        lstNoId = New List(Of Integer)()     ' !!!!!!!!! この行を追加 !!!!!!!

        ReDim lstNoId(2)
        lstNoId(0) = New List(Of Integer)()
        lstNoId(1) = New List(Of Integer)()
        lstNoId(2) = New List(Of Integer)()
        Try
' 範囲外アクセス！
            lstNoId(3) = New List(Of Integer)()
        Catch ex As Exception
            Debug.WriteLine(ex.Message)
        End Try

    End Sub

動的に配列のサイズを変えたい場合は、PreserveオプションやEraseステートメントの併用もありかと思います。

Comments

[LogicMagic]

ご回答頂きありがとうございました。
ReDimを使うという方法もあるのですね。大変勉強になりました。

Answer 2

List型の配列ってあんまり聞かない気がしますが…
List型のList、では駄目ですか？

Public Class clsNOandID_Ctrl
    ' ## NoとIDの対応表定義（リスト配列） ##
    Private lstNoId As New List(Of List(Of Integer))  '★ちなみにここでNewも指定しちゃえばコンストラクタの1行目は不要

    'コンストラクタ
    Public Sub New()
        'lstNoId = New List(Of List(Of Integer))
        lstNoId.Add(New List(Of Integer))  ' ★idx=0
        lstNoId.Add(New List(Of Integer))  ' ★idx=1
    End Sub

    ' ## 添字と値を受け取りリスト配列にAddする ##
    Public Sub setListNoId(ByVal idx As Integer, ByVal val As Integer)
        lstNoId(idx).Add(val)
    End Sub

    Public Function getListNoId() As List(Of List(Of Integer))  ' ★戻り値の型を指定した方が良いのでは
        Return lstNoId
    End Function

End Class

追記：

一応 配列の場合の初期化も

lstNoId = New List(Of Integer)(1) {}     ' !!!!!!!!! この行を追加 !!!!!!!

追記２：

というか No と ID のマッピングであれば、外側は Dictionary の方が良いような気がします。

また、これは たとえば setListNoId() の引数 idx に 9 とか "存在しない添字" が指定された場合はどうなるのでしょうか。
（それともサンプルコードなので省かれているだけで、そういうケースは想定しなくて良い感じですか？）

Comments

[LogicMagic]

ご回答頂きありがとうございました。
こちらのケースですと修正にほとんど時間がかからないため、やってみます。
Dictionaryにつきましてもご教授頂きありがとうございました。