データ挿入、データ削除をボタンで行う。

Question

VBA初心者です。
現在、スコア（球技）の集計をしたいと思い
表にファイル内のデータを指定の位置に挿入する。というものを実現したいのですが
色々試したのですが、なかなかうまくいきません。
・ボタンを押すと初めは挿入できるが、２回目以降はセルがずれてしまう。
・保存方法のせいなのか、エクセルを閉じ再び立ち上げるとマクロが無効になっている。
などなど、イマイチ理解できていない状況です。

今回の処理の流れとしまして
・あらかじめ表を作成しておく（編集できないようにしたい）
・PC上のデータファイル（.csv）を[挿入ボタン]で表に挿入する
・[削除ボタン]にて挿入したデータを一括削除する

これは難しいでしょうか？できそうなのですが、初心者が故に成功しません。
ご教授いただける方よろしくお願いします。
当方、Excel 2011 for Macを使用しているのですが
Excel 2013も使用可能です。

開発環境：Excel 2011 for Mac , MacBookPro

Answer 1

ご質問の内容だけでは要件を正確に把握することができなかったのですが、
わかる範囲で以下のコードを書きました。
コメントもしっかり書いたので理解可能だと思います。
これをベースに 15DB109_hotaka さんの実施したい内容をコード化すれば実施したいことができると思います。
ボタンについては、ご自身で作成された上で
[挿入ボタン] に対しては「ImportCsvFile」
[削除ボタン] に対しては「DeleteCsvData」
を登録すれば実行可能になるはずです。

・保存方法のせいなのか、エクセルを閉じ再び立ち上げるとマクロが無効になっている。

これについてはExcelの設定が原因と思われます。ここを参照して解決できませんか？

Option Explicit

' CSVファイルの1行目をコピーするかを設定してください
' （通常は各列の題名が記載されている行なのでコピー不要と思っています）
Private Const NEED_HEADER As Boolean = False

' CSVファイルのの内容をシートにインポート
Public Sub ImportCsvFile()
    
    ' 変数宣言
    Dim csvBook As Workbook
    Dim csvSheet As Worksheet
    Dim activeWorksheet As Worksheet
    Dim activeCell As Range
    Dim csvBookPath As String
    
    ' インポート処理を実施して良いかの確認ダイアログ
    ' （NO が選択された場合は処理終了）
    If MsgBox("選択されたセルにCSVデータをインポートしてよろしいですか？", vbQuestion + vbYesNo, "確認") = vbNo Then
        Exit Sub
    End If
    
    ' アクティブシートを取得
    Set activeWorksheet = ActiveSheet
    
    ' 貼り付け対象セルを取得
    On Error Resume Next
    Set activeCell = Selection
    On Error GoTo 0
    
    ' 貼り付け対象セルが取得できない場合は処理終了
    If activeCell Is Nothing Then
        MsgBox "セルが選択されていないため処理を継続できません", vbExclamation + vbOKOnly, "処理失敗"
        Exit Sub
        
    End If
    
    ' CSVファイルパスを取得
    csvBookPath = Application.GetOpenFilename(FileFilter:="CSV ファイル, *.csv?")
    
    ' CSVファイルパスが入力されなかった場合は処理終了
    If csvBookPath = "" Then
        MsgBox "CSVファイルが選択されなかったので処理を終了します", vbExclamation + vbOKOnly, "処理失敗"
        Exit Sub
        
    End If
    
    ' 処理高速化のために画面描画をオフ
    Application.ScreenUpdating = False
    
    ' CSVファイルを開く
    Set csvBook = GetCsvBook(csvBookPath)
    
    ' CSVファイルが開けなかった場合は処理終了
    If csvBook Is Nothing Then
        MsgBox "CSVファイルを開けなかったので処理を終了します", vbExclamation + vbOKOnly, "処理失敗"
        
        ' 画面描画を再開
        Application.ScreenUpdating = True
        Exit Sub
        
    End If
    
    ' CSVデータが記載されたシートを取得
    Set csvSheet = csvBook.Worksheets(1)
    
    ' アクティブシートのロックを解除
    activeWorksheet.Unprotect
    
    ' CSVの内容をアクティブシートに貼り付け
    With csvSheet.UsedRange
        csvSheet.Range(csvSheet.Cells(IIf(NEED_HEADER, 1, 2), 1), .Cells(.Cells.Count)).Copy activeCell
    End With
    
    ' CSブックを閉じる
    csvBook.Close False
    
    ' アクティブシートのロックを実施
    ProtectSheet ActiveSheet
    
    ' 画面描画を再開
    Application.ScreenUpdating = True
    
End Sub

' CSVファイルのデータを一括削除
' （但し柔軟性を持たせるために選択した範囲のみを削除できるようにする）
Public Sub DeleteCsvData()
    
    ' 変数宣言
    Dim activeWorksheet As Worksheet
    Dim activeCell As Range
    
    ' 削除処理を実施して良いかの確認ダイアログ
    ' （NO が選択された場合は処理終了）
    If MsgBox("選択されたセル削除してよろしいですか？", vbQuestion + vbYesNo, "確認") = vbNo Then
        Exit Sub
    End If
    
    ' アクティブシートを取得
    Set activeWorksheet = ActiveSheet
    
    ' 削除対象セルを取得
    On Error Resume Next
    Set activeCell = Selection
    On Error GoTo 0
    
    ' 削除対象セルが取得できない場合は処理終了
    If activeCell Is Nothing Then
        MsgBox "セルが選択されていないため処理を継続できません", vbExclamation + vbOKOnly, "処理失敗"
        Exit Sub
    End If
    
    ' 処理高速化のために画面描画をオフ
    Application.ScreenUpdating = False
    
    ' アクティブシートのロックを解除
    activeWorksheet.Unprotect
    
    ' 選択されたセルを削除
    ' （空行ができないように削除された箇所以降を上にシフト）
    activeCell.Delete xlShiftUp
    
    ' アクティブシートのロックを実施
    ProtectSheet ActiveSheet
    
    ' 画面描画を再開
    Application.ScreenUpdating = True
    
End Sub

' シートをロック(許可したい操作によってここの処理は変更してください)
Private Sub ProtectSheet(ByRef pSheet As Worksheet)
    
    With pSheet
        .Protect
    End With
    
End Sub

' CSVブックを開く（失敗した場合は Nothing を返却）
Private Function GetCsvBook(ByRef path As String, Optional password As String = "") As Workbook
    
    ' 変数宣言
    Dim book As Workbook
    
    ' ブックを開く
    On Error Resume Next
    Set book = Workbooks.Open( _
                Filename:=path, _
                UpdateLinks:=0, _
                ReadOnly:=True, _
                password:=password, _
                IgnoreReadOnlyRecommended:=True, _
                AddToMru:=False)
    On Error GoTo 0
    
    ' 結果返却
    Set GetCsvBook = book
    
End Function

Comments

[15DB109_hotaka]

ありがとうございます！コメントまでほんとにわかりやすく、初心者の私にはとても嬉しいです。
試してみます！